Есть запрос с левым соединением. В результате получаются некоторые строки с заполненными колонками только левой таблицы. В консоли запросов их видно. В СКД их нет. Подскажите, пожалуйста, куда копать.

А ты, поди, в СКД на закладке настройки на поля из левого соединения условия в отборе накладываешь, да?

да, накладываю и не могу иначе

правильно накладывать условия, либо соединять по другому..

а как правильнее наложить?

ну ты задачу получше объясни и запрос сюда выложи свой

Запрос:

ВЫБРАТЬ
   ВложенныйЗапрос.Контрагент КАК Контрагент,
   СУММА(ВложенныйЗапрос.СтоимостьОборот) КАК СтоимостьОборот,
   ВложенныйЗапрос.КонтрагентРодитель
ПОМЕСТИТЬ ВТ_Контрагенты
ИЗ
   (ВЫБРАТЬ
       ПродажиОбороты.ПериодМесяц КАК ПериодМесяц,
       ПродажиОбороты.Контрагент КАК Контрагент,
       ПродажиОбороты.СтоимостьОборот КАК СтоимостьОборот,
       ПродажиОбороты.Регистратор КАК Регистратор,
       ПродажиОбороты.Контрагент.Родитель КАК КонтрагентРодитель
   ИЗ
       РегистрНакопления.Продажи.Обороты(&ПериодНачало, &ПериодОкончание, Авто, ) КАК ПродажиОбороты) КАК ВложенныйЗапрос

СГРУППИРОВАТЬ ПО
   ВложенныйЗапрос.Контрагент,
   ВложенныйЗапрос.КонтрагентРодитель

ИНДЕКСИРОВАТЬ ПО
   Контрагент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТ_Контрагенты.КонтрагентРодитель КАК КонтрагентРодитель,
   ВТ_Контрагенты.Контрагент КАК Контрагент,
   ВТ_Контрагенты.СтоимостьОборот КАК СтоимостьОборот,
   КОЛИЧЕСТВО(ВТ_Контрагенты2.Контрагент) КАК РейтингОбщий
ПОМЕСТИТЬ ВТ_Рейтинг
ИЗ
   ВТ_Контрагенты КАК ВТ_Контрагенты
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Контрагенты КАК ВТ_Контрагенты2
       ПО ВТ_Контрагенты.КонтрагентРодитель = ВТ_Контрагенты2.КонтрагентРодитель
           И ВТ_Контрагенты.СтоимостьОборот <= ВТ_Контрагенты2.СтоимостьОборот

СГРУППИРОВАТЬ ПО
   ВТ_Контрагенты.Контрагент,
   ВТ_Контрагенты.СтоимостьОборот,
   ВТ_Контрагенты.КонтрагентРодитель

ИНДЕКСИРОВАТЬ ПО
   Контрагент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТ_Рейтинг.КонтрагентРодитель КАК КонтрагентРодитель,
   ВТ_Рейтинг.Контрагент КАК Контрагент,
   ПродажиОбороты.ПериодМесяц КАК ПериодМесяц,
   ПродажиОбороты.СтоимостьОборот КАК СтоимостьОборот,
   ВТ_Рейтинг.РейтингОбщий КАК РейтингОбщий,
   ПродажиОбороты.Регистратор КАК Регистратор,
   ПродажиОбороты.Номенклатура КАК Номенклатура,
   ПродажиОбороты.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
   ПродажиОбороты.ЗаказПокупателя КАК ЗаказПокупателя,
   ПродажиОбороты.ДоговорКонтрагента КАК ДоговорКонтрагента,
   ПродажиОбороты.ДокументПродажи КАК ДокументПродажи,
   ПродажиОбороты.Подразделение КАК Подразделение,
   ПродажиОбороты.Проект КАК Проект,
   ПродажиОбороты.Организация КАК Организация,
   ПродажиОбороты.КоличествоОборот КАК КоличествоОборот,
   ПродажиОбороты.НДСОборот КАК НДСОборот,
   ПродажиОбороты.ПериодДень КАК ПериодДень,
   ПродажиОбороты.ПериодНеделя КАК ПериодНеделя,
   ПродажиОбороты.ПериодДекада КАК ПериодДекада,
   ПродажиОбороты.ПериодКвартал КАК ПериодКвартал,
   ПродажиОбороты.ПериодПолугодие КАК ПериодПолугодие,
   ПродажиОбороты.ПериодГод КАК ПериодГод
{ВЫБРАТЬ
   Контрагент.*,
   СтоимостьОборот,
   РейтингОбщий,
   Регистратор.*,
   ПериодМесяц,
   Номенклатура.*,
   ХарактеристикаНоменклатуры.*,
   ЗаказПокупателя.*,
   ДоговорКонтрагента.*,
   ДокументПродажи.*,
   Подразделение.*,
   Проект.*,
   Организация.*,
   КоличествоОборот,
   НДСОборот,
   ПериодДень,
   ПериодНеделя,
   ПериодДекада,
   ПериодКвартал,
   ПериодПолугодие,
   ПериодГод}
ИЗ
   ВТ_Рейтинг КАК ВТ_Рейтинг
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Продажи.Обороты(&ПериодНачало, &ПериодОкончание, Авто, Номенклатура В иерархии (&Номенклатура)) КАК ПродажиОбороты
       ПО ВТ_Рейтинг.Контрагент = ПродажиОбороты.Контрагент
{ГДЕ
   ПродажиОбороты.Регистратор.*,
   ПродажиОбороты.ПериодМесяц,
   ПродажиОбороты.Номенклатура.*,
   ПродажиОбороты.ХарактеристикаНоменклатуры.*,
   ПродажиОбороты.ДоговорКонтрагента.*,
   ПродажиОбороты.ДокументПродажи.*,
   ПродажиОбороты.Подразделение.*,
   ПродажиОбороты.Организация.*,
   ВТ_Рейтинг.Контрагент.*}

Условие накладывается на поле Номенклатура. Надо, чтобы были все контрагенты вне зависимости от того были ли по выбранной номенклатуре движения в Продажах.

Теперь могу ответить на (0). Копать в сторону ЕСТЬNULL() для выбранных полей в основном запросе для полей, взятых или сформированных по данным полей из левого соединения.

ПустаяСсылка пойдёт для справочников и прочее?

(8) Должна. Пробуй.

Теперь конечный запрос выглядит примерно так:

ВЫБРАТЬ
   ВТ_Рейтинг.КонтрагентРодитель КАК КонтрагентРодитель,
   ВТ_Рейтинг.Контрагент КАК Контрагент,
   ЕСТЬNULL(ПродажиОбороты.ПериодМесяц, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодМесяц,
   ЕСТЬNULL(ПродажиОбороты.СтоимостьОборот, 0) КАК СтоимостьОборот,
   ВТ_Рейтинг.РейтингОбщий КАК РейтингОбщий,
   ЕСТЬNULL(ПродажиОбороты.Регистратор, ЗНАЧЕНИЕ(Документ.РеализацияТоваровУслуг.ПустаяСсылка)) КАК Регистратор,
   ЕСТЬNULL(ПродажиОбороты.Номенклатура, ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)) КАК Номенклатура,
   ЕСТЬNULL(ПродажиОбороты.ХарактеристикаНоменклатуры, ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)) КАК ХарактеристикаНоменклатуры,
   ЕСТЬNULL(ПродажиОбороты.ЗаказПокупателя, ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)) КАК ЗаказПокупателя,
   ЕСТЬNULL(ПродажиОбороты.ДоговорКонтрагента, ЗНАЧЕНИЕ(Справочник.ДоговорыКонтрагентов.ПустаяСсылка)) КАК ДоговорКонтрагента,
   ЕСТЬNULL(ПродажиОбороты.ДокументПродажи, ЗНАЧЕНИЕ(Документ.РеализацияТоваровУслуг.ПустаяСсылка)) КАК ДокументПродажи,
   ЕСТЬNULL(ПродажиОбороты.Подразделение, ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)) КАК Подразделение,
   ЕСТЬNULL(ПродажиОбороты.Проект, ЗНАЧЕНИЕ(Справочник.Проекты.ПустаяСсылка)) КАК Проект,
   ЕСТЬNULL(ПродажиОбороты.Организация, ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка)) КАК Организация,
   ЕСТЬNULL(ПродажиОбороты.КоличествоОборот, 0) КАК КоличествоОборот,
   ЕСТЬNULL(ПродажиОбороты.НДСОборот, 0) КАК НДСОборот,
   ЕСТЬNULL(ПродажиОбороты.ПериодДень, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодДень,
   ЕСТЬNULL(ПродажиОбороты.ПериодНеделя, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодНеделя,
   ЕСТЬNULL(ПродажиОбороты.ПериодДекада, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодДекада,
   ЕСТЬNULL(ПродажиОбороты.ПериодКвартал, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодКвартал,
   ЕСТЬNULL(ПродажиОбороты.ПериодПолугодие, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодПолугодие,
   ЕСТЬNULL(ПродажиОбороты.ПериодГод, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодГод
ИЗ
   ВТ_Рейтинг КАК ВТ_Рейтинг
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Продажи.Обороты(&ПериодНачало, &ПериодОкончание, Авто, ) КАК ПродажиОбороты
       ПО ВТ_Рейтинг.Контрагент = ПродажиОбороты.Контрагент


но не взлетает.

как же теперь наложить?

(10) Что не взлетает? (11) Куда наложить?

а что за отбор ты накладываешь в СКД?

Результат прежний, не появляются значения нулевые по регистру Продаж.
Как наложить правильно условие на Номенклатуру?

(13)+ Какое условие на номенклатуру?

(13) Отборы по номенклатуре в группе.
(14) Номенкларута в группе.

а зачем накладывать отбор в СКД на закладке Настройки, когда ты уже наложил отбор в запросе?...
Ты понимаешь что ты делаешь? или потыкал-потыкал, получилось и бог с ним?...

(17) как в запросе? в запросе я ничего не накладывал.

в первый раз запрос из консоли скопировал, извините, в запросе в СКД у меня нет условий никаких.

так как же правильно наложить?

{ЕСТЬNULL(ЛеваяТаблица.Поле, ПустаяСсылка) КАК Условие}

ВЫБРАТЬ
   ВТ_Рейтинг.КонтрагентРодитель КАК КонтрагентРодитель,
   ВТ_Рейтинг.Контрагент КАК Контрагент,
   ЕСТЬNULL(ПродажиОбороты.ПериодМесяц, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодМесяц,
   ЕСТЬNULL(ПродажиОбороты.СтоимостьОборот, 0) КАК СтоимостьОборот,
   ВТ_Рейтинг.РейтингОбщий КАК РейтингОбщий,
   ЕСТЬNULL(ПродажиОбороты.Регистратор, ЗНАЧЕНИЕ(Документ.РеализацияТоваровУслуг.ПустаяСсылка)) КАК Регистратор,
   ЕСТЬNULL(ПродажиОбороты.Номенклатура, ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)) КАК Номенклатура,
   ЕСТЬNULL(ПродажиОбороты.ХарактеристикаНоменклатуры, ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)) КАК ХарактеристикаНоменклатуры,
   ЕСТЬNULL(ПродажиОбороты.ЗаказПокупателя, ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)) КАК ЗаказПокупателя,
   ЕСТЬNULL(ПродажиОбороты.ДоговорКонтрагента, ЗНАЧЕНИЕ(Справочник.ДоговорыКонтрагентов.ПустаяСсылка)) КАК ДоговорКонтрагента,
   ЕСТЬNULL(ПродажиОбороты.ДокументПродажи, ЗНАЧЕНИЕ(Документ.РеализацияТоваровУслуг.ПустаяСсылка)) КАК ДокументПродажи,
   ЕСТЬNULL(ПродажиОбороты.Подразделение, ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)) КАК Подразделение,
   ЕСТЬNULL(ПродажиОбороты.Проект, ЗНАЧЕНИЕ(Справочник.Проекты.ПустаяСсылка)) КАК Проект,
   ЕСТЬNULL(ПродажиОбороты.Организация, ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка)) КАК Организация,
   ЕСТЬNULL(ПродажиОбороты.КоличествоОборот, 0) КАК КоличествоОборот,
   ЕСТЬNULL(ПродажиОбороты.НДСОборот, 0) КАК НДСОборот,
   ЕСТЬNULL(ПродажиОбороты.ПериодДень, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодДень,
   ЕСТЬNULL(ПродажиОбороты.ПериодНеделя, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодНеделя,
   ЕСТЬNULL(ПродажиОбороты.ПериодДекада, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодДекада,
   ЕСТЬNULL(ПродажиОбороты.ПериодКвартал, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодКвартал,
   ЕСТЬNULL(ПродажиОбороты.ПериодПолугодие, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодПолугодие,
   ЕСТЬNULL(ПродажиОбороты.ПериодГод, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодГод
{ВЫБРАТЬ
   КонтрагентРодитель.*,
   Контрагент.*,
   ПериодМесяц,
   СтоимостьОборот,
   РейтингОбщий,
   Регистратор.*,
   Номенклатура.*,
   ХарактеристикаНоменклатуры.*,
   ЗаказПокупателя.*,
   ДоговорКонтрагента.*,
   ДокументПродажи.*,
   Подразделение.*,
   Проект.*,
   Организация.*,
   КоличествоОборот,
   НДСОборот,
   ПериодДень,
   ПериодНеделя,
   ПериодДекада,
   ПериодКвартал,
   ПериодПолугодие,
   ПериодГод}
ИЗ
   ВТ_Рейтинг КАК ВТ_Рейтинг
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.Продажи.Обороты(&ПериодНачало, &ПериодОкончание, Авто, ) КАК ПродажиОбороты
       ПО ВТ_Рейтинг.Контрагент = ПродажиОбороты.Контрагент
{ГДЕ
   ВТ_Рейтинг.КонтрагентРодитель.*,
   ВТ_Рейтинг.Контрагент.*,
   (ЕСТЬNULL(ПродажиОбороты.ПериодМесяц, ДАТАВРЕМЯ(1, 1, 1))) КАК ПериодМесяц,
   (ЕСТЬNULL(ПродажиОбороты.СтоимостьОборот, 0)) КАК СтоимостьОборот,
   ВТ_Рейтинг.РейтингОбщий,
   (ЕСТЬNULL(ПродажиОбороты.Регистратор, ЗНАЧЕНИЕ(Документ.РеализацияТоваровУслуг.ПустаяСсылка))).* КАК Регистратор,
   (ЕСТЬNULL(ПродажиОбороты.Номенклатура, ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка))).* КАК Номенклатура,
   (ЕСТЬNULL(ПродажиОбороты.ХарактеристикаНоменклатуры, ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка))).* КАК ХарактеристикаНоменклатуры,
   (ЕСТЬNULL(ПродажиОбороты.ЗаказПокупателя, ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка))).* КАК ЗаказПокупателя,
   (ЕСТЬNULL(ПродажиОбороты.ДоговорКонтрагента, ЗНАЧЕНИЕ(Справочник.ДоговорыКонтрагентов.ПустаяСсылка))).* КАК ДоговорКонтрагента,
   (ЕСТЬNULL(ПродажиОбороты.ДокументПродажи, ЗНАЧЕНИЕ(Документ.РеализацияТоваровУслуг.ПустаяСсылка))).* КАК ДокументПродажи,
   (ЕСТЬNULL(ПродажиОбороты.Подразделение, ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка))).* КАК Подразделение,
   (ЕСТЬNULL(ПродажиОбороты.Проект, ЗНАЧЕНИЕ(Справочник.Проекты.ПустаяСсылка))).* КАК Проект,
   (ЕСТЬNULL(ПродажиОбороты.Организация, ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка))).* КАК Организация,
   (ЕСТЬNULL(ПродажиОбороты.КоличествоОборот, 0)) КАК КоличествоОборот,
   (ЕСТЬNULL(ПродажиОбороты.НДСОборот, 0)) КАК НДСОборот,
   (ЕСТЬNULL(ПродажиОбороты.ПериодДень, ДАТАВРЕМЯ(1, 1, 1))) КАК ПериодДень,
   (ЕСТЬNULL(ПродажиОбороты.ПериодНеделя, ДАТАВРЕМЯ(1, 1, 1))) КАК ПериодНеделя,
   (ЕСТЬNULL(ПродажиОбороты.ПериодДекада, ДАТАВРЕМЯ(1, 1, 1))) КАК ПериодДекада,
   (ЕСТЬNULL(ПродажиОбороты.ПериодКвартал, ДАТАВРЕМЯ(1, 1, 1))) КАК ПериодКвартал,
   (ЕСТЬNULL(ПродажиОбороты.ПериодПолугодие, ДАТАВРЕМЯ(1, 1, 1))) КАК ПериодПолугодие,
   (ЕСТЬNULL(ПродажиОбороты.ПериодГод, ДАТАВРЕМЯ(1, 1, 1))) КАК ПериодГод}

не помогло

автозаполнение отключин надеюсь?

конечно

надо короче запрос разбивать ещё на пакеты, делать один по Продажам с условием, а второй уже выводить в соединении. ща попробую

да, вот так взлетело:

ВЫБРАТЬ
   ПродажиОбороты.НомерСтроки,
   ПродажиОбороты.Регистратор,
   ПродажиОбороты.ПериодСекунда,
   ПродажиОбороты.ПериодМинута,
   ПродажиОбороты.ПериодЧас,
   ПродажиОбороты.ПериодДень,
   ПродажиОбороты.ПериодНеделя,
   ПродажиОбороты.ПериодДекада,
   ПродажиОбороты.ПериодМесяц,
   ПродажиОбороты.ПериодКвартал,
   ПродажиОбороты.ПериодПолугодие,
   ПродажиОбороты.ПериодГод,
   ПродажиОбороты.Номенклатура,
   ПродажиОбороты.ХарактеристикаНоменклатуры,
   ПродажиОбороты.ЗаказПокупателя,
   ПродажиОбороты.ДоговорКонтрагента,
   ПродажиОбороты.ДокументПродажи,
   ПродажиОбороты.Подразделение,
   ПродажиОбороты.Проект,
   ПродажиОбороты.Организация,
   ПродажиОбороты.Контрагент КАК Контрагент,
   ПродажиОбороты.КоличествоОборот,
   ПродажиОбороты.СтоимостьОборот,
   ПродажиОбороты.СтоимостьБезСкидокОборот,
   ПродажиОбороты.НДСОборот
ПОМЕСТИТЬ ВТ_Продажи
ИЗ
   РегистрНакопления.Продажи.Обороты(&ПериодНачало, &ПериодОкончание, Авто, ) КАК ПродажиОбороты
{ГДЕ
   ПродажиОбороты.НомерСтроки,
   ПродажиОбороты.Регистратор.*,
   ПродажиОбороты.ПериодСекунда,
   ПродажиОбороты.ПериодМинута,
   ПродажиОбороты.ПериодЧас,
   ПродажиОбороты.ПериодДень,
   ПродажиОбороты.ПериодНеделя,
   ПродажиОбороты.ПериодДекада,
   ПродажиОбороты.ПериодМесяц,
   ПродажиОбороты.ПериодКвартал,
   ПродажиОбороты.ПериодПолугодие,
   ПродажиОбороты.ПериодГод,
   ПродажиОбороты.Номенклатура.*,
   ПродажиОбороты.ХарактеристикаНоменклатуры.*,
   ПродажиОбороты.ЗаказПокупателя.*,
   ПродажиОбороты.ДоговорКонтрагента.*,
   ПродажиОбороты.ДокументПродажи.*,
   ПродажиОбороты.Подразделение.*,
   ПродажиОбороты.Проект.*,
   ПродажиОбороты.Организация.*,
   ПродажиОбороты.Контрагент.*,
   ПродажиОбороты.КоличествоОборот,
   ПродажиОбороты.СтоимостьОборот,
   ПродажиОбороты.СтоимостьБезСкидокОборот,
   ПродажиОбороты.НДСОборот}

ИНДЕКСИРОВАТЬ ПО
   Контрагент
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВТ_Рейтинг.КонтрагентРодитель КАК КонтрагентРодитель,
   ВТ_Рейтинг.Контрагент КАК Контрагент,
   ЕСТЬNULL(ВТ_Продажи.ПериодМесяц, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодМесяц,
   ЕСТЬNULL(ВТ_Продажи.СтоимостьОборот, 0) КАК СтоимостьОборот,
   ВТ_Рейтинг.РейтингОбщий КАК РейтингОбщий,
   ЕСТЬNULL(ВТ_Продажи.Регистратор, ЗНАЧЕНИЕ(Документ.РеализацияТоваровУслуг.ПустаяСсылка)) КАК Регистратор,
   ЕСТЬNULL(ВТ_Продажи.Номенклатура, ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)) КАК Номенклатура,
   ЕСТЬNULL(ВТ_Продажи.ХарактеристикаНоменклатуры, ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)) КАК ХарактеристикаНоменклатуры,
   ЕСТЬNULL(ВТ_Продажи.ЗаказПокупателя, ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)) КАК ЗаказПокупателя,
   ЕСТЬNULL(ВТ_Продажи.ДоговорКонтрагента, ЗНАЧЕНИЕ(Справочник.ДоговорыКонтрагентов.ПустаяСсылка)) КАК ДоговорКонтрагента,
   ЕСТЬNULL(ВТ_Продажи.ДокументПродажи, ЗНАЧЕНИЕ(Документ.РеализацияТоваровУслуг.ПустаяСсылка)) КАК ДокументПродажи,
   ЕСТЬNULL(ВТ_Продажи.Подразделение, ЗНАЧЕНИЕ(Справочник.Подразделения.ПустаяСсылка)) КАК Подразделение,
   ЕСТЬNULL(ВТ_Продажи.Проект, ЗНАЧЕНИЕ(Справочник.Проекты.ПустаяСсылка)) КАК Проект,
   ЕСТЬNULL(ВТ_Продажи.Организация, ЗНАЧЕНИЕ(Справочник.Организации.ПустаяСсылка)) КАК Организация,
   ЕСТЬNULL(ВТ_Продажи.КоличествоОборот, 0) КАК КоличествоОборот,
   ЕСТЬNULL(ВТ_Продажи.НДСОборот, 0) КАК НДСОборот,
   ЕСТЬNULL(ВТ_Продажи.ПериодДень, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодДень,
   ЕСТЬNULL(ВТ_Продажи.ПериодНеделя, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодНеделя,
   ЕСТЬNULL(ВТ_Продажи.ПериодДекада, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодДекада,
   ЕСТЬNULL(ВТ_Продажи.ПериодКвартал, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодКвартал,
   ЕСТЬNULL(ВТ_Продажи.ПериодПолугодие, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодПолугодие,
   ЕСТЬNULL(ВТ_Продажи.ПериодГод, ДАТАВРЕМЯ(1, 1, 1)) КАК ПериодГод
{ВЫБРАТЬ
   КонтрагентРодитель.*,
   Контрагент.*,
   ПериодМесяц,
   СтоимостьОборот,
   РейтингОбщий,
   Регистратор.*,
   Номенклатура.*,
   ХарактеристикаНоменклатуры.*,
   ЗаказПокупателя.*,
   ДоговорКонтрагента.*,
   ДокументПродажи.*,
   Подразделение.*,
   Проект.*,
   Организация.*,
   КоличествоОборот,
   НДСОборот,
   ПериодДень,
   ПериодНеделя,
   ПериодДекада,
   ПериодКвартал,
   ПериодПолугодие,
   ПериодГод}
ИЗ
   ВТ_Рейтинг КАК ВТ_Рейтинг
       ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Продажи КАК ВТ_Продажи
       ПО ВТ_Рейтинг.Контрагент = ВТ_Продажи.Контрагент
{ГДЕ
   ВТ_Рейтинг.КонтрагентРодитель.*,
   ВТ_Рейтинг.Контрагент.*,
   ВТ_Рейтинг.РейтингОбщий}


:)

теперь другая беда, теперь колонка с пустой датой появляется

ну тут как раз с нулами

ЕСТЬNULL(ВТ_Продажи.ПериодМесяц, &ПериодНачало)