такой вот код:

   СписокКонтрагентов = Новый СписокЗначений;
   Для Каждого ЭлементОформления Из ОформленияСтрок Цикл
       СписокКонтрагентов.Добавить(ЭлементОформления.ДанныеСтроки.Ссылка);
   КонецЦикла;    
   Запрос = Новый Запрос("
   |ВЫБРАТЬ
   |    КонтактнаяИнформация.Объект
   |ПОМЕСТИТЬ СписКонтрагентов
   |ИЗ
   |    РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
   |ГДЕ
   |    КонтактнаяИнформация.Объект В ИЕРАРХИИ (&СписокКонтрагентов)
   |;
   |ВЫБРАТЬ
   |    Выразить(КонтактнаяИнформация.Представление КАК Строка(100)) КАК Адрес,
   |    КонтактнаяИнформация.Объект
   |ПОМЕСТИТЬ ТабАдресов
   |ИЗ
   |    РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
   |ГДЕ
   |    КонтактнаяИнформация.Вид = &Адрес
   |    И КонтактнаяИнформация.Объект В    (ВЫБРАТЬ СписКонтрагентов.Объект
   |                                    ИЗ СписКонтрагентов КАК СписКонтрагентов)
   |;
   |ВЫБРАТЬ
   |    Выразить(КонтактнаяИнформация.Представление КАК Строка(100)) КАК Телефон,
   |    КонтактнаяИнформация.Объект
   |ПОМЕСТИТЬ ТабТелефонов
   |ИЗ
   |    РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
   |ГДЕ
   |    КонтактнаяИнформация.Вид = &Телефон
   |    И КонтактнаяИнформация.Объект В    (ВЫБРАТЬ СписКонтрагентов.Объект
   |                                    ИЗ    СписКонтрагентов КАК СписКонтрагентов)
   |;
   |ВЫБРАТЬ РАЗЛИЧНЫЕ
   |    ТабАдресов.Объект,
   |    ТабАдресов.Адрес,
   |    ТабТелефонов.Телефон
   |ИЗ
   |    СписКонтрагентов КАК СписКонтрагентов,
   |    ТабАдресов КАК ТабАдресов
   |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ТабТелефонов КАК ТабТелефонов
   |        ПО ТабАдресов.Объект = ТабТелефонов.Объект    
   |");
   Запрос.УстановитьПараметр("СписокКонтрагентов", СписокКонтрагентов);
   Запрос.УстановитьПараметр("Телефон", Справочники.ВидыКонтактнойИнформации.ТелефонКонтрагента);
   Запрос.УстановитьПараметр("Адрес", Справочники.ВидыКонтактнойИнформации.ЮрАдресКонтрагента);

Получаю плоскую табличку, собственно то что и хочу, но мучает вопрос, а нельзя-ли подЗапросы по Адресу и по Телефону сделать в одном? Вернее сделать-то можно, но у меня при этом табличка "рассламвается", телефон и Адрес получаются в разных строках

Можно

Немного извращенной фантазии

(2) я пробовал конструкцию КОГДА, получил не то ...можно маленько указать куда фантазировать?

ВЫБРАТЬ
   ЗначенияСвойствОбъектов.Объект КАК Номенклатура,
   МАКСИМУМ(ВЫБОР
           КОГДА ЗначенияСвойствОбъектов.Свойство = &Емкость
               ТОГДА ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК ЧИСЛО(9, 3))
           ИНАЧЕ NULL
       КОНЕЦ) КАК Емкость,
   МАКСИМУМ(ВЫБОР
           КОГДА ЗначенияСвойствОбъектов.Свойство = &Вес
               ТОГДА ЗначенияСвойствОбъектов.Значение
           ИНАЧЕ NULL
       КОНЕЦ) КАК Вес,
   МАКСИМУМ(ВЫБОР
           КОГДА ЗначенияСвойствОбъектов.Свойство = &Цвет
               ТОГДА ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК Справочник.Контрагенты)
           ИНАЧЕ NULL
       КОНЕЦ) КАК Цвет
ПОМЕСТИТЬ ПараметрыНоменклатуры
ИЗ
   РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
ГДЕ
   ЗначенияСвойствОбъектов.Свойство В (&Емкость, &Вес, &Цвет)

СГРУППИРОВАТЬ ПО
   ЗначенияСвойствОбъектов.Объект

кста, если соединить  Адресу и Телефон - быстрее работать будет?

(5) Быстрее. Но не критично. Мне (4) нравиться больше.

Цвет и
ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Значение КАК Справочник.Контрагенты)

не обращайте внимания, это переделывалось на скорую руку.

(7) я понял, дело в МАКСИМУМ
а как быть если у меня еще КонтактнаяИнформация.Объект?
проверять Адрес и Телефон и если оба пустые тогда тоже NULL?

+8 в смысле
ВЫБРАТЬ
   МАКСИМУМ(ВЫБОР
       КОГДА КонтактнаяИнформация.Вид = &Адрес
           ТОГДА ВЫРАЗИТЬ(КонтактнаяИнформация.Представление КАК СТРОКА(100))
            ИНАЧЕ NULL
   КОНЕЦ) КАК Адрес,
   МАКСИМУМ(ВЫБОР
       КОГДА КонтактнаяИнформация.Вид = &Телефон
           ТОГДА ВЫРАЗИТЬ(КонтактнаяИнформация.Представление КАК СТРОКА(100))
            ИНАЧЕ NULL
   КОНЕЦ) КАК Телефон,
   КонтактнаяИнформация.Объект
ПОМЕСТИТЬ ТабАдресовИтелефонов

СГРУППИРОВАТЬ ПО
   КонтактнаяИнформация.Объект

Один в один у меня - твой запрос.

праильно делать левое соединение по объету типу и виду без доп временных таблиц ибо только тогда в индекс попадается.
а за код как в (4) вообще нужно руки отрубать

Так а где тут пакетные запросы ?

(12) Расскажи мне, за что тут руки отрубать.

(14) ибо ты вообще не думаешь о производительности запросов, только о корректной выборке

(13) уже все в пакетах )))

(11) да, я недосмотрел ЗначенияСвойствОбъектов.Объект КАК Номенклатура,
(12) ?
(13) в (0) не?

(15) Ну что там с производительностью?

(18) ты вообще понимаешь выражение "попасть в индекс"?

(19) Ты мне "мясо" давай.

(19) Расскажи, как бы сделал ты.

ВЫБРАТЬ
   КИ_Телефон.Представление,
   КИ_Адрес.Представление КАК Представление1,
   Контрагенты.Ссылка
ИЗ
   Справочник.Контрагенты КАК Контрагенты
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КИ_Телефон
       ПО (КИ_Телефон.Объект = Контрагенты.Ссылка)
           И (КИ_Телефон.Тип = &Т1)
           И (КИ_Телефон.Вид = &В1)
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КИ_Адрес
       ПО (КИ_Адрес.Объект = Контрагенты.Ссылка)
           И (КИ_Адрес.Тип = &Т2)
           И (КИ_Адрес.Вид = &В2)

Причем обязательно соединяться по полю ТИП так как он первый в индексе

(22) а как-же http://chistov.spb.ru/publ/5-1-0-13 ?

(19) собственно ты не один такой, большинство ванцырей не понимают про "попадания в индекс"

(23) это он так учит как в (0)? ППЦ

(22) ИМХАЕТсся мне , что раз пошло дело про оптимизацию
то тут
ВЫБРАТЬ
   КИ_Телефон.Представление,
   КИ_Адрес.Представление КАК Представление1,

надо бы типы ограничить

(25) ну я так понял, на истину не претендую. А что в (0) не так? ...результат есть

(22) Все же применительно к моему запросу по свойствам

ЗначенияСвойствОбъектов.Свойство В (&Емкость, &Вес, &Цвет)

не будет индекс использовать?

(22) А твой код на небольшой табличке 2 раза TableScan сделает скорее всего.

Хотя че я гадаю, счаст глянем.

(28) у тебя поле свойство индексировано? НЕТ

ты "убиваешь" даже индекс по объекту, т.к. делаешь временную таблицу

(31) Нет. Так что мне на попадание в Индекс плевать.

(32) Лучше "убить" индекс и сделать его снова во временной, чем городить адскую кашу потом, в которой захлебнется оптимизатор.

(27) читай (15)

(34) И последующий программист.

ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КИ_Адрес
       ПО (КИ_Адрес.Объект = Контрагенты.Ссылка)
           И (КИ_Адрес.Тип = &Т2)
           И (КИ_Адрес.Вид = &В2)

Это адская каша? вот у тебя адская каша и максимум и группировка

Какой код легче читать? в (0) или (22)?

и максимум и группировка - ничего с этом страшного нет.

(26) вот эта оптимизация уже от лукавого

(38) читать легче (4)

(39) ты просто никогда с высоконагруженными системами не работал. на  2х человек в файловой конечно никакой разницы нет

(42) Я понял тебя провидец.

Хотя ну строится отчет 5 мин да и ладно, но ведь он может строиться всего 5 сек

(44) а почему Выборка по спраовчнику, почему не по регистру? Если по регистру - мы-ж  сразу отрезаем контрагентов с незаполненной КИ?

(45) а их надо отрезать?

(46) ну да ...собственно это не отчет, это вывод Адреса и телефона в форму списка справочника

+(47)  в общем нижевыложенный код дает ne-же табличку что и в (0), не знаю правда пока, какой быстрее
ВЫБРАТЬ РАЗЛИЧНЫЕ
   Выразить(КИ_Телефон.Представление КАК Строка(100)) КАК КИ_Телефон,
   Выразить(КИ_Адрес.Представление КАК Строка(100)) КАК КИ_Адрес,
   Контрагенты.Объект
ИЗ
   РегистрСведений.КонтактнаяИнформация КАК Контрагенты
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КИ_Телефон
       ПО (КИ_Телефон.Объект = Контрагенты.Объект)
           И (КИ_Телефон.Тип = &Т1)
           И (КИ_Телефон.Вид = &В1)
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КИ_Адрес
       ПО (КИ_Адрес.Объект = Контрагенты.Объект)
           И (КИ_Адрес.Тип = &Т2)
           И (КИ_Адрес.Вид = &В2)
ГДЕ
   Контрагенты.Объект В ИЕРАРХИИ (&Контрагенты)

+(48) на небольшом справочнике, замер показал примерно одинаковые значения для (0) и (48): 0.015..0.016

Всем спасибо!

(49) пройдет время, и станет так: http://s006.radikal.ru/i213/1207/b0/688850f4e536.png

(49) На небольшом справочнике индексы не используются.

(50) не понял
(51) запомню :)

(48) зачем различные???

(52) 120 тысяч в смысле?  Не думаю, не тот размах

(52).1 я к тому, что базы имеют тенденцию к росту. у меня в базе ~120к контрагентов, в регистре "контактная информация" ~1,5м записей

(55) можешь замер сделать?

(53) без РАЗЛИЧНЫЕ строки повторяются по нескольку раз

(57) не может быть. хначит ты параметры неверно установил

а понял ты справочник опять заменил на регистр. не стоило

лучше писть
НЕ КИ_Адрес.Объект ЕСТЬ NULL
ИЛИ НЕ КИ_Телефон.Объект ЕСТЬ NULL

(60)  вместо Выразить?

ВЫБРАТЬ
   КонтактнаяИнформация.Объект,
   МАКСИМУМ(ВЫБОР
           КОГДА КонтактнаяИнформация.Вид = &Адрес
               ТОГДА ПОДСТРОКА(КонтактнаяИнформация.Представление, 1, 1000)
           ИНАЧЕ NULL
       КОНЕЦ) КАК Адрес,
   МАКСИМУМ(ВЫБОР
           КОГДА КонтактнаяИнформация.Вид = &Телефон
               ТОГДА ПОДСТРОКА(КонтактнаяИнформация.Представление, 1, 1000)
           ИНАЧЕ NULL
       КОНЕЦ) КАК Поле1
ИЗ
   РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
ГДЕ
   КонтактнаяИнформация.Вид В(&Виды)

СГРУППИРОВАТЬ ПО
   КонтактнаяИнформация.Объект

Юзает IndexSeek.

Причем сцуко странно юзает

Когда ему явно скажешь
with (index(_InfoR14844_ByDims20174_RRR))

А так то - TableScan :-)

ВЫБРАТЬ
   КИ_Телефон.Представление,
   КИ_Адрес.Представление КАК Представление1,
   Контрагенты.Ссылка
ИЗ
   Справочник.Контрагенты КАК Контрагенты
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КИ_Телефон
       ПО (КИ_Телефон.Объект = Контрагенты.Ссылка)
           И (КИ_Телефон.Тип = &Т1)
           И (КИ_Телефон.Вид = &В1)
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.КонтактнаяИнформация КАК КИ_Адрес
       ПО (КИ_Адрес.Объект = Контрагенты.Ссылка)
           И (КИ_Адрес.Тип = &Т2)
           И (КИ_Адрес.Вид = &В2)
ГДЕ
 НЕ КИ_Адрес.Объект ЕСТЬ NULL
 ИЛИ НЕ КИ_Телефон.Объект ЕСТЬ NULL

(65) я понял уже, спасибо