Помогите пожалуйста с куском запроса. В запросе нужно отсечь строки с повторами документа и номера, где дата не максимальная.
Таблица имеет вид:
ссылка_на_документ / дата / стоимость / номенклатура

док 1 ------ дата1 ------ стоимость ---- номенклатура1
док 1 ------ дата2 ------ стоимость ---- номенклатура1
док 1 ------ дата3 ------ стоимость ---- номенклатура2
док 1 ------ дата1 ------ стоимость ---- номенклатура2
док 2 ------ дата1 ------ стоимость ---- номенклатура1
док 2 ------ дата2 ------ стоимость ---- номенклатура1

а должно получиться:
док 1 ------ дата1 ------ стоимость ---- номенклатура1
док 1 ------ дата3 ------ стоимость ---- номенклатура2
док 2 ------ дата1 ------ стоимость ---- номенклатура1

т.е. какая-то ОДНА дата и ОДНА стоимость соответственно.
реально в таблице данные по стоимости номенклатуры с учетом разных цен из регистра Цены - т.е. попали дублирующиеся строчки с разными датами и ценами.

>т.е. какая-то ОДНА дата и ОДНА стоимость соответственно.
для каждой номенклатуры в документе

Бьюсь над этим второй день. Что делалось :)
ВЫБРАТЬ РАЗЛИЧНЫЕ
   ЗаказНарядТовары.Ссылка КАК Ссылка,
   ЦеныСрезПоследних.Цена * ЗаказНарядТовары.Количество КАК СебестоимостьШтуки1,
   ЗаказНарядТовары.Номенклатура,
   ЦеныСрезПоследних.Период
ПОМЕСТИТЬ Табличка
ИЗ
   Документ.ЗаказНаряд.Товары КАК ЗаказНарядТовары
       ПОЛНОЕ СОЕДИНЕНИЕ РегистрСведений.Цены.СрезПоследних(, ТипЦен В (&ЦенаЗакупки)) КАК ЦеныСрезПоследних
       ПО ЗаказНарядТовары.Номенклатура = ЦеныСрезПоследних.Номенклатура
           И ЗаказНарядТовары.Ссылка.Дата >= ЦеныСрезПоследних.Период
ГДЕ
   ЗаказНарядТовары.Ссылка.Дата МЕЖДУ &Дата1 И &Дата2
   И ЗаказНарядТовары.Количество <> 0
   И ЦеныСрезПоследних.Цена <> 0

СГРУППИРОВАТЬ ПО
   ЦеныСрезПоследних.Номенклатура,
   ЗаказНарядТовары.Ссылка,
   ЦеныСрезПоследних.Цена * ЗаказНарядТовары.Количество,
   ЗаказНарядТовары.Номенклатура,
   ЦеныСрезПоследних.Период

//********************************************
ВЫБРАТЬ
   *
ИЗ
   Табличка КАК Табличка
//**********************************************

После этого получаю таблицу как описала выше. Делаю в консоли запросов, чтобы результат видеть.

группировка по документу с агрегатом максимум

цена на номенклатуру не с характеристиками задаются?

почему ПОЛНОЕ СОЕДИНЕНИЕ?

МАКСИМУМ(Период)  предлагали?

(3)(6) знатоки...
как вы думаете, что возвращает РегистрСведений.Цены.СрезПоследних?

А если 2 документа с одной датой:временем ?

(3) Я в этом направлении думала, наверное так и нужно, но пока не получилось. Вот прошу помощи. Могу конечно сюда свой код кинуть - но там чушня.
(4) Характеристик нет.
(5) Исправила не левое. Дубли остаются.

ВЫБРАТЬ
   Табличка.Ссылка,
   Табличка.СебестоимостьШтуки1,
   Табличка.Номенклатура,
   Табличка.Период
ИЗ
   Табличка КАК Табличка
ГДЕ
   Табличка.Период В
           (ВЫБРАТЬ
               МАКСИМУМ(МаксПериоды.Период) КАК Период
           ИЗ
               Табличка КАК МаксПериоды
           ГДЕ
               МаксПериоды.Ссылка = Табличка.Ссылка
               И МаксПериоды.Номенклатура = Табличка.Номенклатура)

(10) Полная лажа

(11) Иди уроки учи, специалист.

Для тех, кто не знает что такое корреляционные запросы решение более понятное

ВЫБРАТЬ
   Табличка.Ссылка,
   Табличка.СебестоимостьШтуки1,
   Табличка.Номенклатура,
   Табличка.Период
ИЗ
   (ВЫБРАТЬ
       Табличка.Ссылка КАК Ссылка,
       Табличка.СебестоимостьШтуки1 КАК СебестоимостьШтуки1,
       Табличка.Номенклатура КАК Номенклатура,
       МАКСИМУМ(Табличка.Период) КАК Период
   ИЗ
       Табличка КАК Табличка
   
   СГРУППИРОВАТЬ ПО
       Табличка.Номенклатура,
       Табличка.Ссылка,
       Табличка.СебестоимостьШтуки1) КАК ВложенныйЗапрос
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Табличка КАК Табличка
       ПО ВложенныйЗапрос.Ссылка = Табличка.Ссылка
           И ВложенныйЗапрос.Номенклатура = Табличка.Номенклатура

+(13) Плюс собственно соединение по периоду "И ВложенныйЗапрос.Период = Табличка.Период"

+(13)(14)

ВЫБРАТЬ
   Табличка.Ссылка,
   Табличка.СебестоимостьШтуки1,
   Табличка.Номенклатура,
   Табличка.Период
ИЗ
   (ВЫБРАТЬ
       Табличка.Ссылка КАК Ссылка,
       Табличка.Номенклатура КАК Номенклатура,
       МАКСИМУМ(Табличка.Период) КАК Период
   ИЗ
       Табличка КАК Табличка
   
   СГРУППИРОВАТЬ ПО
       Табличка.Номенклатура,
       Табличка.Ссылка) КАК ВложенныйЗапрос
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Табличка КАК Табличка
       ПО ВложенныйЗапрос.Ссылка = Табличка.Ссылка
           И ВложенныйЗапрос.Номенклатура = Табличка.Номенклатура
           И ВложенныйЗапрос.Период = Табличка.Период

(15) Это уже более похоже на правду

(10) и (15) Вот этот вариант, на тех наборах, что я обычно проверяю - дал правильный разультат.
Спасибо.
Kashemir, может посоветуете что почитать по SQL запросам в 1С?

Вот правильный ответ:
"ВЫБРАТЬ
|    Табличка.Ссылка КАК Ссылка,
|    Табличка.Номенклатура,
|    МАКСИМУМ(Табличка.Период) КАК Период
|ПОМЕСТИТЬ МаксимальныеДаты
|ИЗ
|    Табличка КАК Табличка
|
|СГРУППИРОВАТЬ ПО
|    Табличка.Ссылка,
|    Табличка.Номенклатура
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|    Табличка.Ссылка КАК Ссылка,
|    Табличка.СебестоимостьШтуки1,
|    Табличка.Номенклатура,
|    Табличка.Период КАК Период
|ИЗ
|    Табличка КАК Табличка
|        ВНУТРЕННЕЕ СОЕДИНЕНИЕ МаксимальныеДаты КАК МаксимальныеДаты
|        ПО Табличка.Ссылка = МаксимальныеДаты.Ссылка
|            И Табличка.Номенклатура = МаксимальныеДаты.Номенклатура
|            И Табличка.Период = МаксимальныеДаты.Период"

(16) Прежде чем делать громкие заявления, попробуй хотя бы проверить.

(17) Что-то конкретное не посоветую. Литературы более достаточно.

(19) Чего проверять? В (10) полная лажа. Видно невооруженным взглядом. В (15) кривоопо, но работать будет

(21) Мда, тяжелый случай. Обратись к старшим товарищам с вопросом что такое корреляционные запросы - пусть тебя просветят.