По поводу "не сексуальных" - желающие пофлудить на тему "как физически выглядит возврат услуг?" прошу отдохнуть. Речь о Альфа-Авто, клиент отдал тачку в автосервис, ему вроде все сделали, оформили заказ-нарядом. Клиент его оплатил, день поездил, опять что-то забрякало - вернулся в автосервис, требует деньги назад.
Деньги ему вернут - действительно оказанная услуга оказалась халтурой. Но нужно основание для РКО, чтобы клиент в должниках не оказался. Да, и с халтурщиками (исполнителями работ) желательно разобраться, т.е. заказ-наряд удалять не желательно.
Первое, что приходит в голову - сделать сторонирующий заказ-наряд, с соответствующей хоз. операцией, или видом ремонта "претензия", который можно отредактировать (если не все услуги в заказ-наряде халтура).
Какие еще возможны варианты возврата услуг?

Встречные услуги от клиента?

Дописывай, если конфигурацией не предусмотрено

"возвращенные товары, невыполненные работы, неоказанные услуги" гуглить

(1) Нет, клиент разочарован нашим автосервисом, требует возврата денег.
(2) Да, дописывать. Но какие еще возможны варианты, кроме сторонирующего заказ-наряд?
(3) Гуглил - один флуд...

Нужен док. "Возврат денег за некачественно оказанные услуги"

Возврат денег по РКО.
Сумму "долга" с клиента "списать" путем отнесения на виновное лицо соответсвующей проводкой.

Альфа-Авто, документ "Акт разногласий", есть ТЧ услуги - почему не подходит?

(5) По сути сторонирующий заказ-наряд по взаиморасчетам,
(6) и выработки исполнителей работ?
(7) Спс, документ "Акт разногласий" упустил, посмотрю...

(7) Вроде то что надо - с форума РАРУСа "Возврат по заказ-наряду, Как правильно?" http://rarus.ru/forum/forum7/topic6019/message35787/#message35787
Документ "Акт разногласий" предназначен для ввода корректировок в закрытый заказ-наряд. При этом документ заполняется выполненными работами и использованными при этом деталями. Возможно изменение количества, цен, скидок, нормочасов с перерасчетом суммы заказ-наряда.

(5) Желательно переименовать тему в "Возврат услуг в Альфа-Авто" - может еще кому она пригодится, а не у всех коллег по цеху имеется доступ к форумам РАРУСа (да и поиск там не очень... или я не умею им пользоваться).

(0) Корректировки задолженности нет или она не подходит?

(11) Не только во взаиморасчетах дело. Претензии заказчиков обычно типа: "Чо вы мне движок новый впарили - он вообще не тянет, и глохнет!? Возвращайте мой взад!". А сторнирования движений товаров в производстве "Акт разногласий" не делает, и "Извлечение товаров из производства" на его основании не сделать (как и из закрытого заказ-наряда) - в этом проблема :?

Смотрел "Акт разногласий" в 4-й Альфа-Авто, может в 5-й он доведен до ума? (сейчас нет под рукой)

В 5-ке есть документ Корректировка реализации, мож подойдёт?

(12) а с какого пня "акт разногласий" должен какие-то "движения по товарам" делать? акт разногласий - если он утрясен и "согласован" сторонами "конфликта" - это всего лишь обязательство скорректировать взаиморасчеты между стороноами. ВЗАИМОРАСЧЕТЫ. которые никаким образом не относятся к товарам/работам - которые (товары/работы) находятся исключительно во внутренней компетенции "поставщика услуг".
как-то так я себе мыслю

Расходник и корректировка долга спасут отца русской демократии

Акт разногласий + извлечение из производства на основании Заказ-наряда.

Открытым остается вопрос начисленной зарплаты исполнителей работ (у нас еще техников-приемщиков).

(17) Чтобы сделать это извлечение из производства сначала детали проданные по заказ-наряду нужно вернуть в производство! Для этого заказ-наряд сделать не проведенным (из закрытого ничего не извлечь), либо сторнировать Актом разногласий из регистра продаж в регистр ТоварыВПроизводстве. Из продаж детали сторнируются, но куда? Или по закрытому, и сторнированному актом заказ-наряду можно сделать извлечение из производства?

А почему детали, которые были списаны на услугу должны в производство вернуться?!

(20) Чтобы было что на склад вернуть. Продажа через заказ-наряд происходит в 2 этапа:
- перемещение со склада в производство специальным документом,
- непосредственная продажа клиенту при закрытии заказ-наряда.
Вернуться они должны тем же путем в обратной последовательности.

(21) это что за детали которые надо вернуть на склад после того, как они были установлены на авто? )

(21) в обратной последовательности они вернуться не могут, они могут вернуться только через КорректировкуРеализации..

не только, есть еще ВозвратОтПокупателя

(24) Да, хороший документ, сразу возвращает товары от покупателя на склад, минуя производство (не нужно делать "Извлечение товаров из производства").
Но ситуации бывают разные. Например, комп заглючил самым непонятных образом. Причина может быть банальной - вздувшийся кондер, а может - вплоть до поджарившегося проца. Если искать вздувшийся кондер - мать паяльником пытать, то перебросить процы - минутное дело, если у соседа-коллеги такой же комп (или проц взаимозаменяемый). Если глюг перешел в соседу, то ясно в чем причина, нет нужды перебирать остальные комплектующие компа.
В автосервисе тоже возможны подобные ситуации: заменили что-то дорогостоящее, вроде помогло. А потом как оказалось, не угадали, клиент вернулся в расстроенных чувствах, обиделся, что его "за лоха держат"...
В такой ситуации одного уже недостаточно одного "Возврат от покупателя", надо весь заказ-наряд сторнировать. И если РАРУС сделал для этого универсальный "Акт разногласий", то он должен иметь возможность охватывать все движения заказ-наряда.
Хотя, честно говоря, в нашей АК (основное м.р.) такой ситуации ни разу не было, понятия не имел о "Акте разногласий"!?

(25) какие ситуации бывают как в АС так и в СЦ я прекрасно знаю...

Прикрутил пару галочек, дописал Функцию ПровестиПоПартиям() по аналогии с проведением по регистру продаж. Правда, с проведением работ по регистру "Выработка сотрудников" пришлось извратнутся, очень не хотелось самих исполнителей в "Акт разногласий" тащить... Вроде работает:

    //+МВ 03.08.2015 Проведем сторнирование деталей по регистру "Товары компании в производстве", и работ по регистру "Выработка сотрудников"
    Если ВернутьДеталиВПроизводство Тогда
        НаборЗаписейТоварыВПроизводстве = Движения.ТоварыВПроизводстве;
        
        Запрос=Новый Запрос;
        Запрос.Текст="
        |ВЫБРАТЬ
        |    ТоварыВПроизводстве.Цех,
        |    ТоварыВПроизводстве.Номенклатура,
        |    ТоварыВПроизводстве.ХарактеристикаНоменклатуры,
        |    ТоварыВПроизводстве.СтатусПартии,
        |    ТоварыВПроизводстве.Партия,
        |    ТоварыВПроизводстве.Количество,
        |    ТоварыВПроизводстве.Сумма,
        |    ТоварыВПроизводстве.СуммаУпр,
        |    ТоварыВПроизводстве.СуммаНДС,
        |    ТоварыВПроизводстве.ХозОперация,
        |    ТоварыВПроизводстве.СтавкаНДС
        |ИЗ
        |    РегистрНакопления.ТоварыВПроизводстве КАК ТоварыВПроизводстве
        |ГДЕ
        |    ТоварыВПроизводстве.Регистратор = &ЗаказНаряд
        |
        |УПОРЯДОЧИТЬ ПО
        |    ТоварыВПроизводстве.НомерСтроки";
        Запрос.УстановитьПараметр("ЗаказНаряд",ДокументОснование);
        тзТоварыВПроизводстве = Запрос.Выполнить().Выгрузить();
        Для каждого СтрокаТЧ Из Товары Цикл
            Количество=СтрокаТЧ.КоличествоРазница;
            СуммаРегл=обПересчет(СтрокаТЧ.СуммаВсегоРазница,ВалютаДокумента,КурсДокумента,ВалютаРегл,КурсРегл);
            СуммаУпр=обПересчет(СтрокаТЧ.СуммаВсегоРазница,ВалютаДокумента,КурсДокумента,ВалютаУпр,КурсВалютыУпр);
            СуммаНДС=обПересчет(СтрокаТЧ.СуммаНДСРазница,ВалютаДокумента,КурсДокумента,ВалютаРегл,КурсРегл);
            Если Количество >= 0 Или (Количество=0 И СуммаРегл=0 И СуммаУпр=0 И СуммаНДС=0) Тогда
                Продолжить; // Для возврата деталей из продаж в производство годится только отрицательная разница между количеством докумета и заказ-наряда
            КонецЕсли;
            Количество    = -Количество;
            СуммаРегл    = -СуммаРегл;
            СуммаУпр    = -СуммаУпр;
            СуммаНДС    = -СуммаНДС;
            СтрокиТоварыВПроизводстве = тзТоварыВПроизводстве.НайтиСтроки(Новый Структура("Номенклатура, ХарактеристикаНоменклатуры", СтрокаТЧ.Номенклатура , СтрокаТЧ.ХарактеристикаНоменклатуры));
            НоваяЗаписьТоварыВПроизводстве = Неопределено;
            Для каждого СтрокаТоварыВПроизводстве Из СтрокиТоварыВПроизводстве Цикл
                Если Количество <= 0 Тогда Прервать; КонецЕсли;
                НоваяЗаписьТоварыВПроизводстве = НаборЗаписейТоварыВПроизводстве.Добавить();
                НоваяЗаписьТоварыВПроизводстве.ВидДвижения                  = ВидДвиженияНакопления.Расход;
                НоваяЗаписьТоварыВПроизводстве.Период                      = ШапкаДокумента.Дата;
                НоваяЗаписьТоварыВПроизводстве.Регистратор                  = ШапкаДокумента.Ссылка;
                НоваяЗаписьТоварыВПроизводстве.ЗаказНаряд                  = ДокументОснование;
                НоваяЗаписьТоварыВПроизводстве.Цех                          = ДокументОснование.Цех;
                НоваяЗаписьТоварыВПроизводстве.Номенклатура                  = СтрокаТоварыВПроизводстве.Номенклатура;
                НоваяЗаписьТоварыВПроизводстве.ХарактеристикаНоменклатуры = СтрокаТоварыВПроизводстве.ХарактеристикаНоменклатуры;
                НоваяЗаписьТоварыВПроизводстве.СтатусПартии                  = СтрокаТоварыВПроизводстве.СтатусПартии;
                НоваяЗаписьТоварыВПроизводстве.Партия                      = СтрокаТоварыВПроизводстве.Партия;
                НоваяЗаписьТоварыВПроизводстве.Количество                  = -Мин(СтрокаТоварыВПроизводстве.Количество, Количество);
                НоваяЗаписьТоварыВПроизводстве.СуммаУпр                      = СтрокаТоварыВПроизводстве.СуммаУпр * НоваяЗаписьТоварыВПроизводстве.Количество/СтрокаТоварыВПроизводстве.Количество;
                НоваяЗаписьТоварыВПроизводстве.Сумма                      = СтрокаТоварыВПроизводстве.Сумма       * НоваяЗаписьТоварыВПроизводстве.Количество/СтрокаТоварыВПроизводстве.Количество;
                НоваяЗаписьТоварыВПроизводстве.СуммаНДС                      = СтрокаТоварыВПроизводстве.СуммаНДС * НоваяЗаписьТоварыВПроизводстве.Количество/СтрокаТоварыВПроизводстве.Количество;
                НоваяЗаписьТоварыВПроизводстве.ХозОперация                  = ШапкаДокумента.ХозОперация;
                НоваяЗаписьТоварыВПроизводстве.СтавкаНДС                  = СтрокаТоварыВПроизводстве.СтавкаНДС;
                Количество    = Количество - (-НоваяЗаписьТоварыВПроизводстве.Количество);
                СуммаУпр    = СуммаУпр     - (-НоваяЗаписьТоварыВПроизводстве.СуммаУпр);
                СуммаРегл    = СуммаРегл     - (-НоваяЗаписьТоварыВПроизводстве.Сумма);
                СуммаНДС    = СуммаНДС     - (-НоваяЗаписьТоварыВПроизводстве.СуммаНДС);
            КонецЦикла;
            Количество    = Окр(Количество, 3);
            СуммаУпр    = Окр(СуммаУпр,      2);
            СуммаРегл    = Окр(СуммаРегл,  2);
            СуммаНДС    = Окр(СуммаНДС,      2);
            Если Количество<>0 Тогда
                //Если после сторнирования еще что-то осталось - сторно на последнюю партию или на пустую партию
                НоваяЗаписьТоварыВПроизводствеПревышение = НаборЗаписейТоварыВПроизводстве.Добавить();
                НоваяЗаписьТоварыВПроизводствеПревышение.ВидДвижения                = ВидДвиженияНакопления.Расход;
                НоваяЗаписьТоварыВПроизводствеПревышение.Период                        = ШапкаДокумента.Дата;
                НоваяЗаписьТоварыВПроизводствеПревышение.Регистратор                = ШапкаДокумента.Ссылка;
                НоваяЗаписьТоварыВПроизводствеПревышение.ЗаказНаряд                    = ДокументОснование;
                НоваяЗаписьТоварыВПроизводствеПревышение.Цех                        = ДокументОснование.Цех;
                НоваяЗаписьТоварыВПроизводствеПревышение.Номенклатура                = СтрокаТЧ.Номенклатура;
                НоваяЗаписьТоварыВПроизводствеПревышение.ХарактеристикаНоменклатуры = СтрокаТЧ.ХарактеристикаНоменклатуры;
                Если НоваяЗаписьТоварыВПроизводстве = Неопределено Тогда
                    НоваяЗаписьТоварыВПроизводствеПревышение.СтатусПартии            = Перечисления.СтатусыПартий.ТоварКупленный;
                Иначе
                    НоваяЗаписьТоварыВПроизводствеПревышение.СтатусПартии            = НоваяЗаписьТоварыВПроизводстве.СтатусПартии;
                    НоваяЗаписьТоварыВПроизводствеПревышение.Партия                    = НоваяЗаписьТоварыВПроизводстве.Партия;
                КонецЕсли;
                НоваяЗаписьТоварыВПроизводствеПревышение.Количество                    = -Количество;
                НоваяЗаписьТоварыВПроизводствеПревышение.СуммаУпр                    = -СуммаУпр;
                НоваяЗаписьТоварыВПроизводствеПревышение.Сумма                        = -СуммаРегл;
                НоваяЗаписьТоварыВПроизводствеПревышение.СуммаНДС                    = -СуммаНДС;
                НоваяЗаписьТоварыВПроизводствеПревышение.ХозОперация                = ШапкаДокумента.ХозОперация;
                НоваяЗаписьТоварыВПроизводствеПревышение.СтавкаНДС                    = СтрокаТоварыВПроизводстве.СтавкаНДС;
            КонецЕсли;
        КонецЦикла;
    КонецЕсли;
    
    Если СторнироватьВыработкуИсполнителей Тогда
        НаборЗаписейВыработкаСотрудников = Движения.ВыработкаСотрудников;
        
        Запрос=Новый Запрос;
        Запрос.Текст="ВЫБРАТЬ
        |    ВыработкаСотрудников.Сотрудник,
        |    ВыработкаСотрудников.Работа,
        |    ВыработкаСотрудников.ВидРемонта,
        |    ВыработкаСотрудников.Цех,
        |    ВыработкаСотрудников.Автомобиль,
        |    ВыработкаСотрудников.Количество,
        |    ВыработкаСотрудников.СуммаУпр,
        |    ВыработкаСотрудников.СуммаУпрСоСкидкой,
        |    ВыработкаСотрудников.ХозОперация
        |ИЗ
        |    РегистрНакопления.ВыработкаСотрудников КАК ВыработкаСотрудников
        |ГДЕ
        |    ВыработкаСотрудников.Регистратор = &ЗаказНаряд
        |
        |УПОРЯДОЧИТЬ ПО
        |    ВыработкаСотрудников.НомерСтроки";
        Запрос.УстановитьПараметр("ЗаказНаряд",ДокументОснование);
        тзВыработкаСотрудников = Запрос.Выполнить().Выгрузить();
        
        Запрос=Новый Запрос;
        Запрос.Текст="ВЫБРАТЬ
        |    ЗаказНарядИсполнители.Исполнитель,
        |    ЗаказНарядИсполнители.Цех,
        |    СУММА(ЗаказНарядИсполнители.Процент) КАК Процент,
        |    ЗаказНарядРаботы.Работа
        |ИЗ
        |    Документ.ЗаказНаряд.Исполнители КАК ЗаказНарядИсполнители
        |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ЗаказНаряд.Работы КАК ЗаказНарядРаботы
        |        ПО ЗаказНарядИсполнители.ИдентификаторРаботы = ЗаказНарядРаботы.ИдентификаторРаботы
        |ГДЕ
        |    ЗаказНарядИсполнители.Ссылка = &ЗаказНаряд
        |
        |СГРУППИРОВАТЬ ПО
        |    ЗаказНарядИсполнители.Исполнитель,
        |    ЗаказНарядИсполнители.Цех,
        |    ЗаказНарядРаботы.Работа";
        Запрос.УстановитьПараметр("ЗаказНаряд",ДокументОснование);
        ТаблицаИсполнителей=Запрос.Выполнить().Выгрузить();
        Для каждого СтрокаТЧ Из Работы Цикл
            СтрокиТаблицаИсполнителей = ТаблицаИсполнителей.НайтиСтроки(Новый Структура("Работа", СтрокаТЧ.Работа));
            Для каждого СтрокаИсполнителя Из СтрокиТаблицаИсполнителей Цикл
                Количество=СтрокаТЧ.КоличествоРазница*СтрокаИсполнителя.Процент;
                СуммаУпр=обПересчет(СтрокаТЧ.СуммаВсегоРазница,ВалютаДокумента,КурсДокумента,ВалютаУпр,КурсВалютыУпр)*СтрокаИсполнителя.Процент;
                СуммаУпрСоСкидкой=СуммаУпр+обПересчет(СтрокаТЧ.СуммаСкидкиРазница,ВалютаДокумента,КурсДокумента,ВалютаРегл,КурсРегл)*СтрокаИсполнителя.Процент;
                Если Количество >= 0 Или (Количество=0 И СуммаРегл=0 И СуммаУпр=0) Тогда
                    Продолжить; // Для сторнирования выработки годится только отрицательная разница между количеством докумета и заказ-наряда
                КонецЕсли;
                Количество          = -Количество;
                СуммаУпр          = -СуммаУпр;
                СуммаУпрСоСкидкой = -СуммаУпрСоСкидкой;
                СтрокиВыработкаСотрудников = тзВыработкаСотрудников.НайтиСтроки(Новый Структура("Сотрудник, Работа", СтрокаИсполнителя.Исполнитель , СтрокаТЧ.Работа));
                НоваяЗаписьВыработкаСотрудников = Неопределено;
                Для каждого СтрокаВыработкаСотрудников Из СтрокиВыработкаСотрудников Цикл
                    Если Количество <= 0 Тогда Прервать; КонецЕсли;
                    НоваяЗаписьВыработкаСотрудников = НаборЗаписейВыработкаСотрудников.Добавить();
                    НоваяЗаписьВыработкаСотрудников.Период                      = ШапкаДокумента.Дата;
                    НоваяЗаписьВыработкаСотрудников.Регистратор                  = ШапкаДокумента.Ссылка;
                    НоваяЗаписьВыработкаСотрудников.Сотрудник                  = СтрокаВыработкаСотрудников.Сотрудник;
                    НоваяЗаписьВыработкаСотрудников.Работа                      = СтрокаВыработкаСотрудников.Работа;
                    НоваяЗаписьВыработкаСотрудников.ВидРемонта                  = СтрокаВыработкаСотрудников.ВидРемонта;
                    НоваяЗаписьВыработкаСотрудников.Цех                          = СтрокаВыработкаСотрудников.Цех;
                    НоваяЗаписьВыработкаСотрудников.Автомобиль                  = СтрокаВыработкаСотрудников.Автомобиль;
                    НоваяЗаписьВыработкаСотрудников.Количество                  = -Мин(СтрокаВыработкаСотрудников.Количество, Количество);
                    НоваяЗаписьВыработкаСотрудников.СуммаУпр                  = СтрокаВыработкаСотрудников.СуммаУпр             * НоваяЗаписьВыработкаСотрудников.Количество/СтрокаВыработкаСотрудников.Количество;
                    НоваяЗаписьВыработкаСотрудников.СуммаУпрСоСкидкой          = СтрокаВыработкаСотрудников.СуммаУпрСоСкидкой * НоваяЗаписьВыработкаСотрудников.Количество/СтрокаВыработкаСотрудников.Количество;
                    НоваяЗаписьВыработкаСотрудников.ХозОперация                  = ШапкаДокумента.ХозОперация;
                    Количество          = Количество          - (-НоваяЗаписьВыработкаСотрудников.Количество);
                    СуммаУпр          = СуммаУпр          - (-НоваяЗаписьВыработкаСотрудников.СуммаУпр);
                    СуммаУпрСоСкидкой = СуммаУпрСоСкидкой - (-НоваяЗаписьВыработкаСотрудников.СуммаУпрСоСкидкой);
                КонецЦикла;
            КонецЦикла;
        КонецЦикла;
    КонецЕсли; //-МВ

Сразу замечу, по своему назначению документ "Акт разногласий" предназначен для ввода корректировок в закрытый заказ-наряд, ни только сторнирующих (в минус), но и наоборот. В моем случае задача корректировать "в плюс" не ставилась - не могу даже представить практически ситуацию, когда это может понадобиться. Да в сама форма документа вроде не позволяет вводить положительные корректирующие значения.
Может у кого есть свой вариант (хотя бы идея)?

Других вариантов, идей нет?

После внесения изменений в конфигурацию появилась проблема (хотя, развернул копию до внесения изменений - проблема та же):
v8: Документ не можеть быть проведен оперативно, а именно с "Заявка на ремонт". Эти документы всегда делались на неделю вперед, и сейчас в базе их проведенных будущей датой больше десятка, и не один не проводится - сразу ошибка!? А сегодняшние - как положено, с выбором режима: Оперативное проведение/Неоперативное проведение.
Смотрел Книга знаний: Как разрешить проведение будущей датой в форме документа, пробовал, не помогло - ошибка появляется до процедур!
Пересчет итогов делал - тоже не помогло. Что рыть, куда копать?

+ до процедур ПередЗаписью()

Процедура ОбработчикИзмененияДаты(Данные) из Книга знаний: Как разрешить проведение будущей датой в форме документа конечно помогла! Но как раньше работало? Не понимаю...

Спросил у РАРУС http://rarus.ru/forum/messages/forum7/topic9937/message58506/?result=reply#message58506