Как получить реальный запрос и результат запроса из СКД?

что нужно? текст запроса чтоль?

реальный это который уходит sql-серверу?

(2) нет,
- нужен тот текст запроса, который сгенерировался в зависимости от настроек
- нужен результат этого запроса

http://infostart.ru/projects/1184/

http://infostart.ru/projects/2932

типовыми методами никак?
Неужели нельзя посмотреть результат запроса компоновки данных?

+(6) и поюзать его еще где-нить?

Результат можно выгрузить в таблицу значений.

никогда не сталкивался, но думаю нужно искать здесь СхемаКомпоновкиДанных.НаборыДанных

up

надо обработать данные, которые вывела компоновка данных

(11) Как это связано с (0)?

(12) юзер строит отчет в компоновке данных. Затем юзер хочет, чтобы номенклатура, попавшая в отчет выгрузилась кое-куда...

Т.е. мне нужно узнать, какие позиции вывелись в отчет...

Процедура СообщитьЗапросы(МакетКомпоновки, Уровень)
   Для каждого Набор из МакетКомпоновки.НаборыДанных Цикл
       Сообщить("Уровень "+Уровень+": "+Набор.Имя);
       Сообщить(Набор.Запрос);
       Для каждого ЭлементТела из МакетКомпоновки.Тело Цикл
           Если ТипЗнч(ЭлементТела)=Тип("ГруппировкаМакетаКомпоновкиДанных") Тогда
               Для каждого ЭлементТелаГруппировки из ЭлементТела.Тело Цикл
                   Если ТипЗнч(ЭлементТелаГруппировки)=Тип("ВложенныйОбъектМакетаКомпоновкиДанных") Тогда
                       СообщитьЗапросы(ЭлементТелаГруппировки.КомпоновкаДанных, Уровень+1)
                   КонецЕсли;
               КонецЦикла;
           КонецЕсли;
       КонецЦикла;
   КонецЦикла;
КонецПроцедуры

(14) это ответ на (0)

Но учитывая (13) задача несколько сложнее.. и текст запроса тут может быть не совсем то на чем нужно строить решение.

КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
   МакетКомпоновки = КомпоновщикМакета.Выполнить(ЭтотОбъект.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных"),ЭтотОбъект.КомпоновщикНастроек.Настройки,ИнформацияРасшифровки,);
   
   ВнешниеНаборыДанных = Новый Структура;
   ВнешниеНаборыДанных.Вставить("СтавкиАренды",СтавкиАренды);
   
   ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
   ПроцессорКомпоновки.Инициализировать(МакетКомпоновки,ВнешниеНаборыДанных,ИнформацияРасшифровки,Истина);
   
   ДокументРезультат = ЭлементыФормы.Результат;
   
   //ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
   //ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
   //
   //ПроцессорВывода.Вывести(ПроцессорКомпоновки,Истина);
   
   ТЗ = Новый ТаблицаЗначений;
   ПроцессорВыводаВКоллекцию = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений;
   ПроцессорВыводаВКоллекцию.УстановитьОбъект(ТЗ);
   ПроцессорВыводаВКоллекцию.Вывести(ПроцессорКомпоновки,Истина);



ПроцессорВыводаВКоллекцию.Вывести(ПроцессорКомпоновки,Истина) - вызывает ошибку, что неизвестен тип макета...

Хорошо, как данные компоновки вывести и в макет и в таблицу значений?

(16) надо тип генератора другой указывать:
МакетКомпоновки = КомпоновщикМакета.Выполнить(ЭтотОбъект.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных"),ЭтотОбъект.КомпоновщикНастроек.Настройки,ИнформацияРасшифровки,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));

(18) спасибо, именно это и хотел

(16) Делаю тоже самое но у меня почему-то выдает ошибку:

{Форма.ФормаОтчета(124)}: Ошибка при вызове метода контекста (Выполнить): Несоответствие типов (параметр номер '4')
   МакетКомпоновки = КомпоновщикМакета.Выполнить(ЭтотОбъект.ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных"),ЭтотОбъект.КомпоновщикНастроек.Настройки,,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"));
по причине:
Несоответствие типов (параметр номер '4')

Функция ПолучитьРезультатКомпоновки(Режим=Ложь,Результат=неопределено,МакетКомпоновки,Настройки=неопределено,ВнешниеДанные=неопределено,МакетОформления=неопределено,ПоказыватьВывод=Ложь) Экспорт
   
   КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
   ДанныеРасшифровки= Новый ДанныеРасшифровкиКомпоновкиДанных;
   
    МакетКомпоновкиДанных = КомпоновщикМакета.Выполнить(МакетКомпоновки
   ,?(Настройки=неопределено,МакетКомпоновки.НастройкиПоУмолчанию,Настройки) //Настройки
   ,ДанныеРасшифровки             //Расшифровка
   ,МакетОформления               //МакетОформления
   ,?(Режим,неопределено,Тип("ГенераторМакетаКомпоновкиДанныхДляКоллекцииЗначений"))
   );
   
       
   ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
   ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных,ВнешниеДанные);
   
   ПроцессорВывода =?(Режим,Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент, Новый  ПроцессорВыводаРезультатаКомпоновкиДанныхВКоллекциюЗначений) ;
   Если Не Результат=неопределено Тогда
       Если Режим Тогда
           ПроцессорВывода.УстановитьДокумент(Результат);
       Иначе
           ПроцессорВывода.УстановитьОбъект(Результат);
       КонецЕсли;    
   КонецЕсли;
   возврат ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных,ПоказыватьВывод);
КонецФункции

(21) Спасибо. Посмотрю сейчас.