есть документ Погрузка, есть регистр сведений состояние погрузки, в нем отражается состояние и время состояния - загружено, отменено и пр.
выбрать запросом все состояния по каждому документу - не проблема, но нужно выбрать только те, у которых время начала погрузки (это одно из состояний) попадало в заданный период. не могу сообразить, как...

Сравнивать не умеешь?

что с чем?

(0) Условием.

может где-то вас не понимаю, но, если ставить условия период состояния в заданном интервале, то не весь цикл погрузки может вывестись. т.е. если конец погрузки не попадает в интервал, нам запись все равно нужна, но условием будет резаться

Показывай код, не стесняйся.

МаксимальнаяДатаЦепочки >= &НачалоПериода И МинимальнаяДатаЦепочки <= &КонецПериода , не?

Первым запросом выбирайте из регистра сведений только поле погрузки, попавшие в условие по времени. Без повторяющихся. А во втором - все записи регистра, соединенными с первым запросом по погрузкам.

(5) лучше личико

в общем нужно получить вот такое

машина 1     начало погрузки      13:00
            остановка погрузки   15:00
            продолжение погрузки 18:15
            завершение погрузки  19:00

условие: должны попадать те, у которых начало попадает в интервал, например 12:00 до 18:00
делаю:
                   
                |    ЗагрузкаМашины.Ссылка КАК Ссылка,
                |    ЗагрузкаМашины.Машина КАК Машина,
                |    СобытияЗагрузки.Событие,
                |    СобытияЗагрузки.Период КАК Период
                |ИЗ
                |    РегистрСведений.СобытияЗагрузкиКАК СобытияЗагрузки
                |        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЗагрузкаМашиныКАК ЗагрузкаМашины
                |        ПО СобытияЗагрузки.ЗаданиеСкладу = ЗагрузкаМашины.Ссылка
                |ГДЕ
                |    И СобытияЗагрузки.Событие <> &Событие
                |    И СобытияЗагрузки.Период МЕЖДУ &ДатаН И &ДатаК
                |
                |УПОРЯДОЧИТЬ ПО
                |    ЗагрузкаМашины.Дата,
                |    ЗагрузкаМашины.Машина,
                |    Период
                |ИТОГИ ПО
                |    Ссылка";

отрезаются все события, не попавшие в период

(6) нужно всю цепочку, у которой начало в интервале

(7) щас попробую сообразить, как это

(11) Вот так, примерно:

ВЫБРАТЬ
   СобытияЗагрузки.ЗагрузкаМашины,
   СобытияЗагрузки.Событие,
   СобытияЗагрузки.Период
ИЗ
   РегистрСведений.СобытияЗагрузки КАК СобытияЗагрузки
ГДЕ
   СобытияЗагрузки.ЗагрузкаМашины В
           (ВЫБРАТЬ
               СобытияЗагрузки.ЗагрузкаМашины
           ИЗ
               РегистрСведений.СобытияЗагрузки КАК СобытияЗагрузки
           ГДЕ
               СобытияЗагрузки.Период МЕЖДУ &ДатаНачала И &ДатаОкончания)

(12) отвлекли. это же только часть? соображаю, что получится

и теперь с этим слеплять второй, да?

(14) Нет, это как бы 2 уже :)
Там, еще слова РАЗЛИЧНЫЕ не хватает, после 2-го выбрать

тогда не поняла, вложенный выбирает все записи из РС с датой из интервала, ну пусть, все различные
ага, а потом выбираются все записи по каждому из документов, у которых есть выбранная запись.
наверное путанно написала. вроде поняла, щас свой подокручиваю

ВЫБРАТЬ
   СобытияЗагрузки.ЗагрузкаМашины,
   СобытияЗагрузки1.Событие,
   СобытияЗагрузки1.Период
ИЗ
   Документ.ЗагрузкаМашиныКАК ЗагрузкаМашины
   ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.СобытияЗагрузки КАК СобытияЗагрузки
   ПО СобытияЗагрузки.ЗагрузкаМашины = ЗагрузкаМашины.Ссылка    
       И СобытияЗагрузки.Событие = &СобытиеНачалаОтгрузки
       И СобытияЗагрузки.Период МЕЖДУ &НачалоСобытия И &КонецСобытия
   ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СобытияЗагрузки КАК СобытияЗагрузки1
   ПО СобытияЗагрузки1.ЗагрузкаМашины = ЗагрузкаМашины.Ссылка
       И СобытияЗагрузки1.Период > СобытияЗагрузки.Период

(17) + нужные упорядочивания/группировки

(17) условие на период в последнем джойне >= должно быть, а не >

(12) спасибо, почти так сделала, получилось
(17) тоже завтра со свежей головой попробую.
всем спасибо)

а фото?

хм, оба работают, но если выбирать по группировкам, то почему-то разные по количеству результаты выдают...

(22) ну тогда надо смотреть на обходы группировок

(21)что-то у вас оно не слишком информативное)

(24) пол не тот :)

отмазка)

это в (24) отмазка :) лучшая защита - нападение? :)

(27) ну, тип того.
завтра сдам отчет если - подумаю над фото

(28) как там? народ волнуется...

там не фонтан ((
идея нужна
есть еще некий регистр, в котором фиксируются грузы, которые по времени загружаются в машину.
их тоже нужно вывести, но если прикручивать через левое соединение, то получается,
что каждому из состояний ставится каждый загруженный груз.
в итоге выборка раздувается, т.е. для (9) и списка записей хода погрузки
15:10  груз1
15:18  груз2
14:40  груз3
16:20  груз4
17:21  груз5
18:01  груз6

получается:

машина 1        начало погрузки          13:00    15:10  груз1
               начало погрузки          13:00      15:18  груз2
               начало погрузки          13:00      14:40  груз3
               начало погрузки        13:00      16:20  груз4
               начало погрузки        13:00      17:21  груз5
машина 1        остановка погрузки      15:00    15:10  груз1
               остановка погрузки      15:00    15:18  груз2
               остановка погрузки      15:00    14:40  груз3
               остановка погрузки      15:00    16:20  груз4
               остановка погрузки      15:00    17:21  груз5
машина 1        продолжение погрузки    18:15    15:10  груз1
               продолжение погрузки    18:15    15:18  груз2
               продолжение погрузки    18:15    14:40  груз3
               продолжение погрузки    18:15    16:20  груз4
               продолжение погрузки    18:15    17:21  груз5
машина 1        завершение погрузки      19:00    15:10  груз1
               завершение погрузки    19:00    15:18  груз2
               завершение погрузки    19:00    14:40  груз3
               завершение погрузки    19:00    16:20  груз4
               завершение погрузки    19:00    17:21  груз5

ее бы как-нибудь не так раздуть, как - нибудь вот так хотя бы

машина 1                начало погрузки          13:00    15:10  груз1
               остановка погрузки      15:00    15:18  груз2
               продолжение погрузки    18:15    14:40  груз3
               завершение погрузки      19:00    16:20  груз4
                                       17:21  груз5

(30) о как... тут уже левым соединением не отделаться...
в первом запросе получать события загрузки, нумеровать строки результата в пределах документа погрузки, помещать во времТабл1
затем, вторым запросом получать грузы, тоже нумеровать строки результата в пределах погрузки, помещать во времТабл2
а затем делать полное соединение полученных времТабл1 и времТабл2 по условию равенства документов погрузки и номеров строк

ой, намудрила я сегодня с таблицами, как раз с полным соединением. но там как-то не кузяво вышло,
почти то же самое, только нагромождено. вот думаю, стоит ли с запросом париться, или вывести как есть в тз, а там перебором...

(32) а здесь уже многое от постановки задачи зависит. Если требуют одним запросом - значит надо делать запросом. Если нет жестких требований - тогда лучше воспользоваться теми средствами, которыми владеете на данный момент. Наберетесь опыта - всегда можно будет вернуться и переделать. Как красивее и правильнее.

ага, если бы еще потом 30 програмеров не тыкали в мой код и не ржали )

(32) на мое скромное имхо, отдельными запросами выгрузить в тз1 и тз2 результаты запросов на состояния погрузок и грузы, добавить колонку с номером, пронумеровать, дальше засунуть в третий запрос, в котором уже и сделать полное объединение.

одним не требуют, надо чтоб работало. насколько медленнее тз перебирает? сильно критично?

(34) здоровая критика - это хорошо. ну и пусть ржут, это они на вас возмещают то, что над ними тоже когда-то ржали. программерами не рождаются :)

(36) есть случаи, когда специально уходят от одного запроса в сторону обхода ТЗ. Запрос запросу рознь. Главное, запросов в цикле не делать.

(35)в смысле не в одном запросе даже это делать?

(39) ну, получается, тремя. первые два собирают базовые наборы данных, третий - их объединяет

(30) Тут какая-то неясность иметься:

машина 1                начало погрузки          13:00    15:10  груз1
               остановка погрузки       15:00    15:18  груз2
               продолжение погрузки     18:15    14:40  груз3
               завершение погрузки      19:00    16:20  груз4
                                       17:21  груз5

Если, допустим, началу погрузки еще как-то можно поставить в соответствие какой-то груз, то в остановку погрузки ставить груз - это странная логика. Было бы неплохо, если бы вы структуру своих данных полностью описали. Скорее всего вам потребуется определять интервалы погрузок (Начало - остановка) и для этого интервала указывать грузы, которые были загружены.
Т.е.

Машина 1
 Интервал 13:00 - 15:00
   Груз1  15:10
   Груз2  15:18
 Интервал 18:15 - 19:00
   Груз3  14:40
   Груз4  16:20
   Груз5  17:21

Если так, то надо, конечно, подумать будет, как такое реализовать. Скорее всего, проще уже будет временные таблицы использовать.

(41)
надо было как-то вот так в идеале:

машина 1        начало погрузки          13:00    
               остановка погрузки       15:00    сумма грузов, попавших в этот интервал
               продолжение погрузки     18:15    
               завершение погрузки      19:00    сумма грузов, попавших в этот интервал

сделала цикл в цикле, на пока

(42) Так вы структуру данных опишите подробнее. Обещаю подумать над запросом :)

Документ.ЗагрузкаМашины
Машина

РегистрСведений.СобытияЗагрузки
Событие
Период
ЗаданиеСкладу = Документ.ЗагрузкаМашины

НекийРегистрВКоторомФиксируютсяГрузы
Груз
Период
ЧтоТоЕщеДолжноБыть

да, есть еще один док, который связан с погрузкой через регистр,
и у этого дока есть как раз записи в регистр ХодПогрузки
структура такая:
http://yulochka.narod.ru/1.jpg

(45) как мне кажется, здесь уже запросом решать нецелесообразно. проще и нагляднее обходами тз. по идее, все просто должно быть. как делала, что не получилось?

так получилось цикл в цикле.
считала всегда, что цикл в цикле и запрос в цикле - не айс.
дело еще в том, что по этому отчету нужно диаграмму ввыводить. типа ганта.
но не ганта, потому что по требованиям нужно, чтобы к каждому интервалу текст выводился,
причем и снизу и сверху. у ганта такой возможности нет.
придется ее в макете рисовать, а там тоже в цикле добавлять области,
уже получается тройная вложенность цикла.

(47) если не хочешь цикл-в цикле-в цикле, собирай данные поэтапно
а) собери таблицу
Погрузка1  НачалоПогрузки1 ОкончаниеПогрузки1
Погрузка1  НачалоПогрузки2 ОкончаниеПогрузки2
Погрузка1  НачалоПогрузки3 ОкончаниеПогрузки3
б) по таблице в А пробегись циклом и дополни ее данными по суммам грузов, т.е. чтобы на выходе получилось
Погрузка1  НачалоПогрузки1 ОкончаниеПогрузки1 СуммаГрузов1
Погрузка1  НачалоПогрузки2 ОкончаниеПогрузки2 СуммаГрузов2
Погрузка1  НачалоПогрузки3 ОкончаниеПогрузки3 СуммаГрузов3
в) в одни проход пробегись по Б и выведи в макет

мне нужно и диаграмму, для которой как раз в два столбца удобно, и отчет,
а вот в него нужно выводить все в 1 столбик - тз такое

В общем вот такой ваш запрос получился:

ВЫБРАТЬ
   СобытияПогрузкиНачало.ЗагрузкаМашины,
   СобытияПогрузкиНачало.Период КАК НачалоПериода,
   МИНИМУМ(СобытияПогрузкиОкончание.Период) КАК ОкончаниеПериода
ПОМЕСТИТЬ ИнтервалыЗагрузок
ИЗ
   РегистрСведений.СобытияПогрузки КАК СобытияПогрузкиНачало
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СобытияПогрузки КАК СобытияПогрузкиОкончание
       ПО (СобытияПогрузкиОкончание.Период > СобытияПогрузкиНачало.Период)
ГДЕ
   (СобытияПогрузкиНачало.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.НачалоЗагрузки)
           ИЛИ СобытияПогрузкиНачало.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.ПродолжениеЗагрузки))
   И СобытияПогрузкиНачало.Период МЕЖДУ &ДатаНачала И &ДатаОкончания
   И (СобытияПогрузкиОкончание.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.ОстановкаЗагрузки)
           ИЛИ СобытияПогрузкиОкончание.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.ЗавершениеЗагрузки))

СГРУППИРОВАТЬ ПО
   СобытияПогрузкиНачало.ЗагрузкаМашины,
   СобытияПогрузкиНачало.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ИнтервалыЗагрузок.ЗагрузкаМашины.Машина,
   ИнтервалыЗагрузок.НачалоПериода,
   ИнтервалыЗагрузок.ОкончаниеПериода,
   СУММА(ХодПогрузки.Сумма) КАК Сумма,
   ХодПогрузки.Номенклатура КАК Номенклатура,
   ХодПогрузки.Период КАК ВремяЗагрузки
ИЗ
   РегистрСведений.ХодПогрузки КАК ХодПогрузки
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИнтервалыЗагрузок КАК ИнтервалыЗагрузок
       ПО ХодПогрузки.Период >= ИнтервалыЗагрузок.НачалоПериода
           И ХодПогрузки.Период <= ИнтервалыЗагрузок.ОкончаниеПериода
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ЗагруженныеМашины КАК ЗагруженныеМашины
       ПО ХодПогрузки.ЗагрузкаМашиныМаршрут = ЗагруженныеМашины.ЗагрузкаМашиныМаршрут
           И (ИнтервалыЗагрузок.ЗагрузкаМашины = ЗагруженныеМашины.ЗагрузкаМашины)

СГРУППИРОВАТЬ ПО
   ИнтервалыЗагрузок.ЗагрузкаМашины.Машина,
   ИнтервалыЗагрузок.НачалоПериода,
   ИнтервалыЗагрузок.ОкончаниеПериода,
   ХодПогрузки.Номенклатура,
   ХодПогрузки.Период


Вариант отчета больше похож на предложенный мной. Пример конфигурации с тестовыми данными тут http://clck.ru/d/DQx2asVL19kz7
Готов ответить на вопросы :)

(50) Ссылка не получилась. Вот http://clck.ru/d/DQx2asVL19kz7

Да, во втором запросе группировка лишней будет. Вот так, лучше:

ВЫБРАТЬ
   ИнтервалыЗагрузок.ЗагрузкаМашины.Машина,
   ИнтервалыЗагрузок.НачалоПериода,
   ИнтервалыЗагрузок.ОкончаниеПериода,
   ХодПогрузки.Сумма КАК Сумма,
   ХодПогрузки.Номенклатура КАК Номенклатура,
   ХодПогрузки.Период КАК ВремяЗагрузки
ИЗ
   РегистрСведений.ХодПогрузки КАК ХодПогрузки
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИнтервалыЗагрузок КАК ИнтервалыЗагрузок
       ПО ХодПогрузки.Период >= ИнтервалыЗагрузок.НачалоПериода
           И ХодПогрузки.Период <= ИнтервалыЗагрузок.ОкончаниеПериода
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ЗагруженныеМашины КАК ЗагруженныеМашины
       ПО ХодПогрузки.ЗагрузкаМашиныМаршрут = ЗагруженныеМашины.ЗагрузкаМашиныМаршрут
           И (ИнтервалыЗагрузок.ЗагрузкаМашины = ЗагруженныеМашины.ЗагрузкаМашины)

(50) ого, какую вы работу проделали...
а нет ли тут какого-то оповещения, если в свою ветку кто-то написал? а то я только что увидела :(
по первой части получается, что если любое событие, означающее начало (продолжение) попадает в интервал, то документ погрузки подходит.
а надо, чтобы только те, у которых именно начало в интервале.

можно тоже вложенным, не будет ли нагромождения

до сих пор бросает в дрожь от кода
выбрать ...
       ПО ХодПогрузки.Период >= ИнтервалыЗагрузок.НачалоПериода
           И ХодПогрузки.Период <= ИнтервалыЗагрузок.ОкончаниеПериода

нельзя проще:

выбрать ...
       ПО ХодПогрузки.Период МЕЖДУ ИнтервалыЗагрузок.НачалоПериода
           И ИнтервалыЗагрузок.ОкончаниеПериода

?? аналогично работает, как раз как <= && >=

(55) да не принципиально, вы бы чего по делу лучше сказали...

(50)Сдавать, похоже, буду со вложенными циклами - сроки горят, а для себе все равно потом разбираться буду.

(53) Оповещений нет.
Для ограничения загрузок только по началу погрузки я предлагаю создать еще одну временную таблицу. Полный запрос будет таким:


ВЫБРАТЬ
   СобытияПогрузки.ЗагрузкаМашины
ПОМЕСТИТЬ Загрузки
ИЗ
   РегистрСведений.СобытияПогрузки КАК СобытияПогрузки
ГДЕ
   СобытияПогрузки.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.НачалоЗагрузки)
   И СобытияПогрузки.Период МЕЖДУ &ДатаНачала И &ДатаОкончания
;

////////////////////////////////////////////////////////////////////////////////

ВЫБРАТЬ
   СобытияПогрузкиНачало.ЗагрузкаМашины,
   СобытияПогрузкиНачало.Период КАК НачалоПериода,
   МИНИМУМ(СобытияПогрузкиОкончание.Период) КАК ОкончаниеПериода
ПОМЕСТИТЬ ИнтервалыЗагрузок
ИЗ
   РегистрСведений.СобытияПогрузки КАК СобытияПогрузкиНачало
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ Загрузки КАК Загрузки
       ПО СобытияПогрузкиНачало.ЗагрузкаМашины = Загрузки.ЗагрузкаМашины
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СобытияПогрузки КАК СобытияПогрузкиОкончание
       ПО (СобытияПогрузкиОкончание.ЗагрузкаМашины = СобытияПогрузкиНачало.ЗагрузкаМашины)
           И (СобытияПогрузкиОкончание.Период > СобытияПогрузкиНачало.Период)
ГДЕ
   (СобытияПогрузкиНачало.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.НачалоЗагрузки)
           ИЛИ СобытияПогрузкиНачало.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.ПродолжениеЗагрузки))
   И (СобытияПогрузкиОкончание.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.ОстановкаЗагрузки)
           ИЛИ СобытияПогрузкиОкончание.СобытиеЗагрузки = ЗНАЧЕНИЕ(Перечисление.СобытияЗагрузки.ЗавершениеЗагрузки))

СГРУППИРОВАТЬ ПО
   СобытияПогрузкиНачало.ЗагрузкаМашины,
   СобытияПогрузкиНачало.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
   ИнтервалыЗагрузок.ЗагрузкаМашины.Машина,
   ИнтервалыЗагрузок.НачалоПериода,
   ИнтервалыЗагрузок.ОкончаниеПериода,
   ХодПогрузки.Сумма КАК Сумма,
   ХодПогрузки.Номенклатура КАК Номенклатура,
   ХодПогрузки.Период КАК ВремяЗагрузки
ИЗ
   РегистрСведений.ХодПогрузки КАК ХодПогрузки
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ ИнтервалыЗагрузок КАК ИнтервалыЗагрузок
       ПО ХодПогрузки.Период >= ИнтервалыЗагрузок.НачалоПериода
           И ХодПогрузки.Период <= ИнтервалыЗагрузок.ОкончаниеПериода
       ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ЗагруженныеМашины КАК ЗагруженныеМашины
       ПО ХодПогрузки.ЗагрузкаМашиныМаршрут = ЗагруженныеМашины.ЗагрузкаМашиныМаршрут
           И (ИнтервалыЗагрузок.ЗагрузкаМашины = ЗагруженныеМашины.ЗагрузкаМашины)