Простая ситуация. Есть два условия (отбора) подразделение и должность, Например отбираю Сотрудников по подразделению соответствоенно:ВЫБРАТЬ
   СотрудникиОрганизаций.Ссылка
ИЗ
   Справочник.СотрудникиОрганизаций КАК СотрудникиОрганизаций
ГДЕ
   СотрудникиОрганизаций.ТекущееПодразделениеОрганизации = &ТекПодр

СГРУППИРОВАТЬ ПО
   СотрудникиОрганизаций.Ссылка

но например если указанно ещё и должность то нужно в этот запрос добавить условие

СотрудникиОрганизаций.ТекущаяДолжностьОрганизации = &ТекДолжн

Нашел тупое решение - двумя запросами...
Как это мне сделать используя один запрос?

ВЫБРАТЬ
   СотрудникиОрганизаций.Ссылка
ИЗ
   Справочник.СотрудникиОрганизаций КАК СотрудникиОрганизаций
ГДЕ
   СотрудникиОрганизаций.ТекущееПодразделениеОрганизации = &ТекПодр
   И СотрудникиОрганизаций.ТекущаяДолжностьОрганизации = &ТекДолжн

(1) Нееее... а если мне в данный момент не нужно отбор и по должности?

(2) используйте построитель запросов

Там можно задать - если некое условие (ТекущаяДолжность пустая) выполняется, то
СотрудникиОрганизаций.ТекущаяДолжностьОрганизации = &ТекДолжн
отбор по ТекДолжность не делается.

намек понел попробуем

вот так например (0)

   
   ПостроительЗапроса = Новый ПостроительЗапроса;
   
   ПостроительЗапроса.Текст =
   "ВЫБРАТЬ
   |    СотрудникиОрганизаций.Ссылка
   |ИЗ
   |    Справочник.СотрудникиОрганизаций КАК СотрудникиОрганизаций
   |{ГДЕ
   |    СотрудникиОрганизаций.ПодразделениеОрганизации.* КАК Подразделение,
   |    СотрудникиОрганизаций.Должность.*}";
   
   // Установка отборов
   
   Если ОтборПодразделение Тогда
       Отбор = ПостроительЗапроса.Отбор.Добавить("Подразделение");
       Отбор.Использование = Истина;
       Отбор.ВидСравнения  = ЭтотОбъект.ВидСравненияПодразделение;
       Отбор.Значение      = ЭтотОбъект.Подразделение;
   КонецЕсли;
   
   Если ОтборДолжность Тогда
       Отбор = ПостроительЗапроса.Отбор.Добавить("Должность");
       Отбор.Использование = Истина;
       Отбор.ВидСравнения  = ЭтотОбъект.ВидСравненияДолжность;
       Отбор.Значение      = ЭтотОбъект.Должность;
   КонецЕсли;
   
   //////////////////////////////////////
   // Получение и выполнение запроса
   
   Запрос = ПостроительЗапроса.ПолучитьЗапрос();
   Результат = Запрос.Выполнить();
   Если Результат.Пустой() Тогда
       Возврат;
   КонецЕсли;

Или
ТекстЗапроса = "
|ВЫБРАТЬ
|    СотрудникиОрганизаций.Ссылка
|ИЗ
|    Справочник.СотрудникиОрганизаций КАК СотрудникиОрганизаций
|ГДЕ
|    СотрудникиОрганизаций.ТекущееПодразделениеОрганизации = &ТекПодр
|    %ПроверкаДолжности%";

Если ПроверятьДолжность Тогда
   ПроверкаДолжности = "И СотрудникиОрганизаций.ТекущаяДолжностьОрганизации = &ТекДолжн";
Иначе
   ПроверкаДолжности = "";
КонецЕсли
СтрЗаменить(ТекстЗапроса, "%ПроверкаДолжности%", ПроверкаДолжности);

Понятно, что в данном случа можно было использовать простое добавление к тексту запроса, но предложенный вариант работает и при необходимости изменения середины запроса, например динамическое изменение полей выборки...

Книга знаний: Хитрое написание текстов запросов с необязательными условиями

(7) а нахрена изобретать лесопед с квадратными колесами? Ты еще предлагаешь 10 условий написать по типу?

   Если ВидСравненияРаботника = ВидСравнения.Равно Тогда
           ВидСравненияРаботник = "="
       ИначеЕсли ВидСравненияРаботника = ВидСравнения.НеРавно Тогда
           ВидСравненияРаботник = "<>"
       ИначеЕсли ВидСравненияРаботника = ВидСравнения.ВСписке Тогда
           ВидСравненияРаботник = "В"
       ИначеЕсли ВидСравненияРаботника = ВидСравнения.НеВСписке Тогда
           ВидСравненияРаботник = "НЕ В"
       ИначеЕсли ВидСравненияРаботника = ВидСравнения.ВСпискеПоИерархии ИЛИ
           ВидСравненияРаботника = ВидСравнения.ВИерархии Тогда
           ВидСравненияРаботник = "В ИЕРАРХИИ"
       ИначеЕсли ВидСравненияРаботника = ВидСравнения.НеВСпискеПоИерархии ИЛИ
           ВидСравненияРаботника = ВидСравнения.НеВИерархии Тогда
           ВидСравненияРаботник = "НЕ В ИЕРАРХИИ"
       КонецЕсли;
       
       Если ВидСравненияРаботник = "=" ИЛИ ВидСравненияРаботник = "<>" Тогда
           УсловиеПоРаботникам    = " Сотрудник " + ВидСравненияРаботник + " &РаботникиОрганизации";
       Иначе
           УсловиеПоРаботникам    = " Сотрудник " + ВидСравненияРаботник + "(&РаботникиОрганизации)";
       КонецЕсли;

как когда то давно было в табеле?

убытсо можно...

(9) Еще можно отбор СКД воткнуть, с группами условий... Это ж сразу сколько говнокода можно выдать!

(9) Первым словом моего сообщения было "Или", целью служило осветить альтернативный вариант решения задачи, а на каких велосипедах кататься каждый вылысыпыдыст решает сам :)
Тема определения "ЭтотОбъект.ВидСравненияПодразделение;" тобой тоже не раскрыта...

(11) это было для примера выдрано из шаблона и чтобы не показывать что там было, написал так... А вообще можно отбор на форму закинуть или еще что-нибудь

ТекстЗапроса = "
|ВЫБРАТЬ
|    СотрудникиОрганизаций.Ссылка
|ИЗ
|    Справочник.СотрудникиОрганизаций КАК СотрудникиОрганизаций
|ГДЕ
|    СотрудникиОрганизаций.ТекущееПодразделениеОрганизации = &ТекПодр
|    И &ПроверкаДолжности";

Если ПроверятьДолжность Тогда
   ПроверкаДолжности = "СотрудникиОрганизаций.ТекущаяДолжностьОрганизации = &ТекДолжн";
Иначе
   ПроверкаДолжности = "ИСТИНА";
КонецЕсли
СтрЗаменить(ТекстЗапроса, "&ПроверкаДолжности", ПроверкаДолжности);

(12) Я все это прекрасно понимаю ;)
Разное оружие для разных ситуаций, два языка - два крыла и т.д.
В общем, Пусть ТС смотрит и решает, мы вариантов решений набросали.

(13) Месье знает толк в извращениях...

(15) да я такой!

ГДЕ
   (СотрудникиОрганизаций.ТекущееПодразделениеОрганизации = &ТекПодр ИЛИ СотрудникиОрганизаций.ТекущееПодразделениеОрганизации = Значение(Справочник.ПодразделенияОрганизаций.ПустаяСсылка))
   И (СотрудникиОрганизаций.ТекущаяДолжностьОрганизации = &ТекДолжн ИЛИ СотрудникиОрганизаций.ТекущаяДолжностьОрганизации = Значение(Справочник.ДолжностиОрганизаций.ПустаяСсылка))

(17) а вот это может сказаться на том, что индексы будут не использованными

хотя не так...
ГДЕ
  (СотрудникиОрганизаций.ТекущееПодразделениеОрганизации = &ТекПодр ИЛИ &НеОтбиратьПоПодразделению)
  И (СотрудникиОрганизаций.ТекущаяДолжностьОрганизации = &ТекДолжн ИЛИ &НеОтбиратьПоДолжности)

Ну а в коде
Запрос.УстановитьПараметр("НеОтбиратьПоПодразделению", ?(ЗначениеЗаполнено(ТекПодр), Ложь, Истина))