Как получить оборот по счету в целом?

Если хотите через обработку, то не поленитесь прочитать фунцию которая сделает то что вы хотите:

// Функция позволяет рассчитать и получить требуемый оборот в соответствии с указанными фильтрами.
// При этом не требуется каких-либо предварительных расчетов итогов.
//
// Параметры:
//
// РегистрБухгалтерии - ОбъектМетаданных или Строка или Число - регистр, имя или индекс регистра
// бухгалтерии, для которого рассчитывается оборот.
// Если не указан, то используется первый из регистров бухгалтерии, (в порядке,
// как они указаны в метаданных).
//
// ИмяРесурса - Строка - имя ресурса регистра бухгалтерии, по которому надо получить оборот.
//
// ДтКт - Строка - какой оборот требуется получить.
// Возможные значения:
// Дт - будет рассчитан дебетовый оборот.
// Кт - будет рассчитан кредитовый оборот.
// Пустая строка - будет рассчитан дебетовый минус кредитовый оборот.
//
// НачалоПериода - Дата, МоментВремени, Граница - начало периода, за который рассчитывается оборот.
// Если параметр не задан, или передано пустое значение, оборот будет рассчитываться
// с самого первого движения.
//
// КонецПериода - Дата, МоментВремени, Граница - конец периода, за который рассчитывается оборот.
// Если параметр не задан, или передано пустое значение, оборот будет рассчитываться
// по самое последнее движение.
//
// Счета - Строка, ПланСчетовСсылка, Массив значений типа ПланСчетовСсылка - счета,
// по которым следует ограничить расчет итогов - могут быть переданы в функцию
// или в виде строки, в которой коды счетов перечислены через запятую, или ввиде
// ссылки на счет, или в виде массива ссылок. Если указан счет-группа - будут
// включены все иерархически подчиненные счета.
//
// ВидыСубконто - ПланВидовХарактеристикСсылка, Массив значений типа ПланВидовХарактеристикСсылка -
// задает субконто, по которым рассчитываются итоги.
// См. описание параметра "Субконто" таблиц запросов регистров бухгалтерии.
//
// КорСчета - Строка, ПланСчетовСсылка, Массив значений типа ПланСчетовСсылка - счета, по
// корреспонденции с которыми следует ограничить расчет оборотов - могут быть
// переданы в процедуруили в виде строки, в которой коды счетов перечислены через
// запятую, или ввидессылки на счет, или в виде массива ссылок. Если указан счет-
// группа - будут включены все иерархически подчиненные счета.
//
// ВидыКорСубконто - ПланВидовХарактеристикСсылка, Массив значений типа ПланВидовХарактеристикСсылка.
// задает субконто по корреспонденции с которыми следует ограничить расчет оборотов.
// См. описание параметра "Кор. субконто" таблицы запросов "Обороты" регистров бухгалтерии.
//
// Фильтры - допускается два варианта синтаксиса: Строка или Структура.
// Если передана Строка: она должна содержать список имен полей,
// разделенных запятыми. В этом случае значения полей должны быть
// указаны в параметрах Значение1, Значение2 и. т. д.
// Если передана Структура, она должна содержать элементы, в которых имя поля
// указано в качестве ключа, а значение поля - в качестве значения элемента.
// В качестве имен полей структуры можно указывать:
// <ИмяИзмерения> - имена измерений регистра, как они заданы в метаданных,
// Субконто1, Субконто2, и т.д., до макс. количества субконто.
// В качестве значений элементов структуры можно указывать конкретные значения
// измерений и субконто, а так же массивы или списки таких значений.
// При расчете итоги будут отфильтрованы по указанным значениям.
// Если в качестве значения указывается группа (справочника), отбираются все
// подчиненные элементы.
//
// ЗначениеN - Любого типа - значения фильтров.
// Параметры используются в случае, если фильтры переданы в функцию в
// параметре Фильтры в виде строки. Количество и порядок значений фильтров
// должны соответствовать количеству и порядку имен полей.
//
// Возвращаемое значение:
//
// Число - величина требуемого бухгалтерского итога.
//
Функция Оборот (Знач РегистрБухгалтерии = 0, ИмяРесурса, ДтКт = "", НачалоПериода = Неопределено, КонецПериода = Неопределено, Знач Счета = Неопределено, ВидыСубконто = Неопределено, Знач КорСчета = Неопределено, ВидыКорСубконто = Неопределено, Знач Фильтры = Неопределено, Значение1 = Неопределено, Значение2 = Неопределено, Значение3 = Неопределено, Значение4 = Неопределено, Значение5 = Неопределено, Значение6 = Неопределено, Значение7 = Неопределено, Значение8 = Неопределено, Значение9 = Неопределено) Экспорт

// Регистр бухгалтерии, для которго выполняется расчет.
Если ТипЗнч(РегистрБухгалтерии) = Тип("ОбъектМетаданных") Тогда

мРегистрБухгалтерии = РегистрБухгалтерии;

Иначе

Для Каждого ОбъектМетаданных Из Метаданные.РегистрыБухгалтерии Цикл
Если ТипЗнч(РегистрБухгалтерии) = Тип("РегистрБухгалтерииМенеджер." + ОбъектМетаданных.Имя) Тогда
РегистрБухгалтерии = ОбъектМетаданных.Имя;
КонецЕсли;
КонецЦикла;

мРегистрБухгалтерии = Метаданные.РегистрыБухгалтерии[РегистрБухгалтерии];

КонецЕсли;

// Параметр Фильтры преобразуется в структуру, если был передан в виде строки.
Если ТипЗнч(Фильтры) <> Тип("Структура") Тогда
Фильтры = Новый Структура(Фильтры, Значение1, Значение2, Значение3, Значение4, Значение5, Значение6, Значение7, Значение8, Значение9);
КонецЕсли;

// Прочие параметры расчета итогов.
ИмяИтога = ИмяРесурса + "Оборот" + ДтКт;
Счета = РазобратьКодыСчетов(мРегистрБухгалтерии.ПланСчетов, Счета);
КорСчета = РазобратьКодыСчетов(мРегистрБухгалтерии.ПланСчетов, КорСчета);

Запрос = Новый Запрос();

УсловиеПоСчету = "";
УсловиеПоКорСчету = "";
УсловиеПоПолям = "";

// Формируются параметры условий таблицы - источника запроса.
СформироватьУсловиеПоСчету(Запрос, УсловиеПоСчету, Счета);
СформироватьУсловиеПоСчету(Запрос, УсловиеПоКорСчету, КорСчета, "Кор");
СформироватьУсловиеПоПолям(Запрос, УсловиеПоПолям, Фильтры);

ИсточникЗапроса = "РегистрБухгалтерии." + мРегистрБухгалтерии.Имя + ".Обороты(&НачалоПериода, &КонецПериода, , " + УсловиеПоСчету + ", &ВидыСубконто, " + УсловиеПоПолям + ", " + УсловиеПоКорСчету + ", &ВидыКорСубконто)";

Запрос.УстановитьПараметр("НачалоПериода", НачалоПериода);
Запрос.УстановитьПараметр("КонецПериода", КонецПериода);
Запрос.УстановитьПараметр("ВидыСубконто", ВидыСубконто);
Запрос.УстановитьПараметр("ВидыКорСубконто", ВидыКорСубконто);

// Собирается полный текст запроса.
Запрос.Текст =
"ВЫБРАТЬ
| СУММА(" + ИмяИтога + ") КАК " + ИмяИтога + "
|ИЗ
| " + ИсточникЗапроса;

// Выполняется запрос, выборка позиционируется на единственную строку.
Выборка = Запрос.Выполнить().Выбрать();

// Если выборка спозиционирована, возвращается итог.
Если Выборка.Следующий() И Выборка[ИмяИтога] <> Null Тогда
Возврат Выборка[ИмяИтога];
Иначе
Возврат 0;
КонецЕсли;

КонецФункции