День добрый нужно сделать отчет чтобы с группировкой по подразделениям и статьям расходов, и колонка где совмещены 2 счета оборотКт 50 посубконто 1, и оборот Кт 51 субконто2, соотвецтвенно субконто 1 50счета и субконто 2 51 совпадают это-статьи расходов .С отбором по подразделениям разобрался не выходит 2 счета загнать в одну колонку.

Запрос на данный момент такой , получилсятолько по 51 счету


Запрос = Новый Запрос;
   Запрос.Текст =
   "ВЫБРАТЬ
   |    ПодразделенияОрганизаций.Ссылка КАК Подразделение,
   |    ПодразделенияОрганизаций.Представление,
   |    ХозрасчетныйОстаткиИОбороты.Субконто2 КАК Субконто2,
   |    ПРЕДСТАВЛЕНИЕ(ХозрасчетныйОстаткиИОбороты.Субконто2),
   
   //|   ВЫБОР      

   //|     КОГДА ХозрасчетныйОстаткиИОбороты.счет=&счет

   //|         тогда ХозрасчетныйОстаткиИОбороты.Субконто2

   //|         Конец как субконто2,

   //|   ВЫБОР      

   //|     КОГДА ХозрасчетныйОстаткиИОбороты.счет=&счет2

   //|         тогда ХозрасчетныйОстаткиИОбороты.Субконто1

   //|         Конец как субконто1,

   
   
   |   ВЫБОР      
   |     КОГДА ХозрасчетныйОстаткиИОбороты.счет=&счет
   |         тогда СУММА(ХозрасчетныйОстаткиИОбороты.СуммаОборотКт)
   |         иначе 0
   |     Конец как СуммаОборотКт,
       
   |   ВЫБОР      
   |     КОГДА ХозрасчетныйОстаткиИОбороты.счет=&счет2
   |         тогда СУММА(ХозрасчетныйОстаткиИОбороты.СуммаОборотКт)
   |         иначе 0
   |     Конец как СуммаОборотКт50,

   
   |    СУММА(ХозрасчетныйОстаткиИОбороты.СуммаОборотДт) КАК СуммаОборотДт,
   |    СУММА(ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокДт) КАК СуммаКонечныйОстатокДт,
   |    СУММА(ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокКт) КАК СуммаКонечныйОстатокКт
   |ИЗ
   |    Справочник.ПодразделенияОрганизаций КАК ПодразделенияОрганизаций
   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
   |                &ДатаНач,
   |                &ДатаКон,
   |                День,
   |                ,
   |                Счет В (&Счет, &Счет2),
   |                ,
   |                Подразделение В ИЕРАРХИИ (&подротбор)
   |                    И организация = &организация) КАК ХозрасчетныйОстаткиИОбороты
   |        ПО ПодразделенияОрганизаций.Ссылка = ХозрасчетныйОстаткиИОбороты.Подразделение.Ссылка
   |ГДЕ
   |    ПодразделенияОрганизаций.Ссылка В ИЕРАРХИИ(&подротбор)
   |    И (НЕ ПодразделенияОрганизаций.Ссылка В ИЕРАРХИИ (&ПодрИсключение))
   |
   |СГРУППИРОВАТЬ ПО
   |    ПодразделенияОрганизаций.Ссылка,
   |    Субконто2,
   //|    Субконто1,

   |    ПодразделенияОрганизаций.Представление,
   |   ХозрасчетныйОстаткиИОбороты.Счет
   |УПОРЯДОЧИТЬ ПО
   |    Подразделение,
   |    Субконто2
   |ИТОГИ
   |    СУММА(СуммаОборотДт),
   |    СУММА(СуммаОборотКт),
   |    СУММА(СуммаКонечныйОстатокДт),
   |    СУММА(СуммаКонечныйОстатокКт),
   |    СУММА(СуммаОборотКт50)
   |ПО
   |    ОБЩИЕ,
   |    Подразделение ИЕРАРХИЯ,
   |    Субконто2
   |АВТОУПОРЯДОЧИВАНИЕ";

скд, а ручками тут полдня будут ваять

объединение тебе поможет. Сначала данные

50 счета первым запросом снимешь и объединишься со вторым где 51 счет. Стоп, а что за подразделения? Они там с каких счетов вылезли?

Я тоже думаю об объединении но ещё этой командой не разу не приходилось пользоваться,изучаю, а подразделения идут в реквизитах счёта так как конфа-Бухгалтерия КОРП и у каждого счета есть реквизит подразделение-доп аналитика

Вот ещё прикидываю может вместо подразделения справочник статьи расходов поставить, и левое соединение к регистру сделать, вобщем ещё ясной картины нет, если возможно короткий пример

Делаю через конструктор иногда руками корректирую, и проверяю вход в конструктор

ВЫБРАТЬ
  ХозрасчетныйОстаткиИОбороты.Период КАК Период,
  ПодразделенияОрганизаций.Ссылка КАК Подразделение,
  ХозрасчетныйОстаткиИОбороты.Субконто1 КАК СтатьяРасходов,
  ХозрасчетныйОстаткиИОбороты.СуммаОборотДт КАК СуммаОборотДт,
  ХозрасчетныйОстаткиИОбороты.СуммаОборотКт КАК СуммаОборотКт,
  ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокДт КАК СуммаКонечныйОстатокДт,
  ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокКт КАК СуммаКонечныйОстатокКт
ИЗ
  Справочник.ПодразделенияОрганизаций КАК ПодразделенияОрганизаций
    ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
  &ДатаНачала,
  &ДатаОкончания,
  День,
  ДвиженияИГраницыПериода,
  Счет = &Счет50 ИЛИ Счет = &Счет51,
  ЗНАЧЕНИЕ(ПланВидовХарактеристи.ВидыСубконтоХозрасчетные.СтатьиРасходов),) КАК ХозрасчетныйОстаткиИОбороты
    ПО (ХозрасчетныйОстаткиИОбороты.Подразделение = ПодразделенияОрганизаций.Ссылка)
ИТОГИ
  СУММА(СуммаОборотДт),
  СУММА(СуммаОборотКт),
  СУММА(СуммаКонечныйОстатокДт),
  СУММА(СуммаКонечныйОстатокКт)
ПО
  ОБЩИЕ,
  Подразделение ИЕРАРХИЯ,
  СтатьяРасходов,
  Период ПЕРИОДАМИ(ДЕНЬ, &ДатаНачала, &ДатаОкончания)

Ага, гляну у меня примерно так получилось, буду проверять

Запрос = Новый Запрос;
   Запрос.Текст =
   "ВЫБРАТЬ
   |    ПодразделенияОрганизаций.Ссылка КАК Подразделение,
   |    ПодразделенияОрганизаций.Представление,
   |    ХозрасчетныйОстаткиИОбороты.Субконто2 КАК Субконто2,
   |    ПРЕДСТАВЛЕНИЕ(ХозрасчетныйОстаткиИОбороты.Субконто2),
   |    СУММА(ХозрасчетныйОстаткиИОбороты.СуммаОборотКт) КАК суммаОборотКт,
   |    СУММА(ХозрасчетныйОстаткиИОбороты.СуммаОборотДт) КАК СуммаОборотДт,
   |    СУММА(ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокДт) КАК СуммаКонечныйОстатокДт,
   |    СУММА(ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокКт) КАК СуммаКонечныйОстатокКт,
   |    NULL КАК Субконто1
   |ИЗ
   |    Справочник.ПодразделенияОрганизаций КАК ПодразделенияОрганизаций
   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
   |                &ДатаНач,
   |                &ДатаКон,
   |                День,
   |                ,
   |                Счет В (&Счет),
   |                ,
   |                Подразделение В ИЕРАРХИИ (&подротбор)
   |                    И организация = &организация) КАК ХозрасчетныйОстаткиИОбороты
   |        ПО ПодразделенияОрганизаций.Ссылка = ХозрасчетныйОстаткиИОбороты.Подразделение.Ссылка
   |ГДЕ
   |    ПодразделенияОрганизаций.Ссылка В ИЕРАРХИИ(&подротбор)
   |    И (НЕ ПодразделенияОрганизаций.Ссылка В ИЕРАРХИИ (&ПодрИсключение))
   |
   |СГРУППИРОВАТЬ ПО
   |    ПодразделенияОрганизаций.Ссылка,
   |    ХозрасчетныйОстаткиИОбороты.Субконто2,
   |    ПодразделенияОрганизаций.Представление,
   |    ХозрасчетныйОстаткиИОбороты.Счет
   |
   |ОБЪЕДИНИТЬ ВСЕ
   |
   |ВЫБРАТЬ
   |    ПодразделенияОрганизаций.Ссылка,
   |    NULL,
   |    NULL,
   |    NULL,
   |    ХозрасчетныйОстаткиИОбороты.СуммаОборотКт,
   |    NULL,
   |    NULL,
   |    NULL,
   |    ХозрасчетныйОстаткиИОбороты.Субконто1
   |ИЗ
   |    Справочник.ПодразделенияОрганизаций КАК ПодразделенияОрганизаций
   |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
   |                &ДатаНач,
   |                &ДатаКон,
   |                День,
   |                ,
   |                Счет В (&Счет2),
   |                ,
   |                Подразделение В ИЕРАРХИИ (&подротбор)
   |                    И организация = &организация) КАК ХозрасчетныйОстаткиИОбороты
   |        ПО ПодразделенияОрганизаций.Ссылка = ХозрасчетныйОстаткиИОбороты.Субконто1
   |
   |СГРУППИРОВАТЬ ПО
   |    ПодразделенияОрганизаций.Ссылка,
   |    ХозрасчетныйОстаткиИОбороты.Субконто1,
   |    ХозрасчетныйОстаткиИОбороты.СуммаОборотКт
   |
   |УПОРЯДОЧИТЬ ПО
   |    Подразделение,
   |    Субконто2
   |ИТОГИ
   |    СУММА(суммаОборотКт),
   |    СУММА(СуммаОборотДт),
   |    СУММА(СуммаКонечныйОстатокДт),
   |    СУММА(СуммаКонечныйОстатокКт)
   |ПО
   |    ОБЩИЕ,
   |    Подразделение ИЕРАРХИЯ,
   |    Субконто2
   |АВТОУПОРЯДОЧИВАНИЕ";

   Запрос.УстановитьПараметр("ДатаКон", КонецДня(ДатаКон));
   Запрос.УстановитьПараметр("ДатаНач", НачалоДня(ДатаНач));
   Запрос.УстановитьПараметр("организация", организация);
   Запрос.УстановитьПараметр("подротбор", подротбор);
   Запрос.УстановитьПараметр("Счет", Счет);
   Запрос.УстановитьПараметр("ПодрИсключение",ПодрКоллекторы );
   Запрос.установитьПараметр("Счет2",Счет2);
   
   Результат = Запрос.Выполнить();

(8) это у меня уже есть) с этого и вопрос начал

Уточню нужен только Ктоборот остальные поля вобщем то уберу из запроса

(9) Всё делается проще. См (8)

Есть у таблицы ОстаткиИОбоороты параметр ВидСубконто.

Установив это параметр ЗНАЧЕНИЕ(ПланВидовХарактеристи.ВидыСубконтоХозрасчетные.СтатьиРасходов), ты упорядочиваешь субконто на счетах. Т.е. первым субконто будут идти СтатьиРасходов вне зависимости от того, в каком порядке они живут на счете - вторым субконто или хоть третьим.

(12) ок поразбираюсь

(9) если укажу учловие для счета счет в (&счет50,&счет51) это равноценно в данном случае счет 50 или счет51

(14) Равноценно.

хорошо, позже напишу что получится)

(16) Кстати. Не понял тебе итог по дням нужен или нет?

В запросе параметрах таблицы выборка с периодичностью "ДЕНЬ", а в итогах периода нет.

Нужен за месяц но лучше чтобы была возможность и за сроки меньше месяца

а значение в конструкторе где указать, в параметрах вирт.таблицы есть субконто, это там?

ещё момент что в 50 счете это субконто 1 а в 51 субконто2

чёт со значением не получается пишет неверные параметры регистра бухгалтерии

Я не совсем понял что тебе надо, мб вот это:
   |   ВЫБОР      
   |     КОГДА ХозрасчетныйОстаткиИОбороты.счет=&счет
   |         тогда ХозрасчетныйОстаткиИОбороты.Субконто2
          КОГДА ХозрасчетныйОстаткиИОбороты.счет=&счет2
   |         тогда ХозрасчетныйОстаткиИОбороты.Субконто1
   |   Конец как СтатьяДДС,

(20) Читай внимательно (12) до просветления.

(22) Тоже почитай (12)

ВЫБРАТЬ
 ХозрасчетныйОстаткиИОбороты.Период КАК Период,
 ПодразделенияОрганизаций.Ссылка КАК Подразделение,
 ХозрасчетныйОстаткиИОбороты.Субконто1 КАК СтатьяРасходов,
 ХозрасчетныйОстаткиИОбороты.СуммаОборотКт КАК СуммаОборотКт
ИЗ
 Справочник.ПодразделенияОрганизаций КАК ПодразделенияОрганизаций
   ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
     &ДатаНачала,
     &ДатаОкончания,
     ,
     ,
     Счет = &Счет50 ИЛИ Счет = &Счет51,
     &СубконтоСтатьиРасходов,) КАК ХозрасчетныйОстаткиИОбороты
    ПО (ХозрасчетныйОстаткиИОбороты.Подразделение = ПодразделенияОрганизаций.Ссылка)
ИТОГИ
  СУММА(СуммаОборотКт)
ПО
  ОБЩИЕ,
  Подразделение ИЕРАРХИЯ,
  СтатьяРасходов

МассивСубконто = Новый Массив;
МассивСубконто.Добавить(ПалыВидовХарактеристи.ВидыСубконтоХозрасчетные.СтатьиРасходов);
Запрос.УстановитьПарамтер("СубконтоСтатьиРасходов", МассивСубконто);

(23) будем просвещаться но такого параметра в таблице пока не нашёл

(22) посмотрю)

(26) В конструкторе параметр "Субконто"

(25) более понятно)

(27) Из примера в (25) надо убрать поле Период.

(27)у меня вобщем то этого поля  и нет

Может я не до конца понимаю в запросе строка
ХозрасчетныйОстаткиИОбороты.Субконто1 КАК СтатьяРасходов
поймёт ли запрос что по 51 нужно субконто 2 брать параметр
СубконтоСтатьиРасходов всё устаканит

(32) >> поймёт ли запрос что по 51 нужно субконто 2

Перечитай (12) еще 38 раз.:

Установив это параметр ты УПОРЯДОЧИВАЕШЬ СУБКОНТО НА СЧЕТАХ.
Т.е. первым субконто в выборке будут идти СтатьиРасходов ВНЕ ЗАВИСИМОСТИ ОТ ТОГО, В КАКОМ ПОРЯДКЕ ОНИ ЖИВУТ НА СЧЕТЕ - вторым субконто или хоть третьим.

+ к (33) выдержка из справки:
Параметр
Субконто (необязательный)

Тип параметра: ПланВидовХарактеристикСсылка.; Массив; ФиксированныйМассив. Ссылка, или массив ссылок, или фиксированный массив ссылок на виды субконто.

Задает набор и ПОРЯДОК субконто, которыми можно оперировать в запросе.

Вобщем всё нормуль спасибо)) проверяю цифры по 2 счетам

Ну и итоговые цифры тоже сходятся))

Только одно субконто лишнее в отчет залезло -Банковские счета, ещё буду смотреть кеак избавиться