Запрос = Новый Запрос;
   Запрос.Текст =
   "ВЫБРАТЬ
   |    ЗаказПокупателя.ДатаОтгрузки,
   |    ЗаказПокупателя.Товары.Номенклатура КАК Номенклатура,
   |   СУММА(ЗаказПокупателя.Товары.Количество) как Количество,
   |    ЗаказПокупателя.СкладГруппа
   |ИЗ
   |    Документ.ЗаказПокупателя КАК ЗаказПокупателя
   |ГДЕ
   |    ЗаказПокупателя.СкладГруппа = &СкладПолучатель
   |
   |СГРУППИРОВАТЬ ПО
   |    Номенклатура";// Вставить содержимое обработчика.
   
   Запрос.УстановитьПараметр("СкладПолучатель", СкладПолучатель);
   ВыборкаРезультата = Запрос.Выполнить().Выбрать();
   
   Пока ВыборкаРезультата.Следующий() цикл
       НоваяСтрока = ЭтотОбъект.Товары.Добавить();
       НоваяСтрока.Номенклатура = ВыборкаРезультата.Номенклатура;
       НоваяСтрока.Количество = ВыборкаРезультата.Количество;
   КонецЦикла;

Пишет Документ.ПеремещениеТоваров.Форма.ФормаДокумента.Форма(2027)}: Ошибка при вызове метода контекста (Выполнить)
   ВыборкаРезультата = Запрос.Выполнить().Выбрать();
по причине:
{(12, 2)}: Поле не найдено "Номенклатура"
<<?>>Номенклатура

ты вручную чтоли группировал? неправильная у тя группировка то.

сделай автоматом с помощью конструктора

Конструкторм сделал потом кое что удалил

а зачем? О_о говорю же, неправильно сгруппировано

(3) LOL

Человек видимо перепутал СГРУППИРОВАТЬ и ИТОГИ

Не смейтесь товарищи делаю в первый раз. Мало ли бывает.

(7) Делаешь в первый раз — не шлифуй руками, доверься конструктору.
Да и вообще не стоит руками что-то править.

Сделала еще раз внемааательно. Ошибок нет. Это уже радостно.

Но блин не грузится док!?

Запрос = Новый Запрос;
   Запрос.Текст =
       "ВЫБРАТЬ
       |    ЗаказПокупателя.ДатаОтгрузки,
       |    ЗаказПокупателя.СкладГруппа,
       |    ЗаказПокупателя.Товары.(
       |        СУММА(Количество),
       |        Номенклатура
       |    )
       |ИЗ
       |    Документ.ЗаказПокупателя КАК ЗаказПокупателя
       |ГДЕ
       |    ЗаказПокупателя.СкладГруппа = &СкладПолучатель
       |    И ЗаказПокупателя.ДатаОтгрузки = &дата
       |
       |СГРУППИРОВАТЬ ПО
       |    ЗаказПокупателя.Товары.(Номенклатура)";

   Запрос.УстановитьПараметр("дата", дата);
   Запрос.УстановитьПараметр("СкладПолучатель", СкладПолучатель);

   Результат = Запрос.Выполнить();

   ВыборкаДетальныеЗаписи = Результат.Выбрать();

   Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
       // Вставить обработку выборки ВыборкаДетальныеЗаписи
   КонецЦикла;

   Пока ВыборкаДетальныеЗаписи.Следующий() цикл
       НоваяСтрока = ЭтотОбъект.Товары.Добавить();
       НоваяСтрока.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;
       НоваяСтрока.Количество = ВыборкаДетальныеЗаписи.Количество;
   КонецЦикла;

По ходу понимаю что даты ведь не совпадают. В документе загрузки с временем дата а в исходном без времени.

Как это одолеть?

(9) "Сделала" "Пол:Мужской"
о_О

(11) Да не русский я. Не обращай внимания тем более это у меня чисто механическая ошибка. Лучше делом помоги.

(11) лучше был бы пол женский, помогли бы быстрее :)

(13) женский+фотка

(12) ни разу так не описывался

Пишет:

{Документ.ПеремещениеТоваров.Форма.ФормаДокумента.Форма(2044)}: Поле объекта не обнаружено (Номенклатура)
       НоваяСтрока.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;

один цикл прибей

Уже прибил. Дошло до (16)

Как из выборки запроса выбрать мне  Номенклатуру то?

твоя номенклатура сидит в ТЧ и "ВыборкаДетальныеЗаписи.Номенклатура" само собой не обнаружено. такой запрос ай-ай...

запрос дурацкий

+(20) тебе нужно перебирать строки ТЧ, чтобы получить номенклатуру, а в данный момент ты получаешь поля выбранные (дата, склад) + коллекцию значений в виде таб части "Товары"

(20) Умом я понимаю что ТЧ это отдельная таблица. Но запрос от клюшек ведь сломал мой мозг

(22) Может в запросе бырать доки а потом без запроса по документам ходит по их табличной части?

(9) не найден документ просто. задача в чем, по запросу непонятно совершенно.

(24) ни в коме случае

(23) в данном случае надо делать вложенную выборку и выборки верхнего уровня по ТЧ

(27) Есть док Перемещение в него надо грузануть данные из документа ЗаказыПокупателей отбор по складу и по дате.

либо использовать итоги в запросе

в конце концов почитай литературу по запросам

(28) параметры как заполняешь? но дата у тебя точно неправильно заполняется ;))

ладно девочки я спать))

(30) Каюсь что недочитал. Вот надо же взять  задачу и еще обещать завтра к утру сделать.

(31) Понимаю что дата нет так заполняется. Но как правильно не знаю.

Дата задается в документах с точность до секунды, так понятно? Используй вместо равенства неравенство и все будет ок ;)

(34) ДА понял я это еще как сделал запрос и глянул на даты дока и дату отгрузки дата отгрузки без времени а док с временем. А Правильно не знаю. Прочитать откуда тоже пока не могу найти.

И как перебрать из тч не знаю.

(9) можно особо не заморачиваться, убрать из запроса агрегацию (СУММА) и группировку:

Запрос.Текст =
       "ВЫБРАТЬ
       |    ЗаказПокупателя.ДатаОтгрузки,
       |    ЗаказПокупателя.СкладГруппа,
       |    ЗаказПокупателя.Товары.(
       |        Количество,
       |        Номенклатура
       |    )
       |ИЗ
       |    Документ.ЗаказПокупателя КАК ЗаказПокупателя
       |ГДЕ
       |    ЗаказПокупателя.СкладГруппа = &СкладПолучатель
       |    И ЗаказПокупателя.ДатаОтгрузки = &дата";


Если помимо табчасти нужны и другие поля для заполнения, тогда внутри цикла получаем следующее (правда цикл в цикле не гуд, но...решение тривиальное):

...
Пока ВыборкаДетальныеЗаписи.Следующий() цикл
...
   ТабЧасть= ВыборкаДетальныеЗаписи.Товары.Выгрузить();
   ТабЧасть.Свернуть("Номенклатура", "Количество");
   Для Каждого ТекСтрока Из ТабЧасть Цикл
       НоваяСтрока = ЭтотОбъект.Товары.Добавить();
       НоваяСтрока.Номенклатура = ВыборкаДетальныеЗаписи.Номенклатура;
           НоваяСтрока.Количество = ВыборкаДетальныеЗаписи.Количество;
   КонецЦикла;
...
КонецЦикла;


|ГДЕ
       |    ЗаказПокупателя.СкладГруппа = &СкладПолучатель
       |    И ЗаказПокупателя.ДатаОтгрузки >= &НачалоПериода и ЗаказПокупателя.ДатаОтгрузки <= &КонецПериода";

(38) тогда уже МЕЖДУ

а лучше так

Запрос.Текст =
       "ВЫБРАТЬ
       |    ЗаказПокупателя.Номенклатура,
       |    ЗаказПокупателя.Количество
       |ИЗ
       |    Документ.ЗаказПокупателя.Товары КАК ЗаказПокупателя
       |ГДЕ
       |    ЗаказПокупателя.СкладГруппа = &СкладПолучатель
       |    И ЗаказПокупателя.ДатаОтгрузки >= &НачалоПериода и ЗаказПокупателя.ДатаОтгрузки <= &КонецПериода";

(39) ну это в конструкторе можно сделать а я руками пишу

(37) О! Снекс Выручил. Ведь видел же когда читал книжку что-то подобное. Видимо надо не только читать еще руки набивать.

(38) И осталось мне определить Начала периода и конец периода с помощью даты документа так?

(42) понятия не имею что у тебя с датами, если за один день тогда так

НачалоПериода=НачалоДня(Период)
КонецПериода=КонецДня(Период)
где Период задан на форме документа

(41) можно и вне конструктора руками набрать МЕЖДУ ;)
(42) не привыкай к таким решениям =) и максимально все делать стоит в запросе, а дальше уже использовать полученный результат (ну "до утра" думаю сойдет, хех)

(44) зануда ))

(43) Как раз то что надо. Снекс.

И это мне еще в параметр засунуть?

(46) ясен пень ))

Спасибо ребяты! Век не забуду! С почином меня...

Получилось. Но блин что-туго воспринимаю.Как всегда лиха беда начала...

Зря мы убрали группировки. В док одноименные товары попадают по нескольку раз.
Хотелось бы свернутые данные.

добавь группировку, не вижу проблем. Ты какой запрос использовал?

а свертку мы зачем делали внутри первого цикла? не уж-то не свернулось?!

(51) у него там еще и поименные дубли))

Помогли переделал все и ок.

НачалоПериода=НачалоДня(Дата);
   КонецПериода=КонецДня(Дата);
   Запрос = Новый Запрос;
   Запрос.Текст =
       "ВЫБРАТЬ
       |    ЗаказПокупателяТовары.Номенклатура,
       |    СУММА(ЗаказПокупателяТовары.Количество) КАК Количество,
       |    ЗаказПокупателяТовары.ЕдиницаИзмерения,
       |    ЗаказПокупателяТовары.Коэффициент,
       |    ЗаказПокупателяТовары.Цена
       |ИЗ
       |    Документ.ЗаказПокупателя.Товары КАК ЗаказПокупателяТовары
       |ГДЕ
       |    ЗаказПокупателяТовары.Ссылка.ДатаОтгрузки МЕЖДУ &НачалоПериода И &КонецПериода
       |    И ЗаказПокупателяТовары.Ссылка.СкладГруппа = &СкладПолучатель
       |    И ЗаказПокупателяТовары.Ссылка.Проведен
       |
       |СГРУППИРОВАТЬ ПО
       |    ЗаказПокупателяТовары.Номенклатура,
       |    ЗаказПокупателяТовары.ЕдиницаИзмерения,
       |    ЗаказПокупателяТовары.Коэффициент,
       |    ЗаказПокупателяТовары.Цена";
   Запрос.УстановитьПараметр("НачалоПериода", НачалоПериода);
   Запрос.УстановитьПараметр("КонецПериода", КонецПериода);
   Запрос.УстановитьПараметр("СкладПолучатель", СкладПолучатель);

   Результат = Запрос.Выполнить();
   ВыборкаДетальныеЗаписи = Результат.Выбрать();
   Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
       НоваяСтрока = ЭтотОбъект.Товары.Добавить();
       НоваяСтрока.Номенклатура    = ВыборкаДетальныеЗаписи.Номенклатура;
       НоваяСтрока.Количество      = ВыборкаДетальныеЗаписи.Количество;
       НоваяСтрока.ЕдиницаИзмерения = ВыборкаДетальныеЗаписи.ЕдиницаИзмерения;
       НоваяСтрока.Коэффициент    = ВыборкаДетальныеЗаписи.Коэффициент;
       НоваяСтрока.Цена = ВыборкаДетальныеЗаписи.Цена;
       ОбработкаТабличныхЧастей.ПриИзмененииНоменклатурыТабЧасти(НоваяСтрока, ЭтотОбъект);
       ЗаполнитьСчетаУчетаВСтрокеТабЧастиРегл(НоваяСтрока, "Товары", Истина);
       НоваяСтрока.Качество = Справочники.Качество.Новый;
   КонецЦикла;

(52) подразумеваю просто, что здесь был выложен сначала изначальный код запроса, под него подстроились, потом он был модифицирован, а код перебора остался прежним...
(53) финишед хим? :)

(54) НУ да все срослось.

Не подумал что ТЧ можно как отдельную таблице расматривать.