Например есть строка - "Иванов;Петров;Сидоров"
Надо их конвертировать в список значений или массив типа:

Иванов
Петров
Сидоров

В семерке есть встроенная функция для разложения, а в восьмерке есть?

напишешь будет

Встроенной нет, типовая - есть.

замени ; на Символы.ПС

многострочную строку не предлагали ещё?

// Функция "расщепляет" строку на подстроки, используя заданный
//        разделитель. Разделитель может иметь любую длину.
//        Если в качестве разделителя задан пробел, рядом стоящие пробелы
//        считаются одним разделителем, а ведущие и хвостовые пробелы параметра Стр
//        игнорируются.
//        Например,
//        РазложитьСтрокуВМассивПодстрок(",ку,,,му", ",") возвратит массив значений из пяти элементов,
//        три из которых - пустые строки, а
//        РазложитьСтрокуВМассивПодстрок(" ку   му", " ") возвратит массив значений из двух элементов
//
//    Параметры:
//        Стр -            строка, которую необходимо разложить на подстроки.
//                        Параметр передается по значению.
//        Разделитель -    строка-разделитель, по умолчанию - запятая.
//
//
//    Возвращаемое значение:
//        массив значений, элементы которого - подстроки
//
Функция РазложитьСтрокуВМассивПодстрок(Знач Стр, Разделитель = ",") Экспорт
   
   МассивСтрок = Новый Массив();
   Если Разделитель = " " Тогда
       Стр = СокрЛП(Стр);
       Пока 1=1 Цикл
           Поз = Найти(Стр,Разделитель);
           Если Поз=0 Тогда
               МассивСтрок.Добавить(Стр);
               Возврат МассивСтрок;
           КонецЕсли;
           МассивСтрок.Добавить(Лев(Стр,Поз-1));
           Стр = СокрЛ(Сред(Стр,Поз));
       КонецЦикла;
   Иначе
       ДлинаРазделителя = СтрДлина(Разделитель);
       Пока 1=1 Цикл
           Поз = Найти(Стр,Разделитель);
           Если Поз=0 Тогда
               МассивСтрок.Добавить(Стр);
               Возврат МассивСтрок;
           КонецЕсли;
           МассивСтрок.Добавить(Лев(Стр,Поз-1));
           Стр = Сред(Стр,Поз+ДлинаРазделителя);
       КонецЦикла;
   КонецЕсли;
   
КонецФункции // глРазложить

(4) "многострочную строку"....
Epic-fail: autorecursion detected. Not enough memory.

(5) разрабам за кол-во строк платят. вот и объяснение

(6) <Номер строки> (обязательный)
Тип: Число. Номер получаемой строки. Нумерация строк в многострочной строке начинается с 1. © СП ;)

(8) я и говорю: Epic-fail ;-)

по логике, это должен быть многострочный текст

Функция РазборСтроки(знач Стр, Разделитель = "," ) Экспорт
   
   #Если Не ( ТонкийКлиент ИЛИ ВебКлиент ) Тогда
       
       // РазбираемаяСтрока - строка исходного текста
       // Разделитель - разделитель элементов строки
       Возврат ЗначениеИзСтрокиВнутр("{""#"",51e7a0d2-530b-11d4-b98a-008048da3034,{0,{""S"",""" + СтрЗаменить(СтрЗаменить( Стр , """", """"""), Разделитель, """},{""S"",""") + """}}}");
       
       
   #Иначе
       
       МассивЗначений = Новый Массив;
       
       Символ = Найти(Стр, Разделитель);
       
       Пока Символ > 0 Цикл
           
           МассивЗначений.Добавить(Лев(Стр, Символ - 1));
           
           Стр = Прав(Стр, СтрДлина(Стр) - Символ);
           
           Символ = Найти(Стр, Разделитель);
           
       КонецЦикла;
       
       МассивЗначений.Добавить(Стр);
       
       Возврат МассивЗначений;
       
   #КонецЕсли
   
КонецФункции

Всем спасибо, коллеги!

(0)
   стр = "Иванов;Петров;Сидоров";
   СтрЗаменить(стр,";",Символы.ПС);
   Для ч = 1 По СтрЧислоСтрок(стр) Цикл
       Ф = СтрПолучитьСтроку(стр,ч)    
   КонецЦикла;