Добрый день, возник такой вопрос, как определить, что за объект метаданных используется, по его ссылке, т.е
есть тип СправочникСсылка.Сотрудники, например, нужно определить, что это именно справочник, если ДокументСсылка, то что это документ соответственно, как это сделать?

Если Справочники.ТипВсеСсылки.СодержитТип(ТипЗнч(Ссылка)) Тогда
...это справочник

ок, спасибо

Ещё вариант...

ТипСтрокой = Строка(ТипЗнч(Ссылка));
ВидМетаданногоСтрокой = Лев(ТипСтрокой, Найти(ТипСтрокой, ".") - 1);

Если ВидМетаданногоСтрокой = "ДокументСсылка" Тогда
ИначеЕсли ВидМетаданногоСтрокой = "СправочникСсылка" Тогда
...
ИначеЕсли ВидМетаданногоСтрокой = "ЗадачаСсылка" Тогда
КонецЕсли;

Возможно, это будет несколько побыстрее, чем (1) работать.

Тогда уж
Метаданные.Справочники.Содержит(Ссылка.Метаданные())

(4) А всё-же как быстрее по замеру производительности - (1), (3) или (4) ???

(5) 3 критично к языку, например

(3) Не рабочий, т.к. Строка(ТипЗнч(Ссылка)) не будет содержать ни "ДокументСсылка", ни "СправочникСсылка"
[верно для 8.2]

Если через строки то уж тогда Ссылка.Метаданные().ПолноеИмя()

(5) на 8.2 не будет работать (3), там Синоним объекта в строке

я бы (4) использовал

по феншую имхо (1)

(11) только со скобками после ТипВсессылки :)

Согласен, исключает ошибку в случае если проверяемое значение не ссылочного типа

(13) и помоему быстрее чем через метаданные

(14) Затестил.
Справочники.ТипВсеСсылки().СодержитТип(ТипЗнч(Справочники.Валюты.ПустаяСсылка()))
примерно в два раза быстрее чем
Метаданные.Справочники.Содержит(Справочники.Валюты.ПустаяСсылка().Метаданные())

но в 2 раза вылилось что типа "5 миллинных секунды vs 9 миллионных"

Функция ПолучитьИмяБазовогоТипаПоТипуОбъекта(ТипОбъекта) Экспорт
   
   МетаданныеТипа = Метаданные.НайтиПоТипу(ТипОбъекта);
   
   Если МетаданныеТипа = Неопределено Тогда
       
       Возврат "УдалениеОбъекта";
       
   ИначеЕсли Метаданные.РегистрыСведений.Содержит(МетаданныеТипа) Тогда
       
       Возврат "РегистрыСведений";
       
   ИначеЕсли Метаданные.Документы.Содержит(МетаданныеТипа) Тогда
       
       Возврат "Документы";
       
   ИначеЕсли Метаданные.Справочники.Содержит(МетаданныеТипа) Тогда
       
       Возврат "Справочники";    
       
   ИначеЕсли Метаданные.РегистрыНакопления.Содержит(МетаданныеТипа) Тогда
   
       Возврат "РегистрыНакопления";    
       
   ИначеЕсли Метаданные.РегистрыБухгалтерии.Содержит(МетаданныеТипа) Тогда
   
       Возврат "РегистрыБухгалтерии";    
     
   Иначе
     
       Возврат "";
       
   КонецЕсли;
           
КонецФункции


Соответственно вызов

ИмяБазовогоТипа = ПолучитьИмяБазовогоТипаПоТипуОбъекта(ТипЗнч(ТекущийРеквизит.ПолучитьОбъект()));

(7)Тьху-ё и правда (((.

(14), (15) А вот как надо (Ссылка.Метаданные() - быстрейший способ получения метаданных):

ПолноеИмяМетаданного = Ссылка.Метаданные().ПолноеИмя();
ВидМетаданногоСтрокой = Лев(ПолноеИмяМетаданного, Найти(ПолноеИмяМетаданного, ".") - 1);

Если ВидМетаданногоСтрокой = "Документ" Тогда
//это документ
ИначеЕсли ВидМетаданногоСтрокой = "Справочник" Тогда
//это справочник
...
ИначеЕсли ВидМетаданногоСтрокой = "Задача" Тогда
//это задача
КонецЕсли;

(16) Очень медлительный вариант

короче (1) наше всё, остальное быдлокод! С пятницей!

(18) Зато правильный ибо не зависит от представления. А в практике уже были случае когда 1С меняла представление при смене платфйормы

(20) Это (17) тоже не зависит от представления. Насчет (3) - полностью согласен, я ошибся.

(17) Затестил.
ПолноеИмяМетаданного=Справочники.Валюты.ПустаяСсылка().Метаданные().ПолноеИмя();х=Лев(ПолноеИмяМетаданного, Найти(ПолноеИмяМетаданного, ".")-1)="Справочник";
Самый медленный вариант. Правда, с минимальным отставанием от других.

Тоже за (1) тогда ;)

(22) На операцию Справочники.Валюты.ПустаяСсылка() львиная доля времени уходит, а в (17) просто Ссылка.Метаданные() и всё.

(24) В идентичных условиях. См (15)

Возможно, (17) в случае именно "копмлексной функции" и минимально лучше будет по скорости, но (1) лучше по читабельности и надежности

Присоединяюсь, всех с пятницей.

(26) Выбрал ссылку на перечисление, чтоб внизу разветвляющейся структуры обоих алгоритмов было и проверок было максимум. (3) в 4 раза быстрее (1) уже при малом объеме метаданных (конфа в 5-7 раз меньше Бух 2.0)

Тестируем (3) на типе объекта "Перечисление"

&НаСервереБезКонтекста
Процедура Третий(СсылкаНаОбъект)
   
   ПолноеИмяМетаданного = СсылкаНаОбъект.Метаданные().ПолноеИмя();
   ВидМетаданногоСтрокой = Лев(ПолноеИмяМетаданного, Найти(ПолноеИмяМетаданного, ".") - 1);
   
   Если ВидМетаданногоСтрокой = "Документ" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "Справочник" Тогда
   
   ИначеЕсли ВидМетаданногоСтрокой = "ПланВидовХарактеристик" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "ПланВидовРасчета" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "Задача" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "БизнесПроцесс" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "Перечисление" Тогда
       
   КонецЕсли;
   
КонецПроцедуры


Время 0,00011

Тестируем (1) на типе объекта "Перечисление"

&НаСервереБезКонтекста
Процедура Первый(СсылкаНаОбъект)
   
   Если Документы.ТипВсеСсылки().СодержитТип(ТипЗнч(СсылкаНаОбъект)) Тогда    
       
   ИначеЕсли Справочники.ТипВсеСсылки().СодержитТип(ТипЗнч(СсылкаНаОбъект)) Тогда    
       
   ИначеЕсли ПланыВидовХарактеристик.ТипВсеСсылки().СодержитТип(ТипЗнч(СсылкаНаОбъект)) Тогда    
       
   ИначеЕсли ПланыВидовРасчета.ТипВсеСсылки().СодержитТип(ТипЗнч(СсылкаНаОбъект)) Тогда    
       
   ИначеЕсли Задачи.ТипВсеСсылки().СодержитТип(ТипЗнч(СсылкаНаОбъект)) Тогда    
       
   ИначеЕсли БизнесПроцессы.ТипВсеСсылки().СодержитТип(ТипЗнч(СсылкаНаОбъект)) Тогда    
       
   ИначеЕсли Перечисления.ТипВсеСсылки().СодержитТип(ТипЗнч(СсылкаНаОбъект)) Тогда    
       
   КонецЕсли;

КонецПроцедуры

Время 0,00046

(28) а всё равно (1) правильней, и такие универсальные не используются как правило

(29) >правильней
чем?
>такие универсальные не используются как правило
В типовых в модуле ОбщегоНазначения эти механизмы присутствуют.

(0) эта байда в БСП в обоих вариантах есть, причем идентикатор класса объекта метаданных там определяться через хмл-типизацию и англоязный аналог и это привильно

(30) просто по феншую это. религиозно правильно.
Как правило не сипользуется - не значит что вобще

(30) (16) из типовой БП 2.0

(32) (1) по феншую, (3) - по пьяни, (17) - по быстродействию.
(33) Верно. На больших конфигурациях это будет работать в десятки раз медленнее.

(34) Да нету там быстродействия

(28)

Процедура Третий(СсылкаНаОбъект)
   
   ПолноеИмяМетаданного = СсылкаНаОбъект.Метаданные().ПолноеИмя();
   ВидМетаданногоСтрокой = Лев(ПолноеИмяМетаданного, Найти(ПолноеИмяМетаданного, ".") - 1);
   
   Если ВидМетаданногоСтрокой = "Документ" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "Справочник" Тогда
   
   ИначеЕсли ВидМетаданногоСтрокой = "ПланВидовХарактеристик" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "ПланВидовРасчета" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "Задача" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "БизнесПроцесс" Тогда
       
   ИначеЕсли ВидМетаданногоСтрокой = "Перечисление" Тогда
       
   КонецЕсли;
   
КонецПроцедуры

Процедура Первый(СсылкаНаОбъект)
   
   Тип=ТипЗнч(СсылкаНаОбъект);
   Если Документы.ТипВсеСсылки().СодержитТип(Тип) Тогда    
       
   ИначеЕсли Справочники.ТипВсеСсылки().СодержитТип(Тип) Тогда    
       
   ИначеЕсли ПланыВидовХарактеристик.ТипВсеСсылки().СодержитТип(Тип) Тогда    
       
   ИначеЕсли ПланыВидовРасчета.ТипВсеСсылки().СодержитТип(Тип) Тогда    
       
   ИначеЕсли Задачи.ТипВсеСсылки().СодержитТип(Тип) Тогда    
       
   ИначеЕсли БизнесПроцессы.ТипВсеСсылки().СодержитТип(Тип) Тогда    
       
   ИначеЕсли Перечисления.ТипВсеСсылки().СодержитТип(Тип) Тогда    
       
   КонецЕсли;

КонецПроцедуры


СсылкаНаОбъект=Перечисления.ABCКлассификация.ПустаяСсылка();

Для i=1 по 100000 цикл Третий(СсылкаНаОбъект); конецЦикла;  // 1.966
Для i=1 по 100000 цикл Первый(СсылкаНаОбъект);  конецЦикла; // 3.057

СсылкаНаОбъект=Документы.ABCКлассификацияПокупателей.ПустаяСсылка();

Для i=1 по 100000 цикл Третий(СсылкаНаОбъект); конецЦикла;    // 1.651
Для i=1 по 100000 цикл Первый(СсылкаНаОбъект);  конецЦикла; // 1.058


Т.е. в неблагоприятных условиях стравнение строк выполняется быстрее, чем поиск (кто бы сомневался) а в благоприятных, напротив твоя ф-я медленней.
При этом метод через типы может работать с любым типом! Зачем при прочих равных выбирать менее надежный вариант?

И (29) прав, зачем универсальная? Чтоб потом опять строить кучу Если вокруг возвращенного значения?

(36) Это хороший анализ алгоритмов. Теперь можно ставить точку.

.