Собственно, если в 2-х таблицах более 10000 строк и соединение по 1 измерению (Договор) делается >10 минут. Возможно проще в цикле перебрать левую таблицу и находить в правой нужные строки отбором?

Возможно, стоит таки задуматься, почему это соединение 10 минут делается. Ибо это вообще-то ненормально.
Например, потому что нет индекса на поле Договор. Или вы плодите декартово произведение.

нет-нет, строки по договору сгруппированы, индексы стоят.

у меня соединение 3.5млн с 34млн делается за доли секунды. что то у вас не так...

(0) запрос показывай.
У меня что-то > 10 минут запрос никогда не выполнялся

(4) похоже дело уже не в соединении, сейчас просто 2я таблица выводится 10 мин. Либо в ней отбор виртуальной таблицы не надо задавать по всем договорам из первой, либо надо убрать периодичность по регистратору.

ВЫБРАТЬ
   ХозрасчетныйОстатки.Субконто1 КАК Субконто1,
   ХозрасчетныйОстатки.Субконто2 КАК ДоговорКонтрагента,
   СУММА(ХозрасчетныйОстатки.СуммаОстатокДт) КАК Остаток
ПОМЕСТИТЬ ОстаткиЗадолженности
ИЗ
   РегистрБухгалтерии.Хозрасчетный.Остатки(&Дата, Счет = &СчетУчетаРасчетов, , Организация = &Организация) КАК ХозрасчетныйОстатки

СГРУППИРОВАТЬ ПО
   ХозрасчетныйОстатки.Субконто2,
   ХозрасчетныйОстатки.Субконто1

ИНДЕКСИРОВАТЬ ПО
   ДоговорКонтрагента
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   НДСНачисленныйОбороты.СтавкаНДС,
   НДСНачисленныйОбороты.СчетФактура.ДоговорКонтрагента КАК СчетФактураДоговорКонтрагента,
   СУММА(НДСНачисленныйОбороты.НДСПриход) КАК НДСПриход
ИЗ
   РегистрНакопления.НДСНачисленный.Обороты(
           &Дата0,
           &Дата,
           Регистратор,
           Организация = &Организация
               И СчетФактура.ДоговорКонтрагента В
                   (ВЫБРАТЬ
                       ОстаткиЗадолженности.ДоговорКонтрагента
                   ИЗ
                       ОстаткиЗадолженности КАК ОстаткиЗадолженности)) КАК НДСНачисленныйОбороты

СГРУППИРОВАТЬ ПО
   НДСНачисленныйОбороты.СтавкаНДС,
   НДСНачисленныйОбороты.СчетФактура.ДоговорКонтрагента

выразить юзай на Субконто в ВТ

и соединения не вижу.

И СчетФактура.ДоговорКонтрагента В
                   (ВЫБРАТЬ
                       ОстаткиЗадолженности.ДоговорКонтрагента
                   ИЗ
                       ОстаткиЗадолженности КАК ОстаткиЗадолженности))
нафиг так делать? к ВТ левым соединением цепляй НДСНачисленный

НДСНачисленныйОбороты.СчетФактура.ДоговорКонтрагента - а это зачем?
НДСНачисленныйОбороты.ДоговорКонтрагента просто

короче все тормоза от жутко составных типов в полях, приводить к нужным надо если есть возможность

Детализация до регистратора в Оборотах зачем?

(11)+ Периодичность в смысле..

(10)Скорее тормоза от того что получаются обороты с детализацией до регистратора, а потом это все еще и группируется. Баян такой, сначала развернуть, а потом свернуть:)

(9) начисляет без договора, в регистре он пуст.

в итоге: регистратор убрал - не помогло, но (8) помогло!
Спасибо!!
менее минуты

вот так быстро:

ВЫБРАТЬ
   ХозрасчетныйОстатки.Субконто1 КАК Субконто1,
   ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто2 КАК Справочник.ДоговорыКонтрагентов) КАК ДоговорКонтрагента,
   СУММА(ХозрасчетныйОстатки.СуммаОстатокДт) КАК Остаток
ПОМЕСТИТЬ ОстаткиЗадолженности
ИЗ
   РегистрБухгалтерии.Хозрасчетный.Остатки(&Дата, Счет = &СчетУчетаРасчетов, , Организация = &Организация) КАК ХозрасчетныйОстатки

СГРУППИРОВАТЬ ПО
   ХозрасчетныйОстатки.Субконто1,
   ВЫРАЗИТЬ(ХозрасчетныйОстатки.Субконто2 КАК Справочник.ДоговорыКонтрагентов)

ИНДЕКСИРОВАТЬ ПО
   ДоговорКонтрагента
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   НДСНачисленныйОбороты.СтавкаНДС,
   НДСНачисленныйОбороты.СчетФактура.ДоговорКонтрагента КАК СчетФактураДоговорКонтрагента,
   СУММА(НДСНачисленныйОбороты.НДСПриход) КАК НДСПриход
ПОМЕСТИТЬ СтавкиНДС
ИЗ
   РегистрНакопления.НДСНачисленный.Обороты(&Дата0, &Дата, , Организация = &Организация) КАК НДСНачисленныйОбороты

СГРУППИРОВАТЬ ПО
   НДСНачисленныйОбороты.СтавкаНДС,
   НДСНачисленныйОбороты.СчетФактура.ДоговорКонтрагента

ИНДЕКСИРОВАТЬ ПО
   СчетФактураДоговорКонтрагента
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   СтавкиНДС.СчетФактураДоговорКонтрагента КАК СчетФактураДоговорКонтрагента,
   МАКСИМУМ(СтавкиНДС.НДСПриход) КАК НДСПриход
ПОМЕСТИТЬ МаксНДСпоДоговору
ИЗ
   СтавкиНДС КАК СтавкиНДС

СГРУППИРОВАТЬ ПО
   СтавкиНДС.СчетФактураДоговорКонтрагента

ИНДЕКСИРОВАТЬ ПО
   СчетФактураДоговорКонтрагента
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   СтавкиНДС.СтавкаНДС,
   СтавкиНДС.СчетФактураДоговорКонтрагента КАК СчетФактураДоговорКонтрагента,
   СтавкиНДС.НДСПриход
ПОМЕСТИТЬ МаксСтавкаНДСпоДоговору
ИЗ
   СтавкиНДС КАК СтавкиНДС
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ МаксНДСпоДоговору КАК МаксНДСпоДоговору
       ПО СтавкиНДС.СчетФактураДоговорКонтрагента = МаксНДСпоДоговору.СчетФактураДоговорКонтрагента
           И СтавкиНДС.НДСПриход = МаксНДСпоДоговору.НДСПриход

ИНДЕКСИРОВАТЬ ПО
   СчетФактураДоговорКонтрагента
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ОстаткиЗадолженности.Субконто1,
   ОстаткиЗадолженности.ДоговорКонтрагента,
   ОстаткиЗадолженности.Остаток,
   МаксСтавкаНДСпоДоговору.СтавкаНДС,
   МаксСтавкаНДСпоДоговору.НДСПриход
ИЗ
   ОстаткиЗадолженности КАК ОстаткиЗадолженности
       ЛЕВОЕ СОЕДИНЕНИЕ МаксСтавкаНДСпоДоговору КАК МаксСтавкаНДСпоДоговору
       ПО ОстаткиЗадолженности.ДоговорКонтрагента = МаксСтавкаНДСпоДоговору.СчетФактураДоговорКонтрагента

Короче разбей запрос на несколько частей и проанализируй где тормоза. Здесь уже все написали.

(17) все, уже сделал, помогло, (16) - это уже быстрый запрос!