Имя: Пароль:
1C
1С v8
Проблема в написании ВПФ
,
0 pers200590
 
16.09.12
06:58
Здравствуйте
При тестировании написанной мной ВПФ пишет:
Ошибка печати: Поле объекта не обнаружено (ПредставлениеСклада)
Просьба помогите разобраться
Вот текст процедуры:

Функция СформироватьПечатнуюФормуНакладная(МассивОбъектов, ОбъектыПечати)
   
   КолонкаКодов = ФормированиеПечатныхФорм.ИмяДополнительнойКолонки();
   ВыводитьКоды = ЗначениеЗаполнено(КолонкаКодов);
   
   ИспользоватьРучныеСкидки = ПолучитьФункциональнуюОпцию("ИспользоватьРучныеСкидкиВЗакупках");
   Розничная = Справочники.ВидыЦен.НайтиПоНаименованию("Розничные");
   Если Не ЗначениеЗаполнено(Розничная) Тогда
       Сообщить("Не найдена розничный вид цены");
       Возврат Неопределено;
   КонецЕсли;
   
   Запрос = Новый Запрос(
   "ВЫБРАТЬ
   |    ПоступлениеТоваровУслуг.Ссылка КАК Ссылка,
   |    ПоступлениеТоваровУслуг.Номер КАК Номер,
   |    ПоступлениеТоваровУслуг.Дата КАК Дата,
   |    ПоступлениеТоваровУслуг.Склад КАК Склад,
   |    ПоступлениеТоваровУслуг.Партнер КАК Партнер,
   |    ПРЕДСТАВЛЕНИЕ(ПоступлениеТоваровУслуг.Склад) КАК ПредставлениеСклада,
   |    ПоступлениеТоваровУслуг.Контрагент КАК Поставщик,
   |    ПоступлениеТоваровУслуг.Организация КАК Организация,
   |    ПоступлениеТоваровУслуг.Организация.Префикс КАК Префикс,
   |    ПоступлениеТоваровУслуг.Валюта КАК Валюта,
   |    ПоступлениеТоваровУслуг.ЦенаВключаетНДС КАК ЦенаВключаетНДС,
   |    ПоступлениеТоваровУслуг.Принял.Наименование КАК ПолучениеПроизвел,
   |    ВЫБОР
   |        КОГДА ПоступлениеТоваровУслуг.НалогообложениеНДС = ЗНАЧЕНИЕ(Перечисление.ТипыНалогообложенияНДС.ПродажаОблагаетсяНДС)
   |            ТОГДА ИСТИНА
   |        ИНАЧЕ ЛОЖЬ
   |    КОНЕЦ КАК УчитыватьНДС
   |ИЗ
   |    Документ.ПоступлениеТоваровУслуг КАК ПоступлениеТоваровУслуг
   |ГДЕ
   |    ПоступлениеТоваровУслуг.Ссылка В(&МассивДокументов)
   |
   |УПОРЯДОЧИТЬ ПО
   |    Ссылка
   |;
   |
   |////////////////////////////////////////////////////////////////////////////////
   |ВЫБРАТЬ
   |    ВложенныйЗапрос.Ссылка КАК Ссылка,
   |    ВложенныйЗапрос.Номенклатура КАК Номенклатура,
   |    ВложенныйЗапрос.Номенклатура.НаименованиеПолное КАК ТоварНаименованиеПолное,
   |    ВложенныйЗапрос.Номенклатура.Код КАК Код,
   |    ВложенныйЗапрос.Номенклатура.Артикул КАК Артикул,
   |    ВложенныйЗапрос.ЕдиницаИзмерения.Наименование КАК ЕдиницаЦены,
   |    ВложенныйЗапрос.ЕдиницаИзмерения КАК ЕдиницаИзмерения,
   |    ВложенныйЗапрос.Характеристика.НаименованиеПолное КАК Характеристика,
   |    ВЫБОР
   |        КОГДА ЕСТЬNULL(ВложенныйЗапрос.Упаковка.Коэффициент, 1) = 1
   |            ТОГДА НЕОПРЕДЕЛЕНО
   |        ИНАЧЕ ВложенныйЗапрос.Упаковка.Наименование
   |    КОНЕЦ КАК Упаковка,
   |    ВложенныйЗапрос.СтавкаНДС КАК СтавкаНДС,
   |    ВложенныйЗапрос.Цена КАК Цена,
   |    ВложенныйЗапрос.Количество КАК Количество,
   |    ВложенныйЗапрос.Сумма КАК Сумма,
   |    ВложенныйЗапрос.СуммаНДС КАК СуммаНДС,
   |    ВложенныйЗапрос.СуммаСкидки КАК СуммаСкидки,
   |    ВложенныйЗапрос.СуммаБезСкидки КАК СуммаБезСкидки,
   |    ВложенныйЗапрос.НомерСтроки КАК НомерСтроки,
   |    ЛОЖЬ КАК ЭтоВозвратнаяТара,
   |    ЕСТЬNULL(ЦеныНоменклатурыСрезПоследних.Упаковка.Коэффициент, 1) КАК КоэфРегистра,
   |    ВложенныйЗапрос.Коэффициент,
   |    ВЫРАЗИТЬ(ЕСТЬNULL(ЦеныНоменклатурыСрезПоследних.Цена, 0) / ЕСТЬNULL(ЦеныНоменклатурыСрезПоследних.Упаковка.Коэффициент, 1) * ВложенныйЗапрос.Коэффициент КАК ЧИСЛО(15, 2)) КАК ЦенаРозничная,
   |    ЦеныНоменклатурыСрезПоследних.Цена КАК ЦенаПоРегистру
   |ИЗ
   |    (ВЫБРАТЬ
   |        ПоступлениеТоваровУслуг.Ссылка КАК Ссылка,
   |        ПоступлениеТоваровУслуг.Номенклатура КАК Номенклатура,
   |        ВЫБОР
   |            КОГДА ПоступлениеТоваровУслуг.Упаковка = ЗНАЧЕНИЕ(Справочник.УпаковкиНоменклатуры.ПустаяСсылка)
   |                ТОГДА 1
   |            ИНАЧЕ ПоступлениеТоваровУслуг.Упаковка.Коэффициент
   |        КОНЕЦ КАК Коэффициент,
   |        ВЫБОР
   |            КОГДА ПоступлениеТоваровУслуг.Упаковка = ЗНАЧЕНИЕ(Справочник.УпаковкиНоменклатуры.ПустаяСсылка)
   |                ТОГДА ПоступлениеТоваровУслуг.Номенклатура.ЕдиницаИзмерения
   |            ИНАЧЕ ПоступлениеТоваровУслуг.Упаковка.ЕдиницаИзмерения
   |        КОНЕЦ КАК ЕдиницаИзмерения,
   |        ПоступлениеТоваровУслуг.ПроцентРучнойСкидки КАК ПроцентСкидки,
   |        ПоступлениеТоваровУслуг.Характеристика КАК Характеристика,
   |        ПоступлениеТоваровУслуг.Упаковка КАК Упаковка,
   |        ПоступлениеТоваровУслуг.СтавкаНДС КАК СтавкаНДС,
   |        ПоступлениеТоваровУслуг.Цена КАК Цена,
   |        ПоступлениеТоваровУслуг.КоличествоУпаковок КАК Количество,
   |        ПоступлениеТоваровУслуг.Сумма КАК Сумма,
   |        ПоступлениеТоваровУслуг.СуммаРучнойСкидки КАК СуммаСкидки,
   |        ПоступлениеТоваровУслуг.Сумма + ПоступлениеТоваровУслуг.СуммаРучнойСкидки КАК СуммаБезСкидки,
   |        ПоступлениеТоваровУслуг.СуммаНДС КАК СуммаНДС,
   |        ПоступлениеТоваровУслуг.НомерСтроки КАК НомерСтроки
   |    ИЗ
   |        Документ.ПоступлениеТоваровУслуг.Товары КАК ПоступлениеТоваровУслуг
   |    ГДЕ
   |        ПоступлениеТоваровУслуг.Ссылка В(&МассивДокументов)
   |        И ПоступлениеТоваровУслуг.Номенклатура.ТипНоменклатуры = ЗНАЧЕНИЕ(Перечисление.ТипыНоменклатуры.Товар)) КАК ВложенныйЗапрос
   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ВидЦены = &Розничная) КАК ЦеныНоменклатурыСрезПоследних
   |        ПО ВложенныйЗапрос.Номенклатура = ЦеныНоменклатурыСрезПоследних.Номенклатура
   |
   |УПОРЯДОЧИТЬ ПО
   |    ВложенныйЗапрос.Ссылка,
   |    НомерСтроки
   |ИТОГИ
   |    СУММА(СуммаСкидки)
   |ПО
   |    Ссылка");

   Запрос.УстановитьПараметр("МассивДокументов",                МассивОбъектов);
   Запрос.УстановитьПараметр("Розничная",                Розничная);

   ТабличныйДокумент = Новый ТабличныйДокумент;
   ТабличныйДокумент.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_ПоступлениеТоваровУслуг_Накладная_ВРозничных";
   
   ТабличныйДокумент = Новый ТабличныйДокумент;
   
   МассивРезультатов            = Запрос.ВыполнитьПакет();
   ДанныеПечати            = МассивРезультатов[0].Выбрать();
   ВыборкаПоДокументам    = МассивРезультатов[1].Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
   
   ПервыйДокумент = Истина;
   
   Пока ДанныеПечати.Следующий() Цикл
       
       // Найдем в выборке товары по текущему документу
       СтруктураПоиска = Новый Структура("Ссылка", ДанныеПечати.Ссылка);
       НайденСледующий = ВыборкаПоДокументам.НайтиСледующий(СтруктураПоиска);
       
       // Если в накладной только услуги - перейдем к следующему документу
       
       Если НайденСледующий Тогда
           ВыборкаПоТоварам = ВыборкаПоДокументам.Выбрать();
           //ЕстьСкидки = ФормированиеПечатныхФорм.НужноВыводитьСкидки(ВыборкаПоТоварам, ИспользоватьРучныеСкидки);
           ЕстьСкидки = Ложь;
           ВыборкаПоТоварам.Сбросить();
       Иначе
           Продолжить;
       КонецЕсли;
       
       // Макет необходимо получать для каждого документа, т.к. размеры колонок изменяются динамически
       Макет = ПолучитьМакет("ПФ_MXL_ПоступлениеТоваров");
       
       Если Не ПервыйДокумент Тогда
           ТабличныйДокумент.ВывестиГоризонтальныйРазделительСтраниц();
       КонецЕсли;
       
       ПервыйДокумент    = Ложь;
       НомерСтрокиНачало = ТабличныйДокумент.ВысотаТаблицы + 1;
       
       // Выводим шапку накладной
       
       ОбластьМакета = Макет.ПолучитьОбласть("Заголовок");
       
       ТекстЗаголовка = ОбщегоНазначенияКлиентСервер.СформироватьЗаголовокДокумента(ДанныеПечати, НСтр("ru='Поступление товаров'"));
       
       ОбластьМакета.Параметры.ТекстЗаголовка = ТекстЗаголовка;
       
       ТабличныйДокумент.Вывести(ОбластьМакета);
       
       ОбластьМакета                                   = Макет.ПолучитьОбласть("Поставщик");
       ПредставлениеПоставщика                         = ФормированиеПечатныхФорм.ОписаниеОрганизации(ФормированиеПечатныхФорм.СведенияОЮрФизЛице(ДанныеПечати.Поставщик, ДанныеПечати.Дата), "ПолноеНаименование");
       ОбластьМакета.Параметры.ПредставлениеПоставщика = ПредставлениеПоставщика;
       ОбластьМакета.Параметры.Поставщик               = ДанныеПечати.Поставщик;
       ТабличныйДокумент.Вывести(ОбластьМакета);
       
       ОбластьМакета                                   = Макет.ПолучитьОбласть("Покупатель");
       ПредставлениеПолучателя                         = ФормированиеПечатныхФорм.ОписаниеОрганизации(ФормированиеПечатныхФорм.СведенияОЮрФизЛице(ДанныеПечати.Организация, ДанныеПечати.Дата), "ПолноеНаименование");
       ОбластьМакета.Параметры.ПредставлениеПолучателя = ПредставлениеПолучателя;
       ОбластьМакета.Параметры.Получатель              = ДанныеПечати.Организация;
       ТабличныйДокумент.Вывести(ОбластьМакета);
       
       ОбластьМакета                                   = Макет.ПолучитьОбласть("Склад");
       ПредставлениеСклада = СкладыСервер.ПолучитьПредставлениеСклада(ВыборкаПоДокументам.ПредставлениеСклада);
       ОбластьМакета.Параметры.ПредставлениеСклада = ПредставлениеСклада;
       ОбластьМакета.Параметры.Склад              = ДанныеПечати.ПредставлениеСклада;
       ТабличныйДокумент.Вывести(ОбластьМакета);

           
       // Выводим заголовок таблицы Товары
       
       Если ЕстьСкидки Тогда
           ОбластьКолонкаТовар = Макет.Область("ТоварСоСкидкой");
       Иначе
           ОбластьКолонкаТовар = Макет.Область("Товар");
       КонецЕсли;
           
       Если Не ВыводитьКоды Тогда
           
           Если ЕстьСкидки Тогда
               ОбластьКолонкаТовар.ШиринаКолонки = ОбластьКолонкаТовар.ШиринаКолонки * 1.35;
           Иначе
               ОбластьКолонкаТовар.ШиринаКолонки = ОбластьКолонкаТовар.ШиринаКолонки * 1.2;
           КонецЕсли;
           
       КонецЕсли;
       
       Если ЕстьСкидки Тогда
           
           ОбластьНомера  = Макет.ПолучитьОбласть("ШапкаТаблицыСоСкидкой|НомерСтроки");
           ОбластьКодов   = Макет.ПолучитьОбласть("ШапкаТаблицыСоСкидкой|КолонкаКодов");
           ОбластьТовар   = Макет.ПолучитьОбласть("ШапкаТаблицыСоСкидкой|ТоварСоСкидкой");
           ОбластьДанных  = Макет.ПолучитьОбласть("ШапкаТаблицыСоСкидкой|ДанныеСоСкидкой");
           
       Иначе
           
           ОбластьНомера  = Макет.ПолучитьОбласть("ШапкаТаблицы|НомерСтроки");
           ОбластьКодов   = Макет.ПолучитьОбласть("ШапкаТаблицы|КолонкаКодов");
           ОбластьТовар   = Макет.ПолучитьОбласть("ШапкаТаблицы|Товар");
           ОбластьДанных  = Макет.ПолучитьОбласть("ШапкаТаблицы|Данные");
           
       КонецЕсли;
           
       ТабличныйДокумент.Вывести(ОбластьНомера);
           
       Если ВыводитьКоды Тогда
           ОбластьКодов.Параметры.ИмяКолонкиКодов = КолонкаКодов;
           ТабличныйДокумент.Присоединить(ОбластьКодов);
       КонецЕсли;
           
       ТабличныйДокумент.Присоединить(ОбластьТовар);
       ТабличныйДокумент.Присоединить(ОбластьДанных);
       
       Если ЕстьСкидки Тогда
           
           ОбластьНомера  = Макет.ПолучитьОбласть("СтрокаТаблицыСоСкидкой|НомерСтроки");
           ОбластьКодов   = Макет.ПолучитьОбласть("СтрокаТаблицыСоСкидкой|КолонкаКодов");
           ОбластьТовар   = Макет.ПолучитьОбласть("СтрокаТаблицыСоСкидкой|ТоварСоСкидкой");
           ОбластьДанных  = Макет.ПолучитьОбласть("СтрокаТаблицыСоСкидкой|ДанныеСоСкидкой");
           
       Иначе
           
           ОбластьНомера  = Макет.ПолучитьОбласть("СтрокаТаблицы|НомерСтроки");
           ОбластьКодов   = Макет.ПолучитьОбласть("СтрокаТаблицы|КолонкаКодов");
           ОбластьТовар   = Макет.ПолучитьОбласть("СтрокаТаблицы|Товар");
           ОбластьДанных  = Макет.ПолучитьОбласть("СтрокаТаблицы|Данные");
           
       КонецЕсли;
           
       Сумма          = 0;
       СуммаНДС       = 0;
       ВсегоСкидок    = 0;
       НомерСтроки    = 0;
       ВсегоБезСкидок = 0;
       
       СуммаРозничная = 0;
       
       // Выводим строки таблицы Товары
           
       Пока ВыборкаПоТоварам.Следующий() Цикл
           
           НомерСтроки = НомерСтроки + 1;
           
           ОбластьНомера.Параметры.НомерСтроки = НомерСтроки;
           ТабличныйДокумент.Вывести(ОбластьНомера);
           
           Если ВыводитьКоды Тогда
               
               ОбластьКодов.Параметры.Артикул = ВыборкаПоТоварам[КолонкаКодов];
               ТабличныйДокумент.Присоединить(ОбластьКодов);
               
           КонецЕсли;
           
           ОбластьТовар.Параметры.Заполнить(ВыборкаПоТоварам);
           ОбластьТовар.Параметры.Товар = ФормированиеПечатныхФорм.ПолучитьПредставлениеНоменклатурыДляПечати(
               ВыборкаПоТоварам.ТоварНаименованиеПолное,
               ВыборкаПоТоварам.Характеристика,
               ВыборкаПоТоварам.Упаковка
           ) + ?(ВыборкаПоТоварам.ЭтоВозвратнаяТара, НСтр("ru=' (возвратная тара)'"), "");
               
           ТабличныйДокумент.Присоединить(ОбластьТовар);

           ОбластьДанных.Параметры.Заполнить(ВыборкаПоТоварам);
           
           
           ОбластьДанных.Параметры.Цена = ВыборкаПоТоварам.ЦенаРозничная;
           ТекСуммаРозничная = ВыборкаПоТоварам.ЦенаРозничная * ВыборкаПоТоварам.Количество;
           ОбластьДанных.Параметры.Сумма = ТекСуммаРозничная;
           СуммаРозничная = СуммаРозничная + ТекСуммаРозничная;

           ТабличныйДокумент.Присоединить(ОбластьДанных);
           
           Сумма          = Сумма          + ВыборкаПоТоварам.Сумма;
           СуммаНДС       = СуммаНДС       + ВыборкаПоТоварам.СуммаНДС;
           
           Если ЕстьСкидки Тогда
               ВсегоСкидок    = ВсегоСкидок    + ВыборкаПоТоварам.СуммаСкидки;
               ВсегоБезСкидок = ВсегоБезСкидок + ВыборкаПоТоварам.СуммаБезСкидки;
           КонецЕсли;
           
       КонецЦикла;
       
       // Выводим подвал
       
       Если ЕстьСкидки Тогда
           
           ОбластьНомера  = Макет.ПолучитьОбласть("ПодвалТаблицыСоСкидкой|НомерСтроки");
           ОбластьКодов   = Макет.ПолучитьОбласть("ПодвалТаблицыСоСкидкой|КолонкаКодов");
           ОбластьТовар   = Макет.ПолучитьОбласть("ПодвалТаблицыСоСкидкой|ТоварСоСкидкой");
           ОбластьДанных  = Макет.ПолучитьОбласть("ПодвалТаблицыСоСкидкой|ДанныеСоСкидкой");
           
       Иначе
           
           ОбластьНомера  = Макет.ПолучитьОбласть("ПодвалТаблицы|НомерСтроки");
           ОбластьКодов   = Макет.ПолучитьОбласть("ПодвалТаблицы|КолонкаКодов");
           ОбластьТовар   = Макет.ПолучитьОбласть("ПодвалТаблицы|Товар");
           ОбластьДанных  = Макет.ПолучитьОбласть("ПодвалТаблицы|Данные");
           
       КонецЕсли;
       
       ТабличныйДокумент.Вывести(ОбластьНомера);
       
       Если ВыводитьКоды Тогда
           ТабличныйДокумент.Присоединить(ОбластьКодов);
       КонецЕсли;
       
       ТабличныйДокумент.Присоединить(ОбластьТовар);
       
       Если ЕстьСкидки Тогда
           
           ОбластьДанных.Параметры.ВсегоСкидок    = ВсегоСкидок;
           ОбластьДанных.Параметры.ВсегоБезСкидок = ВсегоБезСкидок;
           
       КонецЕсли;
       
       //ОбластьДанных.Параметры.Всего = ФормированиеПечатныхФорм.ФорматСумм(Сумма);
       ОбластьДанных.Параметры.Всего = ФормированиеПечатныхФорм.ФорматСумм(СуммаРозничная);
       ТабличныйДокумент.Присоединить(ОбластьДанных);
       
       // Выводим ИтогоНДС
       
       //Если ДанныеПечати.УчитыватьНДС Тогда
       //    
       //    Если ЕстьСкидки Тогда
       //        
       //        ОбластьНомера  = Макет.ПолучитьОбласть("ПодвалТаблицыНДССоСкидкой|НомерСтроки");
       //        ОбластьКодов   = Макет.ПолучитьОбласть("ПодвалТаблицыНДССоСкидкой|КолонкаКодов");
       //        ОбластьТовар   = Макет.ПолучитьОбласть("ПодвалТаблицыНДССоСкидкой|ТоварСоСкидкой");
       //        ОбластьДанных  = Макет.ПолучитьОбласть("ПодвалТаблицыНДССоСкидкой|ДанныеСоСкидкой");
       //        
       //    Иначе
       //        
       //        ОбластьНомера  = Макет.ПолучитьОбласть("ПодвалТаблицыНДС|НомерСтроки");
       //        ОбластьКодов   = Макет.ПолучитьОбласть("ПодвалТаблицыНДС|КолонкаКодов");
       //        ОбластьТовар   = Макет.ПолучитьОбласть("ПодвалТаблицыНДС|Товар");
       //        ОбластьДанных  = Макет.ПолучитьОбласть("ПодвалТаблицыНДС|Данные");
       //        
       //    КонецЕсли;
       //    
       //    ТабличныйДокумент.Вывести(ОбластьНомера);
       //    
       //    Если ВыводитьКоды Тогда
       //        ТабличныйДокумент.Присоединить(ОбластьКодов);
       //    КонецЕсли;
       //    
       //    ТабличныйДокумент.Присоединить(ОбластьТовар);
       //    
       //    ОбластьДанных.Параметры.ВсегоНДС = ФормированиеПечатныхФорм.ФорматСумм(СуммаНДС);
       //    ОбластьДанных.Параметры.НДС = ?(ДанныеПечати.ЦенаВключаетНДС, НСтр("ru='В том числе НДС:'"), НСтр("ru='Сумма НДС:'"));
       //    ТабличныйДокумент.Присоединить(ОбластьДанных);
       //    
       //КонецЕсли;
       
       // Выводим Сумму прописью
       
       ОбластьМакета = Макет.ПолучитьОбласть("СуммаПрописью");
       СуммаКПрописи = Сумма + ?(ДанныеПечати.ЦенаВключаетНДС, 0, СуммаНДС);
       СуммаКПрописи = СуммаРозничная;
       
       ИтоговаяСтрока = НСтр("ru='Всего наименований %КоличествоНаименований%, на сумму %СуммаДокумента% '");
       ИтоговаяСтрока = СтрЗаменить(ИтоговаяСтрока, "%КоличествоНаименований%", ВыборкаПоТоварам.Количество());
       ИтоговаяСтрока = СтрЗаменить(ИтоговаяСтрока, "%СуммаДокумента%", ФормированиеПечатныхФорм.ФорматСумм(СуммаКПрописи, ДанныеПечати.Валюта));

       ОбластьМакета.Параметры.ИтоговаяСтрока = ИтоговаяСтрока;
       ОбластьМакета.Параметры.СуммаПрописью  = РаботаСКурсамиВалют.СформироватьСуммуПрописью(СуммаКПрописи, ДанныеПечати.Валюта);
       
       ТабличныйДокумент.Вывести(ОбластьМакета);
       
       // Выводим подписи
       ОбластьМакета = Макет.ПолучитьОбласть("Подписи");
       
       Если ЗначениеЗаполнено(ДанныеПечати.ПолучениеПроизвел) Тогда
           ОбластьМакета.Параметры.ПолучениеПроизвел = ФизическиеЛица.ФамилияИнициалыФизЛица(ДанныеПечати.ПолучениеПроизвел);
       КонецЕсли;
       
       ТабличныйДокумент.Вывести(ОбластьМакета);
       
       УправлениеПечатью.ЗадатьОбластьПечатиДокумента(ТабличныйДокумент, НомерСтрокиНачало, ОбъектыПечати, ДанныеПечати.Ссылка);
       
   КонецЦикла;
   
   ТабличныйДокумент.АвтоМасштаб = Истина;

   Если ПривилегированныйРежим() Тогда
       УстановитьПривилегированныйРежим(Ложь);
   КонецЕсли;
   
   Возврат ТабличныйДокумент;

КонецФункции // СформироватьПечатнуюФормуНакладная()
1 Web00001
 
16.09.12
07:28
ВПФ это что общепринятое сокращение? Лом нормально написать?
1С должна указывать на строку, в которой он не нашла "ПредставлениеСклада"
2 Эмбеддер
 
16.09.12
07:29
ошибка в ВыборкаПоДокументам.ПредставлениеСклада
в коде
       ПредставлениеСклада = СкладыСервер.ПолучитьПредставлениеСклада(ВыборкаПоДокументам.ПредставлениеСклада);
       ОбластьМакета.Параметры.ПредставлениеСклада = ПредставлениеСклада;
       ОбластьМакета.Параметры.Склад              = ДанныеПечати.ПредставлениеСклада;
3 pers200590
 
16.09.12
07:29
(1) в версии 8.2.16 не показывает
4 pers200590
 
16.09.12
07:31
(1) если включить отладку то
{ВнешняяОбработка.ВнешняяПечатнаяФормаПоступлениеТоваров.МодульОбъекта(449)}: Поле объекта не обнаружено (ПредставлениеСклада)
       ПредставлениеСклада = СкладыСервер.ПолучитьПредставлениеСклада(ВыборкаПоДокументам.ПредставлениеСклада);
5 pers200590
 
16.09.12
07:32
(2) а что не так?
6 Web00001
 
16.09.12
07:34
говорит ВыборкаПоДокументам не содержит ПредставлениеСклада, выгрузи выборку в таблицу значений и посмотри на колонки
7 Эмбеддер
 
16.09.12
07:35
ВыборкаПоДокументам - это выборка из 2-го запроса, там нет ПредставлениеСклада
8 Web00001
 
16.09.12
07:38
(7) ага тоже уже заметил
(5)Надо во втором запросе из первого вытянуть это поле
9 pers200590
 
16.09.12
07:39
Проблема решилась
Заменил ВыборкаПоДокументам в ПредставлениеСклада = СкладыСервер.ПолучитьПредставлениеСклада(ВыборкаПоДокументам.ПредставлениеСклада);
на ДанныеПечати
10 pers200590
 
16.09.12
07:39
Правильно ли это
11 pers200590
 
16.09.12
07:39
???
12 Web00001
 
16.09.12
07:55
откуда нам знать данные из какого запроса тебе нужны? если из первого то правильно, если из второго то неправильно. Тебе ж говорят в (8) вытяни это поле и можешь его использовать.
13 pers200590
 
16.09.12
07:57
Всем спасибо
Проблема решена
14 andrewks
 
16.09.12
09:03
(1) "ВПФ это что общепринятое сокращение?" да. или ты всегда пишешь "Управление Торговлей", а не УТ ?
15 pers200590
 
24.09.12
11:04
Сейчас столкнулся с проблемой в создании ВПФ Внутреннего потребления товаров с розничными ценами.
В печатной форме выводится только шапка документа.
Ошибку ищу уже несколько дней и не могу найти.
Ссылка на ВПФ : http://zalil.ru/33781816
16 pers200590
 
24.09.12
11:13
где все
17 pers200590
 
24.09.12
11:41
мистяне проснитесь
18 pers200590
 
24.09.12
12:25
ау
19 pers200590
 
24.09.12
14:08
где все?
20 pers200590
 
25.09.12
06:15
дорогие форумчане я не могу разобраться, необходима ваша помощь
21 Агент Инфостарта
 
25.09.12
08:22
(20) Эта тема http://forum.infostart.ru/forum26/topic69962/ ?
800 рублей.
22 pers200590
 
25.09.12
08:27
(21) ого. А просто объяснить в чем причина начинающему 1Снику
23 Мимохожий Однако
 
25.09.12
08:43
(22)Телепаты в отпуске. Отладчиком смотрел?
24 pers200590
 
25.09.12
08:48
(23)отладчик мне не помог так как мало в нем понимаю
25 Агент Инфостарта
 
25.09.12
08:48
(22) Стаж: 2 г. 7 мес.  - за два с половиной года можно стать матёрым 1Сником.

(23) Бесполезно, уже был такой совет на ис.
26 Мимохожий Однако
 
25.09.12
08:56
(24)Открой свою конфигурацию с двумя-тремя объектами и потренируйся.
27 pers200590
 
25.09.12
08:57
(25) за время моего стажа на форуме сначала сидел на 7 , перешел на 8 и стала комфортно за время стажа научился многому, но в этом у меня пока минус
28 Мимохожий Однако
 
25.09.12
08:58
(27)не теряй время на оправдывания - тренируйся. )))
29 pers200590
 
25.09.12
09:06
так не теряй время уже голова кругом . сравнивал несколько своиз других впф все и все нормально
30 Мимохожий Однако
 
25.09.12
09:08
Сделай паузу - скушая твикс. Проще говоря, надо успокоиться. Мозг отдохнет, точка кипения станет выше. Потом можно начать заново, забыв предыдущие попытки.
31 pers200590
 
25.09.12
09:10
(30) конечно хорошая неделя , но уже много раз пытался
32 pers200590
 
25.09.12
12:27
мистяне уже голова кругом