Типа:

Доллар
10.01.11  1000-00
09.01.11  999-00
Евро
10.01.11  2000-00
09.01.11  1999-00

и т.д.

Запросом.

(1) О какое просветление! Прям бальзам в душу!

самое простое - выбрать первые 2 и объединить по валютам

(3) Пример можно?

(4) Выбрать первые 2 ....

(0) загрузи курсы на каждый день и проблема решится )
Кто предлагает первые 2, то попробуйте сделать так, как указал автор.

ВЫБРАТЬ ПЕРВЫЕ 2
   КурсыВалютСрезПоследних.Валюта,
   КурсыВалютСрезПоследних.Курс,
   КурсыВалютСрезПоследних.Кратность
ИЗ
   РегистрСведений.КурсыВалют.СрезПоследних(&Дата, Валюта = &Доллар) КАК КурсыВалютСрезПоследних

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ ПЕРВЫЕ 2
   КурсыВалютСрезПоследних.Валюта,
   КурсыВалютСрезПоследних.Курс,
   КурсыВалютСрезПоследних.Кратность
ИЗ
   РегистрСведений.КурсыВалют.СрезПоследних(&Дата, Валюта = &Евро) КАК КурсыВалютСрезПоследних

(7) Ты предлагаешь указать каждую валюту отдельно?
Без этого никак?

(7) я думаю всё же надо использовать физическую таблицу с упорядочиванием по дате, а не виртуальную среза

(7) + Итоги по валюте, но если не на каждый день курсы - то есно вернёт 2 последние записи по валюте

(8) это самое простое, можно подумать конечно чтоб покрасивей было

(8) можно выбрать срез последних и соединить с физической с условием период < период, ну и группировкой.

(11) Извини, но это вариант не катит.

(12) Задача надо решать в консоли отчетов

т.е в консоле запросов

(15) параметры же там есть, в консоли

(16) Я про валюту для примера. А так задача помасштабнее. Там элементов могут быть сотни

(7) Этим запросом мы выберем не 2 последних курса, а 2 записи, если учесть что срез последних с отбором по валюте вернет нам 1 запись, то выберем одну.

"ВЫБРАТЬ        //Предпоследние
|    ВложенныйЗапрос.РежимПотребления,
|    ПериодыСтабильностиАбонентов.Действует
|ИЗ
|    (ВЫБРАТЬ
|        ПериодыСтабильностиАбонентов.РежимПотребления КАК РежимПотребления,
|        КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ПериодыСтабильностиАбонентовСрезПоследних.Период) КАК Период
|    ИЗ
|        РегистрСведений.ПериодыСтабильностиАбонентов КАК ПериодыСтабильностиАбонентов
|            ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПериодыСтабильностиАбонентов.СрезПоследних КАК ПериодыСтабильностиАбонентовСрезПоследних
|            ПО ПериодыСтабильностиАбонентов.Период < ПериодыСтабильностиАбонентовСрезПоследних.Период
|                И ПериодыСтабильностиАбонентов.РежимПотребления < ПериодыСтабильностиАбонентовСрезПоследних.РежимПотребления
|    
|    СГРУППИРОВАТЬ ПО
|        ПериодыСтабильностиАбонентов.РежимПотребления) КАК ВложенныйЗапрос
|        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПериодыСтабильностиАбонентов КАК ПериодыСтабильностиАбонентов
|        ПО ВложенныйЗапрос.РежимПотребления = ПериодыСтабильностиАбонентов.РежимПотребления
|            И ВложенныйЗапрос.Период = ПериодыСтабильностиАбонентов.Период
|
|ОБЪЕДИНИТЬ ВСЕ
|              //Последние
|ВЫБРАТЬ
|    ПериодыСтабильностиАбонентовСрезПоследних.РежимПотребления,
|    ПериодыСтабильностиАбонентовСрезПоследних.Действует
|ИЗ
|    РегистрСведений.ПериодыСтабильностиАбонентов.СрезПоследних КАК ПериодыСтабильностиАбонентовСрезПоследних"

(18) +1

+ ТОлько не Количество(Различные) а Максимум. Писа быстро и без проверок. Но идея должна быть понятна.

(18) > (10), говорил уж что последние записи вернёт. Да и курсы валют меняются каждый день по факту, одинаковых небывает вроде)

(18) Две записи равны двум курсам , так каку валюты курс на каждый день свой назначается

можно так:

(24) Не так нельзя

ВЫБРАТЬ
   КурсыВалютСрезПоследних.Период,
   КурсыВалютСрезПоследних.Валюта,
   КурсыВалютСрезПоследних.Курс
ПОМЕСТИТЬ ВТ_ПоследнийКурс
ИЗ
   РегистрСведений.КурсыВалют.СрезПоследних(, ) КАК КурсыВалютСрезПоследних
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   МАКСИМУМ(КурсыВалют.Период) КАК Период,
   КурсыВалют.Валюта
ПОМЕСТИТЬ ВТ_Предпоследние
ИЗ
   ВТ_ПоследнийКурс КАК ВТ_ПоследнийКурс
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК КурсыВалют
       ПО (КурсыВалют.Валюта = ВТ_ПоследнийКурс.Валюта)
           И (КурсыВалют.Период < ВТ_ПоследнийКурс.Период)

СГРУППИРОВАТЬ ПО
   КурсыВалют.Валюта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   КурсыВалют.Период,
   КурсыВалют.Валюта,
   КурсыВалют.Курс
ПОМЕСТИТЬ ВТ_ПредпоследнийКурс
ИЗ
   РегистрСведений.КурсыВалют КАК КурсыВалют
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Предпоследние КАК ВТ_Предпоследние
       ПО КурсыВалют.Валюта = ВТ_Предпоследние.Валюта
           И КурсыВалют.Период = ВТ_Предпоследние.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТ_ПоследнийКурс.Период КАК Период,
   ВТ_ПоследнийКурс.Валюта КАК Валюта,
   ВТ_ПоследнийКурс.Курс
ИЗ
   ВТ_ПоследнийКурс КАК ВТ_ПоследнийКурс

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   ВТ_ПредпоследнийКурс.Период,
   ВТ_ПредпоследнийКурс.Валюта,
   ВТ_ПредпоследнийКурс.Курс
ИЗ
   ВТ_ПредпоследнийКурс КАК ВТ_ПредпоследнийКурс

УПОРЯДОЧИТЬ ПО
   Валюта,
   Период




возможно, слишком навороченый...

(25) да... пальцы шаловливые))0

Я бы как-то так написал:
ВЫБРАТЬ ПЕРВЫЕ 4    NULL КАК Евро,
   КурсыВалютСрезПоследних.Валюта КАК Доллар,
   КурсыВалютСрезПоследних.Курс
ИЗ
   РегистрСведений.КурсыВалют КАК КурсыВалютСрезПоследних
ГДЕ
   КурсыВалютСрезПоследних.Валюта = &Доллар

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ ПЕРВЫЕ 2
   КурсыВалютСрезПоследних.Валюта,
   NULL,
   КурсыВалютСрезПоследних.Курс
ИЗ
   РегистрСведений.КурсыВалют КАК КурсыВалютСрезПоследних
ГДЕ
   КурсыВалютСрезПоследних.Валюта = &Евро

(26) Тоже что и (19) ТОлько слишком много временных таблиц..

(29) "мы без трудностей не можем, мы их сами создаем" (с)

Если хочется для всех имеющихся валют, то просто выполнять вот такой запрос:

ВЫБРАТЬ ПЕРВЫЕ 2
   КурсыВалютСрезПоследних.Валюта КАК ЗНАЧЕНИЕ(КурсыВалютСрезПоследних.Валюта),
   КурсыВалютСрезПоследних.Курс
ИЗ
   РегистрСведений.КурсыВалют КАК КурсыВалютСрезПоследних
ГДЕ
   КурсыВалютСрезПоследних.Валюта = &Валюта


для каждого непомеченного на удаление элемента справочника Валюты.

Вернее такой вот:
ВЫБРАТЬ ПЕРВЫЕ 2
   КурсыВалютСрезПоследних.Валюта КАК ЗНАЧЕНИЕ(КурсыВалютСрезПоследних.Валюта.НаименованиеПолное),
...

(28)(31) о )появляются таланты )

Ну... я запрос не проверял... это так, идея только :-)

(26) Вроде получилось, сенкс

Не уверен, что синоним можно выражением формировать... ну-ка, проверю...

(36) нельзя конечно

(35) Эх а мое творчество оказалось не заметным ? )))

(26) медленно работать будет.

(39) Оптимизировать можно.

(40) я знаю )

(41) далеко можно не смотреть и увидеть, что
ВЫБРАТЬ
   МАКСИМУМ(КурсыВалют.Период) КАК Период,
   КурсыВалют.Валюта
ПОМЕСТИТЬ ВТ_Предпоследние
ИЗ
   ВТ_ПоследнийКурс КАК ВТ_ПоследнийКурс
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК КурсыВалют
       ПО (КурсыВалют.Валюта = ВТ_ПоследнийКурс.Валюта)
           И (КурсыВалют.Период < ВТ_ПоследнийКурс.Период)

СГРУППИРОВАТЬ ПО
   КурсыВалют.Валюта
;
этот кусок можно оптимизировать ого-го

(38) твое творчество я ща проверила... возвращает в обоих случаях последний курс... так что... ))

(42) ну, началось... я ж на скорую руку... )))

(43) Я давал идею.

(45) твоя идея возвращает последнюю запись

(42) Интересно что хочешь оптимизировать именно в этом куске?

(47) подумал, я был неправ.

(26) Ты сама придумала или где то уже есть?

(49) эээ... сама... ))

(50) Все получилось, спасибо

(49) не верится?)))

(52) Стыдно признаться, но я только что узнал, чтоб временные таблицы можно использовать внутри запроса

(45) пересмотрела твой запрос. строчку
КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ПериодыСтабильностиАбонентовСрезПоследних.Период) КАК Период
заменить на
КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ПериодыСтабильностиАбонентов.Период) КАК Период

и все получилось

(51) так что, если запрос NcSteel реально работает быстрее моего, то  лучше его переписать и юзать

(38) Блин, у меня с абстракцией плохо

(56) держи переделанный запрос NcSteel


ВЫБРАТЬ        //Предпоследние

   ВложенныйЗапрос.Валюта,
   КурсыВалют.Курс
ИЗ
   (ВЫБРАТЬ
       КурсыВалют.Валюта КАК Валюта,
       МАКСИМУМ(КурсыВалют.Период) КАК Период
   ИЗ
       РегистрСведений.КурсыВалют КАК КурсыВалют
           ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют.СрезПоследних КАК КурсыВалютСрезПоследних
           ПО КурсыВалют.Валюта = КурсыВалютСрезПоследних.Валюта
            И КурсыВалют.Период < КурсыВалютСрезПоследних.Период
   
   СГРУППИРОВАТЬ ПО
       КурсыВалют.Валюта) КАК ВложенныйЗапрос
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК КурсыВалют
       ПО ВложенныйЗапрос.Валюта = КурсыВалют.Валюта
           И ВложенныйЗапрос.Период = КурсыВалют.Период

ОБЪЕДИНИТЬ ВСЕ
             //Последние

ВЫБРАТЬ
   КурсыВалютСрезПоследних.Валюта,
   КурсыВалютСрезПоследних.Курс
ИЗ
   РегистрСведений.КурсыВалют.СрезПоследних КАК КурсыВалютСрезПоследних

(57) А меня лень обуяла )))

(58) а мне работать не кайф ))

Вариант с коррелированным запросом в соединении
ВЫБРАТЬ
   КурсыВалютСрезПоследних.Валюта,
   КурсыВалютСрезПоследних.Период КАК ПоследняяДата,
   КурсыВалют.Период КАК ПредпоследняяДата,
   КурсыВалютСрезПоследних.Курс КАК ПоследнийКурс,
   КурсыВалют.Курс КАК ПредпоследнийКурс
ИЗ
   РегистрСведений.КурсыВалют.СрезПоследних КАК КурсыВалютСрезПоследних
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК КурсыВалют
       ПО ((КурсыВалют.Валюта, КурсыВалют.Период) В
               (ВЫБРАТЬ
                   КурсыВалют.Валюта,
                   МАКСИМУМ(КурсыВалют.Период) КАК Период
               ИЗ
                   РегистрСведений.КурсыВалют КАК КурсыВалют
               ГДЕ
                   КурсыВалют.Период < КурсыВалютСрезПоследних.Период
                   И КурсыВалют.Валюта = КурсыВалютСрезПоследних.Валюта
               СГРУППИРОВАТЬ ПО
                           КурсыВалют.Валюта))

Самый элегантный вариант - коррелированным подзапросом с ВЫБРАТЬ ПЕРВЫЕ 2

Вот он:
ВЫБРАТЬ
   ТаблицаРегистра.Период,
   ТаблицаРегистра.Валюта,
   ТаблицаРегистра.Курс
ИЗ
   РегистрСведений.КурсыВалют КАК ТаблицаРегистра
ГДЕ
   (ТаблицаРегистра.Валюта, ТаблицаРегистра.Период) В
           (ВЫБРАТЬ ПЕРВЫЕ 2
               КурсыВалют.Валюта,
               КурсыВалют.Период КАК Период
           ИЗ
               РегистрСведений.КурсыВалют КАК КурсыВалют
           ГДЕ
               КурсыВалют.Валюта = ТаблицаРегистра.Валюта
           УПОРЯДОЧИТЬ ПО
               Период УБЫВ)

Это самый короткий вариант видимо

Достаточно просто

ВЫБРАТЬ
   ТаблицаРегистра.Период,
   ТаблицаРегистра.Валюта,
   ТаблицаРегистра.Курс
ИЗ
   РегистрСведений.КурсыВалют КАК ТаблицаРегистра
ГДЕ
   ТаблицаРегистра.Период В
           (ВЫБРАТЬ ПЕРВЫЕ 2
               КурсыВалют.Период КАК Период
           ИЗ
               РегистрСведений.КурсыВалют КАК КурсыВалют
           ГДЕ
               КурсыВалют.Валюта = ТаблицаРегистра.Валюта
           УПОРЯДОЧИТЬ ПО
               Период УБЫВ)

(64) а если валют все-таки не 2, а 3? :)

Не имеет значения

(65) Цифра 2 относится к глубине выбираемой истории курсов по каждой валюте, а не к количеству валют :)

(64) Да

(66) сори, невнимательно смотрела)

(67) А если курс не менялся ?

Если требуется получить предыдущий отличный от последнего курс в варианте (60) можно можно добавить условие.

м.б. так:

ВЫБРАТЬ
   *
ПОМЕСТИТЬ Посл
ИЗ
   РегистрСведений.КурсыВалют.СрезПоследних(&Дата, ) КАК КурсыВалютСрезПоследних
;
ВЫБРАТЬ
   *
ИЗ
   Посл КАК Посл
   
ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   *
ИЗ
   РегистрСведений.КурсыВалют.СрезПоследних(
           &Дата,
           (НЕ (Период, Валюта) В
                   (ВЫБРАТЬ
                       Посл.Период,
                       Посл.Валюта
                   ИЗ
                       Посл КАК Посл))) КАК КурсыВалютСрезПоследних

(70) Тогда придется коррелированный подзапрос делать не по основной таблице регистра, а по подзапросу, возвращающему различные курсы.