v7: Неполадки с Rom-mail.dll

Вдогонку:
Сервер win2003 standart sp2, 1с7 версия 7.70.025, код, связаный с Rom-mail.dll, следующий:
[code]
Процедура ПочтаПринять()

Протокол("Проверка почтового ящика " + НашЕмайл + "...");
Если НастроитьПочтовыйЯщик(0) = 0 Тогда
ФлОшибкиАвтообмен = 1;
Возврат;
КонецЕсли;

Если ПочтовыйЯщик.Подключиться("POP3") = 0 Тогда
Протокол("ОШИБКА!!! Не удалось подключится к серверу POP3");
ФлОшибкиАвтообмен = 1;
//ПочтовыйЯщик.Отключиться();
Возврат;
КонецЕсли;

// обработка сообщений
ТекстПисьма = СоздатьОбъект("Текст");

СчетчикФайлов = 0;
СчетчикЗапросов = 0;

ТекКолСообщений = ПочтовыйЯщик.КоличествоСообщений();
Для ТекНомерСообщения = 1 По ТекКолСообщений Цикл
Если ПочтовыйЯщик.ПолучитьЗаголовок(ТекНомерСообщения) = 0 Тогда Продолжить;
КонецЕсли;

// Анализ заголовка письма
ТекАдресОтправителя = СокрЛП(Нрег(ПочтовыйЯщик.АдресОтправителя));
ТекИмяОтправителя = СокрЛП(Нрег(ПочтовыйЯщик.ИмяОтправителя));
ТемаПисьма = Врег(СокрЛП(ПочтовыйЯщик.Тема));
ДатаПисьма = Дата(ПочтовыйЯщик.ДатаОтправки);
ИдПисьма = ПочтовыйЯщик.IDMessage;
Если ПустоеЗначение(ИдПисьма) = 1 Тогда
ИдПисьма = "БезИД" + Время1980();
КонецЕсли;

Протокол("Анализ письма: '" + Лев(ТемаПисьма, 100) + "' от " + Лев(ТекАдресОтправителя,50) + " (" + ДатаПисьма + ")");

ФлЗапросПринят = 0;
// Удаление сообщений "Mail Delivery System"
Если Найти(Врег(ТекИмяОтправителя),Врег("Mail Delivery")) <> 0 Тогда
ПочтовыйЯщик.ПометитьНаУдаление(ТекНомерСообщения);
Протокол("Mail Delivery - помечено на удаление");
Продолжить;
КонецЕсли;
Если Найти(Врег(ТемаПисьма),Врег("Mail Delivery")) <> 0 Тогда
ПочтовыйЯщик.ПометитьНаУдаление(ТекНомерСообщения);
Протокол("Mail Delivery - помечено на удаление");
Продолжить;
КонецЕсли;

// Анализ адреса отправителя
Если СписКлиентыЧерный.Принадлежит(ТекАдресОтправителя) <> 0 Тогда
ПочтовыйЯщик.ПометитьНаУдаление(ТекНомерСообщения);
Протокол("Включено в черный список - помечено на удаление");
Продолжить;
КонецЕсли;
Если СписКлиенты.Принадлежит(ТекАдресОтправителя) <> 0 Тогда
ФлЗапросПринят = 1;
Иначе
СпрКонтрагенты = СоздатьОбъект("Справочник.Контрагенты");
СпрКонтрагенты.ВыбратьЭлементы();
Пока СпрКонтрагенты.ПолучитьЭлемент() = 1 Цикл
Если СпрКонтрагенты.ЭтоГруппа() = 1 Тогда Продолжить;
ИначеЕсли Найти(Нрег(СпрКонтрагенты.ЭлПочта),ТекАдресОтправителя) = 0 Тогда Продолжить;
КонецЕсли;
ФлЗапросПринят = 1;
Прервать;
КонецЦикла;
КонецЕсли;

Если ФлЗапросПринят = 0 Тогда
Протокол("Неизвестный адрес отправителя!");
// Старые письма удаляем
Если ВыбДнейСпам = 0 Тогда Продолжить;
КонецЕсли;
Если ТекущаяДата() - ДатаПисьма < ВыбДнейСпам Тогда Продолжить;
КонецЕсли;
ПочтовыйЯщик.ПометитьНаУдаление(ТекНомерСообщения);
Протокол("Время хранения письма истекло - помечено на удаление");
Продолжить;
КонецЕсли;

Если ПочтовыйЯщик.ПолучитьТело(ТекНомерСообщения) = 0 Тогда
Протокол("ОШИБКА!!! Не удалось получить тело письма");
ФлОшибкиАвтообмен = 1;
Продолжить;
КонецЕсли;

// Запись тела письма
ПрефиксПисьма = ПолучитьПрефиксФайла(ВыбКатПрием);

ТекстПисьма.Очистить();
ТекстПисьма.ДобавитьСтроку("From: " + ТекАдресОтправителя);
ТекстПисьма.ДобавитьСтроку("Message-Id: " + ИдПисьма);
ТекстПисьма.ДобавитьСтроку("Subject: " + ТемаПисьма);
Для ТекСтрокаСообщения = 1 По ПочтовыйЯщик.КоличествоСтрок() Цикл
ТекстПисьма.ДобавитьСтроку("Text: " + ПочтовыйЯщик.ПолучитьСтроку(ТекСтрокаСообщения));
КонецЦикла;

ТекстПисьма.Записать(ВыбКатПрием + ПрефиксПисьма + "message.txt");
Протокол("Письмо сохранено в файл "+ ПрефиксПисьма + "message.txt");
СчетчикЗапросов = СчетчикЗапросов + 1;

// Сохранение вложений
ТекКолФайлов = ПочтовыйЯщик.КоличествоФайлов();
Для ТекНомерВложения = 1 По ТекКолФайлов Цикл
ТекИмяВложения = ПочтовыйЯщик.ПолучитьФайл(ТекНомерВложения);
ТекИмяФайла = ПрефиксПисьма + ТекИмяВложения;
ПочтовыйЯщик.СохранитьФайл(ТекНомерВложения,ТекИмяФайла);
Протокол("Принят файл " + ТекИмяВложения + ", сохранен как " + ТекИмяФайла);
СчетчикФайлов = СчетчикФайлов + 1;
КонецЦикла;
ПочтовыйЯщик.ПометитьНаУдаление(ТекНомерСообщения);
КонецЦикла;

ПочтовыйЯщик.Отключиться();

Протокол("Получено писем " + ТекКолСообщений + ", сохранено " + СчетчикЗапросов + ", файлов " + СчетчикФайлов);

КонецПроцедуры // ПочтаПринять()
[/code]
[code]
//*********************************************************
// ПочтаОтправить()
//
Процедура ПочтаОтправить()

// Подготовка ящика на отправку
Если НастроитьПочтовыйЯщик(1) = 0 Тогда
ФлОшибкиАвтообмен = 1;
Возврат;
КонецЕсли;

//Подготовка списка писем
СписОтправить = СоздатьОбъект("СписокЗначений");
ТекФайл = ФС.НайтиПервыйФайл(ВыбКатОтправка + "*.*");
Пока ПустоеЗначение(ТекФайл) = 0 Цикл
Если (ТекФайл = ".")
или (ТекФайл = "..") Тогда
ТекФайл = ФС.НайтиСледующийФайл();
Продолжить;
КонецЕсли;

ТекИмяФайла = ТекФайл;
ТекПрефикс = ВыделитьПрефикс(ТекИмяФайла);
Если ПустоеЗначение(ТекПрефикс) = 1 Тогда // Без префикса не отправляем
ТекФайл = ФС.НайтиСледующийФайл();
Продолжить;
КонецЕсли;

СписОтправить.ДобавитьЗначение(ТекФайл,ТекПрефикс);

ТекФайл = ФС.НайтиСледующийФайл();
КонецЦикла;

Если СписОтправить.РазмерСписка() = 0 Тогда
Протокол("Нет писем к отправке");
Возврат;
КонецЕсли;

// Подготовка ящика на отправку
Если ПочтовыйЯщик.Подключиться("Отправка") = 0 Тогда
Протокол("ОШИБКА!!! Не удалось подключится к серверу SMTP");
ФлОшибкиАвтообмен = 1;
Возврат;
КонецЕсли;

// Отправка писем
ТекстПисьма = СоздатьОбъект("Текст");

СписОтправить.СортироватьПоПредставлению();
ПрефиксПисьма = "";
ТемаПисьма = "";
Емайл = "";
ТекСообщение = "";
ТекФайлы = "";
ТекФайлыПротокол = "";

СчетчикОшибок = 0;
СчетчикПисем = 0;

Инд = 0;
Пока 1=1 Цикл

Инд = Инд + 1;
// Анализ строки списка
Если Инд > СписОтправить.РазмерСписка() Тогда // Список обработан - отправить и прервать
ФлОтправить = 2;
Иначе
ТекПрефикс = "";
СписОтправить.ПолучитьЗначение(Инд,ТекПрефикс);
Если ПрефиксПисьма = "" Тогда // первый цикл
ФлОтправить = 0;
ИначеЕсли ПрефиксПисьма = ТекПрефикс Тогда // Продолжение письма
ФлОтправить = 0;
Иначе
ФлОтправить = 1; // Новое письмо
КонецЕсли;
КонецЕсли;

Если ФлОтправить > 0 Тогда
ФлОтправлено = 0;
// Отправка письма, сначала проверить заголовок
Если ПустоеЗначение(Емайл) = 1 Тогда
Протокол("Отправка письма невозможна - не найден файл заголовка: " + ПрефиксПисьма + "message.txt");
Иначе
ПочтовыйЯщик.ИмяОтправителя = ИмяПользователя() + " " + ВыбИДБазы;
ПочтовыйЯщик.АдресОтправителя = НашЕмайл;
ПочтовыйЯщик.АдресПолучателя = Емайл;
ПочтовыйЯщик.Тема = ТемаПисьма;
ПочтовыйЯщик.Тело = ТекСообщение;
ПочтовыйЯщик.Вложения = ТекФайлы;

ФлОтправлено = ПочтовыйЯщик.Отправить();

Если ФлОтправлено = 0 Тогда
Протокол("ОШИБКА!!! Не удалось отправить почту " + Емайл + " '" + ТемаПисьма + "' '" + ТекФайлы +"'");
ФлОшибкиАвтообмен = 1;
СчетчикОшибок = СчетчикОшибок + 1;
Иначе
Протокол("Отправлено письмо для " + Емайл + " '" + ТемаПисьма + "' '" + ТекФайлы +"'");
СчетчикПисем = СчетчикПисем + 1;
КонецЕсли;

КонецЕсли;

// Переместить отправленные файлы в архив и убрать из ТМП
Для Инд1 = 1 По СписОтправить.РазмерСписка() Цикл
ТекПрефикс = "";
ТекФайл = СписОтправить.ПолучитьЗначение(Инд1,ТекПрефикс);
Если ТекПрефикс <> ПрефиксПисьма Тогда Продолжить;
КонецЕсли;
Если ФлОтправлено = 1 Тогда
ФС.ПереименоватьФайл(ВыбКатОтправка + ТекФайл,ВыбКатОтправка + "ARH\" + ТекФайл,1);
Протокол("Файл " + ТекФайл + " перемещен в архив");
КонецЕсли;
ВыделитьПрефикс(ТекФайл);
// Удалить временный файл
Если ФС.СуществуетФайл(КаталогНастроек + "TMP\" +ТекФайл) = 1 Тогда
ФС.УдалитьФайл(КаталогНастроек + "TMP\" +ТекФайл);
КонецЕсли;
КонецЦикла;

Если ФлОтправить = 2 Тогда Прервать;
КонецЕсли;

// Подготовка нового письма
ТекстПисьма.Очистить();
ТемаПисьма = "";
Емайл = "";
ТекСообщение = "";
ТекФайлы = "";
ТекФайлыПротокол = "";

КонецЕсли;

// Обработка строки списка
ТекФайл = СписОтправить.ПолучитьЗначение(Инд,ПрефиксПисьма);
ТекИмяФайла = ТекФайл;
ВыделитьПрефикс(ТекИмяФайла);

Если Нрег(ТекИмяФайла) = "message.txt" Тогда // тело письма
// Обработка тела письма
ТекстПисьма.Открыть(ВыбКатОтправка + ТекФайл);
Для ТекСтрокаПисьма = 1 По ТекстПисьма.КоличествоСтрок() Цикл
ТекСтрока = ТекстПисьма.ПолучитьСтроку(ТекСтрокаПисьма);
Если Врег(Лев(ТекСтрока,СтрДлина("TO: "))) = "TO: " Тогда
Емайл = Сред(ТекСтрока,СтрДлина("TO: ")+1);
ИначеЕсли Врег(Лев(ТекСтрока,СтрДлина("SUBJECT: "))) = "SUBJECT: " Тогда
ТемаПисьма = Сред(ТекСтрока,СтрДлина("SUBJECT: ") + 1);
ИначеЕсли Врег(Лев(ТекСтрока,СтрДлина("TEXT: "))) = "TEXT: " Тогда
ТекСообщение = ТекСообщение + Сред(ТекСтрока,СтрДлина("TEXT: ")+1) + РазделительСтрок;
КонецЕсли;
КонецЦикла;
Иначе
// Обработка вложений
ФС.КопироватьФайл(ВыбКатОтправка + ТекФайл,КаталогНастроек + "TMP\" + ТекИмяФайла,0);
Если ПустоеЗначение(ТекФайлы) = 0 Тогда
ТекФайлы = ТекФайлы + ";";
ТекФайлыПротокол = ТекФайлыПротокол + ",";
КонецЕсли;
ТекФайлы = ТекФайлы + КаталогНастроек + "TMP\" +ТекИмяФайла;
ТекФайлыПротокол = ТекФайлыПротокол + ТекИмяФайла;
КонецЕсли;
КонецЦикла;

ПочтовыйЯщик.Отключиться();
Протокол("Отправлено писем " + СчетчикПисем + ", ошибок " + СчетчикОшибок);

КонецПроцедуры // ПочтаОтправить()
[/code]