@Echo Off
echo %date% %time% ***Start***
SetLocal EnableDelayedExpansion
Set $SRC=list_add.txt
Set $EXC=list_excl.txt
Set $DST=D:\backups

Set $COMPR=1
Set $COPIES=7
C:\"Program Files"\7-Zip\7z.exe a -t7z -mhe=on "%$DST%\files%DATE:~-4%-%DATE:~3,2%-%DATE:~0,2%_%TIME:~0,2%-%TIME:~3,2%-%TIME:~6,2%.7z" @%$SRC% -scsWIN  -mx=%$COMPR% -ssw -xr@%$EXC%
For /F "Delims=" %%i In ('DIR /B/O:-N %$DST%\files????-??-??_??-??-??.7z') Do (
Set /A $COPIES-=1
If !$COPIES! LSS 0 DEL "%$DST%\%%i"
)
echo %date% %time% ***End***

echo %date% %time% ***Start***
SetLocal EnableDelayedExpansion
Set $SRC=list_add2.txt
Set $EXC=list_excl2.txt
Set $DST=D:\backups2
Set $COMPR=1
Set $COPIES=7
C:\"Program Files"\7-Zip\7z.exe a -t7z -mhe=on "%$DST%\files%DATE:~-4%-%DATE:~3,2%-%DATE:~0,2%_%TIME:~0,2%-%TIME:~3,2%-%TIME:~6,2%.7z" @%$SRC% -scsWIN  -mx=%$COMPR% -ssw -xr@%$EXC%
For /F "Delims=" %%i In ('DIR /B/O:-N %$DST%\files????-??-??_??-??-??.7z') Do (
Set /A $COPIES-=1
If !$COPIES! LSS 0 DEL "%$DST%\%%i"
)
echo %date% %time% ***End***
Этот батник копирует всё что указано в list_add.txt и list_add2.txt
А если таких list_add.txt будет больше? Как организовать цикл?
То есть чтоб для всех list_addN.txt исполнялось.

(0)
тебе сюда
http://blogs.technet.com/b/eldar/archive/2006/08/30/444878.aspx

(1)Это не то,имхо.

(2)
в смысле не то ???
делай цикл
или ты не знаешь как у тебя файлы будут называться ?
тоесть не list_add5.txt а jhdueud.txt - так что ли ?

(3)Знаю.Не знаю сколько их будет.

(4)
for %%i in ("каталог\*.txt") do echo %%i

+(5) или так
for %%i in ("c:\mypapka\list_add*.txt") do echo %%i

В каталоге с батником лежат файлы list_addNN.txt.Нужно чтобы скрипт выполнял копирование файлов которые в них указаны в папки D:\backupsNN.

Можно ли как-то сделать цикл до NN
и в
Set $SRC=list_addNN.txt
Set $EXC=list_exclNN.txt
Set $DST=D:\backupsNN подставлять NN ?
Пусть даже NN известно.Это неважно.При отсутствии файла например list_add7.txt он все равно ничего не делает.

setlocal ENABLEDELAYEDEXPANSION
for /l %%i in (0,1,99) do (
   set /a n=100 + %%i
   echo !n:~1!
)

(8)Это цикл для n от 50 до 99?

от 0 до 99

если не нужен незначащий нуль убрать сет и оставить !н!

(11)А как это n подставить в названия файлов?

а так в (6)

(12) так и подставляй внутри цикала !n!

Set $SRC=list_add!n!txt
Set $EXC=list_excl!n!.txt
Set $DST=D:\backups!n! так что ли?

(15)

setlocal ENABLEDELAYEDEXPANSION
rem если нужны ведущие нули ставим 1
set null=0
for /l %%i in (0,1,99) do (
  set n=%%i
  if %null% equ 1 (
      set /a n=100 + !n!
      set n=!n:~1!
  )
  Set $SRC=list_add!n!txt
  Set $EXC=list_excl!n!.txt
  Set $DST=D:\backups!n!
  ...
  ...
)

+(6)

setlocal ENABLEDELAYEDEXPANSION
for %%i in ("%~dp0\list_add*.txt") do (
   set x=%%~ni
   Set $SRC=list_add!x!.txt
   Set $EXC=list_excl!x!.txt
   Set $DST=D:\backups!x!
   ...
   ...
)

вернее в (17)

setlocal ENABLEDELAYEDEXPANSION
for %%i in ("%~dp0\list_add*.txt") do (
   set x=%%~ni
   set x=!x:list_add=!
   Set $SRC=list_add!x!.txt
   Set $EXC=list_excl!x!.txt
   Set $DST=D:\backups!x!
   ...
   ...
)

echo %date% %time% ***Start***
setlocal ENABLEDELAYEDEXPANSION
for %%i in ("%~dp0\list_add*.txt") do (
   set x=%%~ni
   set x=!x:list_add=!
   Set $SRC=list_add!x!.txt
   Set $EXC=list_excl!x!.txt
   Set $DST=D:\backups!x!
   Set $COMPR=1
   Set $COPIES=7

C:\"Program Files"\7-Zip\7z.exe a -t7z -mhe=on "%$DST%\files%DATE:~-4%-%DATE:~3,2%-%DATE:~0,2%_%TIME:~0,2%-%TIME:~3,2%-%TIME:~6,2%.7z" @%$SRC% -scsWIN  -mx=%$COMPR% -ssw -xr@%$EXC%
For /F "Delims=" %%i In ('DIR /B/O:-N %$DST%\files????-??-??_??-??-??.7z') Do (
Set /A $COPIES-=1
If !$COPIES! LSS 0 DEL "%$DST%\%%i"
)
)
pause
echo %date% %time% ***End***
Так вот не получается.Инкорект лайн.

Простите если туплю.Просто если чтото доработать в скрипте я еще могу.То вот с таким не сталкивался вообще.

echo %date% %time% ***Start***
setlocal ENABLEDELAYEDEXPANSION
Set $COMPR=1
Set $COPIES=7
for %%i in ("%~dp0\list_add*.txt") do (
  set x=%%~ni
  set x=!x:list_add=!
  Set $SRC=list_add!x!.txt
  Set $EXC=list_excl!x!.txt
  Set $DST=D:\backups!x!

C:\"Program Files"\7-Zip\7z.exe a -t7z -mhe=on "!$DST!\files%DATE:~-4%-%DATE:~3,2%-%DATE:~0,2%_%TIME:~0,2%-%TIME:~3,2%-%TIME:~6,2%.7z" @!$SRC! -scsWIN  -mx=%$COMPR% -ssw -xr@!$EXC!
For /F "Delims=" %%i In ('DIR /B/O:-N !$DST!\files????-??-??_??-??-??.7z') Do (
Set /A $COPIES-=1
If !$COPIES! LSS 0 DEL "!$DST!\%%i"
)
)
pause
echo %date% %time% ***End***

при отложенном расширении переменных в циклах и прочих субшелах вместо процентов нужно использовать восклицательные знаки в тех переменных которые создаются/задаются в теле цыкла

результат то какой надо, может попросче сделать
лениво разбираться с семь зипом

(230Не,не работает(

Смысл такой.Есть вот этот скрипт.
echo %date% %time% ***Start***

SetLocal EnableDelayedExpansion
Set $SRC=list_add.txt
Set $EXC=list_excl.txt
Set $DST=D:\backups
Set $COMPR=1
Set $COPIES=7

C:\"Program Files"\7-Zip\7z.exe a -t7z -mhe=on "%$DST%\files%DATE:~-4%-%DATE:~3,2%-%DATE:~0,2%_%TIME:~0,2%-%TIME:~3,2%-%TIME:~6,2%.7z" @%$SRC% -scsWIN  -mx=%$COMPR% -ssw -xr@%$EXC%
For /F "Delims=" %%i In ('DIR /B/O:-N %$DST%\files????-??-??_??-??-??.7z') Do (
Set /A $COPIES-=1
If !$COPIES! LSS 0 DEL "%$DST%\%%i"
)
echo %date% %time% ***End***

Я хочу из реестра или v8i в txt скидывать пути к базам.А скрипт должен прочитать все тхт и запаковать базы по папкам.Так то он отлично работает.Количество копий указывается($COPIES=7).Исключения(list_excl!x!.txt).Сжатие.
Вот с тхт только загвоздка.

Если его допилить.Да еще и читать данные о базах из реестра.То в книгу знаний попадет скрипт этот)Имхо он удобный.

При копировании с форума в концах строк удаляй пробел, он возникает

echo off
echo %date% %time% ***Start***
setlocal ENABLEDELAYEDEXPANSION
Set $COMPR=1
Set $COPIES=7
for %%i in ("%~dp0\list_add*.txt") do (
   set x=%%~ni
   set x=!x:list_add=!
   Set $SRC=%~dp0\list_add!x!.txt
   Set $EXC=%~dp0\list_excl!x!.txt
   Set $DST=D:\backups!x!
   set xyear=%date:~-4%
   set xmon=%date:~-3,2%
   set xday=%date:~-0,2%
   set xtime=%time::=-%
   set xtime=%time:,=-%
   set xdatetime=!xyear!-!xmon!_!xday!-!xtime!
   start "" /b "C:\Program Files\7-Zip\7z.exe" a -t7z -mhe=on "!$DST!\files!xdatetime!.7z" @"!$SRC!" -scsWIN  -mx=%$COMPR% -ssw -xr@"!$EXC!"
   for %%x in ("!$DST!\files????-??-??_??-??-??-??.7z") Do (
       Set /A $COPIES-=1
       If !$COPIES! LSS 0 DEL /q "!$DST!\%%i"
   )
)
echo %date% %time% ***End***
pause


set xdatetime=!xyear!-!xmon!_!xday!-!xtime!

заменить на

set xdatetime=!xyear!-!xmon!-!xday!_!xtime!

+ start "" /b - не обязательно, 7з.ехе консольное оказывается

echo off
23.08.2011 14:03:09,95 ***Start***
23.08.2011 14:03:09,96 ***End***
Для продолжения нажмите любую клавишу . . .
7-Zip 9.20  Copyright (c) 1999-2010 Igor Pavlov  2010-11-18

7-Zip 9.20  Copyright (c) 1999-2010 Igor Pavlov  2010-11-18
ScanningScanning

Creating archive D:\backups2\files2011-01-23_14:03:09-95.7z



Creating archive D:\backups\files2011-01-23_14:03:09-95.7z


Error:

Error:
7-Zip cannot open file
D:\backups\files2011-01-23_14:03:09-95.7z
Параметр задан неверно.

7-Zip cannot open file
D:\backups2\files2011-01-23_14:03:09-95.7z
Параметр задан неверно.





System error:System error:

Неопознанная ошибка
Неопознанная ошибка

Правда создал 2 пустых каталога как положено.

попутал сам ))

set xtime=%time::=-%
set xtime=!xtime:,=-!

echo off
echo %date% %time% ***Start***
setlocal ENABLEDELAYEDEXPANSION
Set $COMPR=1
Set $COPIES=7
for %%i in ("%~dp0\list_add*.txt") do (
   set x=%%~ni
   set x=!x:list_add=!
   Set $SRC=%~dp0\list_add!x!.txt
   Set $EXC=%~dp0\list_excl!x!.txt
   Set $DST=D:\backups!x!
   set xyear=%date:~-4%
   set xmon=%date:~-3,2%
   set xday=%date:~-0,2%
   set xtime=%time::=-%
   set xtime=!xtime:,=-!
   set xdatetime=!xyear!-!xmon!-!xday!_!xtime!
   start "" /b "C:\Program Files\7-Zip\7z.exe" a -t7z -mhe=on "!$DST!\files!xdatetime!.7z" @"!$SRC!"

-scsWIN  -mx=%$COMPR% -ssw -xr@"!$EXC!"
   for %%x in ("!$DST!\files????-??-??_??-??-??-??.7z") Do (
       Set /A $COPIES-=1
       If !$COPIES! LSS 0 DEL /q "!$DST!\%%i"
   )
)
echo %date% %time% ***End***

Спасибо большое.Всё вроде работает.Буду тестировать.
Дальше попробую пути к базам вытащить и засунуть.

наверное лучче вот так

set xdate=!date!
set xyear=!xdate:~-4!
set xmon=!xdate:~-3,2!
set xday=!xdate:~-0,2!
set xtime=!time::=-!
set xtime=!xtime:,=-!

вместо
set xyear=%date:~-4%
...

(34)А что это такое вообще? Чтоб имена файлов различались?

(35) если будут %date% %time% - то в цикле всегда одни и теже значения будут

а если !date! !time! то реальные (на сколько система позволяет) дата и время на каждый оборот цыкла

(34)Не катит - каждый раз создается файл files.7z

если интересует один файл по дате времени запуска пакетника, то вынести за цикл так

set xdate=%date%
set xyear=%xdate:~-4%
set xmon=%xdate:~-3,2%
set xday=%xdate:~-0,2%
set xtime=%time::=-%
set xtime=%xtime:,=-%
set xdatetime=%xyear%-%xmon%-%xday%_%xtime%

Блин,теперь старые не удаляет.

for %%x in ("!$DST!\files????-??-??_??-??-??-??.7z") Do (
      Set /A $COPIES-=1
      If !$COPIES! LSS 0 DEL /q "%%~i"
  )

вернее

for %%X in ("!$DST!\files????-??-??_??-??-??-??.7z") Do (
     Set /A $COPIES-=1
     If !$COPIES! LSS 0 DEL /q "%%~X"
 )

echo off
echo %date% %time% ***Start***
setlocal ENABLEDELAYEDEXPANSION
Set $COMPR=1
Set $COPIES=3
set xdate=%date%
set xyear=%xdate:~-4%
set xmon=%xdate:~-3,2%
set xday=%xdate:~-0,2%
set xtime=%time::=-%
set xtime=%xtime:,=-%
set xdatetime=%xyear%-%xmon%-%xday%_%xtime%
for %%i in ("%~dp0\list_add*.txt") do (
   set x=%%~ni
   set x=!x:list_add=!
   Set $SRC=%~dp0\list_add!x!.txt
   Set $EXC=%~dp0\list_excl!x!.txt
   Set $DST=D:\backups!x!
   
   start "" /b "C:\Program Files\7-Zip\7z.exe" a -t7z -mhe=on "!$DST!\files!xdatetime!.7z" @"!$SRC!" -scsWIN  -mx=%$COMPR% -ssw -xr@"!$EXC!"
)
for %%X in ("!$DST!\files????-??-??_??-??-??-??.7z") Do (
     Set /A $COPIES-=1
     If !$COPIES! LSS 0 DEL /q "%%~X"
 )
echo %date% %time% ***End***
если так то удаляет только из последней папки backup2

А если в общий цикл записать удаление то в одной папке 1 архив во второй 4 при копиес = 3

в тело цикла

...
start "" /b "C:\Program Files\7-Zip\7z.exe" a -t7z -mhe=on "!$DST!\files!xdatetime!.7z" @"!$SRC!" -scsWIN  -mx=%$COMPR% -ssw -xr@"!$EXC!"
for %%X in ("!$DST!\files????-??-??_??-??-??-??.7z") Do (
    Set /A $COPIES-=1
    If !$COPIES! LSS 0 DEL /q "%%~X"
)
)

нужно что удалять ?
самый ранний файл в каждой папке ?

(46)Да.

(46)Ой.Я наверно в одну минуту копии делал.Сейчас минуту ждать буду.

Нет.Все равно в одной 1 файл остается после 4го бэкапа а в другой четыре а должно 3 и 3.

Set /A $COPIES=7
for /f "delims=" %%X in ('dir /b /s /o:-n "!$DST!\files????-??-??_??-??-??-??.7z"') Do (
    Set /A $COPIES-=1
    If !$COPIES! LSS 0 DEL /q "%%~X"
)
)
echo %date% %time% ***End***

(50)К сожалению неправильно получается.

не верю

написал бы давно православный vbs... и возможностей больше и отладка проще...

(52)
echo off
echo %date% %time% ***Start***
setlocal ENABLEDELAYEDEXPANSION
Set $COMPR=1
set xdate=%date%
set xyear=%xdate:~-4%
set xmon=%xdate:~-3,2%
set xday=%xdate:~-0,2%
set xtime=%time::=-%
set xtime=%xtime:,=-%
set xdatetime=%xyear%-%xmon%-%xday%_%xtime%
for %%i in ("%~dp0\list_add*.txt") do (
  set x=%%~ni
  set x=!x:list_add=!
  Set $SRC=%~dp0\list_add!x!.txt
  Set $EXC=%~dp0\list_excl!x!.txt
  Set $DST=D:\backups!x!
 
  start "" /b "C:\Program Files\7-Zip\7z.exe" a -t7z -mhe=on "!$DST!\files!xdatetime!.7z" @"!$SRC!" -scsWIN  -mx=%$COMPR% -ssw -xr@"!$EXC!"
Set /A $COPIES=3
for /f "delims=" %%X in ('dir /b /s /o:-n "!$DST!\files????-??-??_??-??-??-??.7z"') Do (
   Set /A $COPIES-=1
   If !$COPIES! LSS 0 DEL /q "%%~X"
)
)
echo %date% %time% ***End***
Так все работает.Это я на работе неправильно что-то накопипастил.Только копий делает 4 при выставленных 3-х.Но это же неплохо.Спасибо еще раз.

(53)Отец у меня католик.И я наверно в душе тоже.

(53)А что в vbs проще?