Добрый день! Подскажите пожалуйста, как сделать запрос по счету 62, чтобы вывел следующие поля:
- Контрагент
- Договор контрагента
- Остаток по Кт62 на выбранную дату
- Дата первого документа движения по Кт62
- Дата первого документа движения по Кт62 + 15 дней
- Остаток по Кт62 на "Дата первого документа движения по Кт62 + 15 дней"

100 долларов

если УПП, то лучше используй РН РасчетыПоРеализацииВУЕ
более подробно за 99$ :)

(2) а зачем этот РН?
(0) $250

Не упп, бухгалтерия.

первые 3 пункта легко... а потом уже извращаться надо

хоть подсказку дайте пожалуйста, если тут теперь за деньги опытом делятся

(6) Подсказка: Открываешь конструктор запроса...

+(7) в качестве таблицы выбираешь РегистрБухгалтерии

Таблицу остатков или движений с субконто?

>>Остаток по Кт62 на "Дата первого документа движения по Кт62 + 15 дней"
вот это в запросе проблематично сильно. остальное норм

а Дата первого документа движения по Кт62 связываешь?

(10) ни разу не проблематично - самое главное моск включить
PS в РБ на субконто есть документы расчетов - вполне можно выкрутиться

(3) затем, что там все есть, плюс пользоваться удобней и отрабатывать будет по-быстрее

+13 даже не "по-быстрее", а в неск. раз быстрее, т.к. в УПП пришлось бы использовать реальную таблицу, а не виртуальную

(14) а в РБ не все есть?

(13) если есть договора в у.е., то в РасчетыПоРеализацииВУЕ и на 62.31 будут разные суммы

(14) хотя не... можно использовать периодичность = регистратор

не понимаю как 4 поле все таки прилепить

всё, можете кидаться какашками. нет тока остака на первую дату + 15 дней

ВЫБРАТЬ
   ХозрасчетныйОбороты.Счет,
   МИНИМУМ(ХозрасчетныйОбороты.Период) КАК ПерваяДата,
   МИНИМУМ(ДОБАВИТЬКДАТЕ(ХозрасчетныйОбороты.Период, ДЕНЬ, 15)) КАК ПерваяДатаПлюс15
ПОМЕСТИТЬ втПерваяДатаДвижения
ИЗ
   РегистрБухгалтерии.Хозрасчетный.Обороты(, , Регистратор, Счет = &Счет62, , Субконто2 = &Договор, , ) КАК ХозрасчетныйОбороты

СГРУППИРОВАТЬ ПО
   ХозрасчетныйОбороты.Счет
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ХозрасчетныйОстатки.Счет,
   ХозрасчетныйОстатки.Субконто1 КАК Контрагент,
   ХозрасчетныйОстатки.Субконто2 КАК Договор,
   ХозрасчетныйОстатки.СуммаОстатокКт КАК ТекущийОстаток,
   втПерваяДатаДвижения.ПерваяДата,
   втПерваяДатаДвижения.ПерваяДатаПлюс15
ИЗ
   РегистрБухгалтерии.Хозрасчетный.Остатки(&ТекДата, Счет = &Счет62, , Субконто2 = &Договор) КАК ХозрасчетныйОстатки
       ЛЕВОЕ СОЕДИНЕНИЕ втПерваяДатаДвижения КАК втПерваяДатаДвижения
       ПО ХозрасчетныйОстатки.Счет = втПерваяДатаДвижения.Счет

(19) я бы еще предложил соединение делать не только по счету, но и по договорам

(20) пример на 1 конкретный договор, запись одна. для разных контров-договоров - да

(21) сорри, не заметил что отбор по договору

ДОБАВИТЬКДАТЕ(ХозрасчетныйОбороты.Период, ДЕНЬ, 15) КАК ПерваяДатаПлюс15

- это во второй пакет запроса надо, чтоб не напрягать при формировании ВТ )

ДОБАВИТЬКДАТЕ(втПерваяДатаДвижения.ПерваяДата, ДЕНЬ, 15) КАК ПерваяДатаПлюс15

спасибо большое, разбираюсь

получилось, спасибо, а как быть с последним полем?

(26) с последним (12) видимо знает, мне лень думать)

(26) Вложенный запрос спасет отца русской демократии или еще несколько запросов в пакете

Сделал вложенный запрос, остатки и обороты, периодичность секунда, связь по периоду и ПерваяДатаПлюс15. Что-то явно не то

не всё так просто. надо остатки снять на нужную дату, которую мы получаем в запросе - значит надо снимать соаттки на каждую дату и соединять с нужной, слишком неоптимально...

как их снять на каждую дату? мой вариант не правильно работает

Сделал такую связь:
       
ВложенныйЗапрос1.Контрагент = ВложенныйЗапрос.Субконто1
И ВложенныйЗапрос1.Договор = ВложенныйЗапрос.Субконто2
И ВложенныйЗапрос1.ПерваяДатаПлюс15 >= ВложенныйЗапрос.Период

вложенный запрос содержит Остатки и обороты, периодичность секунда.
Возможно ли как то задать, чтобы он присоединял только ту запись, которая меньше ПерваяДатаПлюс15, но максимальна среди таких же

Как-то так в итоге напилил, поправьте меня:
ВЫБРАТЬ
   ХозрасчетныйОстаткиИОбороты.Период КАК Период,
   ХозрасчетныйОстаткиИОбороты.Субконто1 КАК Субконто1,
   ХозрасчетныйОстаткиИОбороты.Субконто2 КАК Субконто2,
   СУММА(ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокКт) КАК СуммаКонечныйОстатокКт
ПОМЕСТИТЬ ВтПоСекундам
ИЗ
   РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(, , Секунда, , Счет В (&Счет62), , ) КАК ХозрасчетныйОстаткиИОбороты

СГРУППИРОВАТЬ ПО
   ХозрасчетныйОстаткиИОбороты.Субконто2,
   ХозрасчетныйОстаткиИОбороты.Субконто1,
   ХозрасчетныйОстаткиИОбороты.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   МИНИМУМ(ХозрасчетныйОбороты.Период) КАК ПерваяДата,
   ХозрасчетныйОбороты.Субконто1 КАК Субконто1,
   ХозрасчетныйОбороты.Субконто2 КАК Субконто2
ПОМЕСТИТЬ ВтПерваяДата
ИЗ
   РегистрБухгалтерии.Хозрасчетный.Обороты(, , Регистратор, Счет В (&Счет62), , , , ) КАК ХозрасчетныйОбороты

СГРУППИРОВАТЬ ПО
   ХозрасчетныйОбороты.Субконто1,
   ХозрасчетныйОбороты.Субконто2
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ХозрасчетныйОстатки.Субконто1 КАК Контрагент,
   ХозрасчетныйОстатки.Субконто2 КАК Договор,
   ХозрасчетныйОстатки.СуммаОстатокКт КАК Задолженность,
   ВтПерваяДата.ПерваяДата КАК ДатаНачалаЗадолженности,
   ВЫБОР
       КОГДА ХозрасчетныйОстатки.Субконто2.УстановленСрокОплаты
           ТОГДА ХозрасчетныйОстатки.Субконто2.СрокОплаты
       ИНАЧЕ "Не изв."
   КОНЕЦ КАК ОтсрочкаПлатежа,
   ДОБАВИТЬКДАТЕ(ВтПерваяДата.ПерваяДата, ДЕНЬ, ХозрасчетныйОстатки.Субконто2.СрокОплаты) КАК ДатаЗадолженностиСУчетомОтсрочки
ПОМЕСТИТЬ ВтПолТаблицы
ИЗ
   РегистрБухгалтерии.Хозрасчетный.Остатки(&Дата, Счет В (&Счет62), , ) КАК ХозрасчетныйОстатки
       ЛЕВОЕ СОЕДИНЕНИЕ ВтПерваяДата КАК ВтПерваяДата
       ПО ХозрасчетныйОстатки.Субконто1 = ВтПерваяДата.Субконто1
           И ХозрасчетныйОстатки.Субконто2 = ВтПерваяДата.Субконто2
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВтПолТаблицы.Контрагент,
   ВтПолТаблицы.Договор,
   МАКСИМУМ(ВтПолТаблицы.Задолженность) КАК Задолженность,
   ВтПолТаблицы.ДатаНачалаЗадолженности,
   ВтПолТаблицы.ОтсрочкаПлатежа,
   ВтПолТаблицы.ДатаЗадолженностиСУчетомОтсрочки,
   МАКСИМУМ(ВтПоСекундам.Период) КАК Период
ПОМЕСТИТЬ ВтПолТаблицы2
ИЗ
   ВтПолТаблицы КАК ВтПолТаблицы
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВтПоСекундам КАК ВтПоСекундам
       ПО ВтПолТаблицы.Контрагент = ВтПоСекундам.Субконто1
           И ВтПолТаблицы.Договор = ВтПоСекундам.Субконто2
           И ВтПолТаблицы.ДатаЗадолженностиСУчетомОтсрочки >= ВтПоСекундам.Период

СГРУППИРОВАТЬ ПО
   ВтПолТаблицы.Контрагент,
   ВтПолТаблицы.Договор,
   ВтПолТаблицы.ДатаЗадолженностиСУчетомОтсрочки,
   ВтПолТаблицы.ДатаНачалаЗадолженности,
   ВтПолТаблицы.ОтсрочкаПлатежа
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ВтПолТаблицы2.Контрагент,
   ВтПолТаблицы2.Договор,
   ВтПолТаблицы2.Задолженность,
   ВтПолТаблицы2.ДатаНачалаЗадолженности,
   ВтПолТаблицы2.ОтсрочкаПлатежа,
   ВтПолТаблицы2.ДатаЗадолженностиСУчетомОтсрочки,
   ВтПоСекундам.СуммаКонечныйОстатокКт КАК ЗадолженностьНаДатуЗадолженностиСУчетомОтсрочки
ИЗ
   ВтПолТаблицы2 КАК ВтПолТаблицы2
       ЛЕВОЕ СОЕДИНЕНИЕ ВтПоСекундам КАК ВтПоСекундам
       ПО ВтПолТаблицы2.Контрагент = ВтПоСекундам.Субконто1
           И ВтПолТаблицы2.Договор = ВтПоСекундам.Субконто2
           И ВтПолТаблицы2.Период = ВтПоСекундам.Период