Как собственно на форму вытащить таблицу значений именно программно.
Сильно не пинайте с 8.2 пока только осваиваюсь

(Таблица значений) уже есть как реквизит?

нет она тоже программно создаеться

и структура у нее естественно может меняться

На сервере создается?
Нужно создать ДанныеФормыКоллекция соотв. ТЗ и пихнуть её в реквизиты формы через ИзменитьРеквизиты, потом создать через Элементы таблицу формы с привязкой к этой коллекции.

(4) А образец кода можно? Плиз

(5) А ты попробуй сам. Вдруг получится? В СП поищи, в типовой какой-нить.

Не могу сообразить как и примеров в типовых нету. По крайней мере явных

Примерно так:
МассивТипаВыбора = Новый Массив;
МассивТипаВыбора.Добавить(Тип("ТаблицаЗначений"));
ОписаниеТипаВыбора = Новый ОписаниеТипов(МассивТипаВыбора);
МассивРеквизитов.Добавить(Новый РеквизитФормы("МойРеквизит", ОписаниеТипаВыбора, "", "Моя таблица"));


ТаблицаПолейВыбора                          = ФормаОтчета.Элементы.Добавить("МояТаблица", Тип("ТаблицаФормы"), Группа);
ТаблицаПолейВыбора.ПутьКДанным              = "МойРеквизит";
ТаблицаПолейВыбора.Отображение              = ОтображениеТаблицы.Список;
ТаблицаПолейВыбора.ПоложениеЗаголовка       = ПоложениеЗаголовкаЭлементаФормы.Нет;
ТаблицаПолейВыбора.ПоложениеКоманднойПанели = ПоложениеКоманднойПанелиЭлементаФормы.Нет;
ТаблицаПолейВыбора.ВертикальныеЛинии        = ложь;
ТаблицаПолейВыбора.ГоризонтальныеЛинии      = ложь;
ТаблицаПолейВыбора.Шапка                    = ложь;
ТаблицаПолейВыбора.Подвал                   = ложь;
ТаблицаПолейВыбора.ИзменятьПорядокСтрок     = истина;
ТаблицаПолейВыбора.ИзменятьСоставСтрок      = ложь;
ТаблицаПолейВыбора.РастягиватьПоГоризонтали = Истина;
ТаблицаПолейВыбора.ИзменятьСоставСтрок      = ложь;

ФормаОтчета.ИзменитьРеквизиты(МассивРеквизитов);

v8: СКД 8.2: программный вывод в дерево значений на форме

Спасибо попробую отпишусь о результатах

Вообщем получилось както так:

   МассивРеквизитов = Новый Массив;
   МассивТипаВыбора = Новый Массив;
   МассивТипаВыбора.Добавить(Тип("ТаблицаЗначений"));
   ОписаниеТипаВыбора = Новый ОписаниеТипов(МассивТипаВыбора);
   МассивРеквизитов.Добавить(Новый РеквизитФормы("МойРеквизит", ОписаниеТипаВыбора, "", "Моя таблица"));
   
   Для Каждого Колонка Из ТЗ.Колонки Цикл
        МассивРеквизитов.Добавить(Новый РеквизитФормы(Колонка.Имя, Колонка.ТипЗначения, "МойРеквизит"));
   КонецЦикла;

   ИзменитьРеквизиты(МассивРеквизитов);
   
   ТаблицаПолейВыбора                          = Элементы.Добавить("МояТаблица", Тип("ТаблицаФормы"),Родитель);
   ТаблицаПолейВыбора.ПутьКДанным              = "МойРеквизит";
   ТаблицаПолейВыбора.Отображение              = ОтображениеТаблицы.Список;
   Для Каждого Колонка Из ТЗ.Колонки Цикл
       НовыйЭлемент = Элементы.Добавить("Дерево_" + Колонка.Имя, Тип("ПолеФормы"), ТаблицаПолейВыбора);
       НовыйЭлемент.Вид = ВидПоляФормы.ПолеВвода;
       НовыйЭлемент.ПутьКДанным = "МойРеквизит." + Колонка.Имя;
   КонецЦикла;    
   ЗначениеВРеквизитФормы(ТЗ,"МойРеквизит");

ТЗ - произвольная таблица значений.