доброго утра всем!
имеется след. запрос:

Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ РАЗРЕШЕННЫЕ
|    СвойстваОбъектов.Ссылка КАК Свойство,
|    СвойстваОбъектов.Наименование КАК СвойствоНаименование
|ПОМЕСТИТЬ ВТСписокСвойств
|ИЗ
|    ПланВидовХарактеристик.СвойстваОбъектов КАК СвойстваОбъектов
|ГДЕ
|    СвойстваОбъектов.НазначениеСвойства = ЗНАЧЕНИЕ(ПланВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_Номенклатура)
|
|ИНДЕКСИРОВАТЬ ПО
|    Свойство
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ РАЗРЕШЕННЫЕ
|    ЗначенияСвойствОбъектов.Свойство КАК Свойство,
|    ЗначенияСвойствОбъектов.Значение КАК ЗначениеСвойства
|ПОМЕСТИТЬ ВТЗначенияСвойств
|ИЗ
|    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
|ГДЕ
|    (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Объект КАК Справочник.Номенклатура)) = &Номенклатура
|
|ИНДЕКСИРОВАТЬ ПО
|    Свойство
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|    СписокСвойств.Свойство КАК Свойство,
|    СписокСвойств.СвойствоНаименование КАК СвойствоНаименование,
|    ""ПВХ_"" + СписокСвойств.СвойствоНаименование КАК СвойствоПредставление,
|    ЕСТЬNULL(ЗначенияСвойств.ЗначениеСвойства, ЗНАЧЕНИЕ(Справочник.ЗначенияСвойствОбъектов.ПустаяСсылка)) КАК ЗначениеСвойства,
|    ВЫБОР
|        КОГДА НЕ ЗначенияСвойств.Свойство ЕСТЬ NULL
|            ТОГДА ИСТИНА
|        ИНАЧЕ ЛОЖЬ
|    КОНЕЦ КАК ЗначениеНайдено
|ИЗ
|    ВТСписокСвойств КАК СписокСвойств
|        ЛЕВОЕ СОЕДИНЕНИЕ ВТЗначенияСвойств КАК ЗначенияСвойств
|        ПО СписокСвойств.Свойство = ЗначенияСвойств.Свойство";

Запрос.УстановитьПараметр("Номенклатура", Номенклатура);
на 1 позицию ТМЦ уходит 1 секунда - пожалуйста подскажите, в чем может быть причина медленной работы этого простого запроса?
база файловая УТ 10.3, в справочнике Номенклатура 19380 позиций, в регистре ЗначенияСвойствОбъектов 197230 записей.
заранее благодарю за помощь.

(0) убирай из запроса по кусочку, постепенно наткнёшься на тот блок, который тормозит

как я и думал - это таблица ВТЗначенияСвойств

убрал ВТ, вместо 1,6 сек запрос выполняется 3,2 сек... весело однако

Слушай, может быть попробуй убрать "Выразить" из
(ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Объект КАК Справочник.Номенклатура)) = &Номенклатура

Напиши просто ЗначенияСвойствОбъектов.Объект = &Номенклатура

(4) браво! 0,005 сек вместо 1,6 сек

Хорошо. Я тебя поздравляю. Значит, в остальном запрос был написан верно.

(6) спасибо за помощь...

(7) Приятно было помочь, моя гордость и самомнение от этого выросли! :)
Я уже не только в мелочи могу помочь, я уже могу разобрать Запрос! :)
Хотяа, это был не сложный случай.

(5) Следующий раз он отработает с теми жа 1.5 секундами.

ГДЕ (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Объект КАК Справочник.Номенклатура)) = &Номенклатура

здесь ни на что не влияет.

(10)Влияет

(10) (11) каккие фаши доказзаттельстааа? (с)

(11) в данном случае

|    (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Объект КАК Справочник.Номенклатура)) = &Номенклатура

и

|    ЗначенияСвойствОбъектов.Объект = &Номенклатура

разница только в производительности

я раньше думал что через выразить наоборот быстрее работает

(14) а ты думал, во что твой запрос превращается? и почему "от выразить быстрее" в некоторых случаях, а в твоем - нет?

зачем нужны индексы?

какие индексы создает 1с

про планы выполнения

а еще - в (0) запрос в цикле, наверняка

(14) Не в этом случае.
(17) Почти уверен, что и с выразить будет использоваться индекс.

(13)про производительность и говорми

Может характеристики получать вот по подобию?

ВЫБРАТЬ
   Контрагенты.Ссылка КАК Контрагенты
ИЗ
   Справочник.Контрагенты КАК Контрагенты

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
   "Всего"
{ХАРАКТЕРИСТИКИ
   ТИП(Справочник.Контрагенты)
   СПИСОК (ВЫБРАТЬ
           СвойстваОбъектов.Ссылка,
           СвойстваОбъектов.Наименование,
           СвойстваОбъектов.ТипЗначения
       ИЗ
           ПланВидовХарактеристик.СвойстваОбъектов КАК СвойстваОбъектов
       ГДЕ
           СвойстваОбъектов.НазначениеСвойства.Код = "00000000101")
   ИДЕНТИФИКАТОР Ссылка
   ИМЯ Наименование
   ТИПЗНАЧЕНИЯ ТипЗначения
   ЗНАЧЕНИЯ РегистрСведений.ЗначенияСвойствОбъектов
   ОБЪЕКТ Объект
   ХАРАКТЕРИСТИКА Свойство
   ЗНАЧЕНИЕ Значение }

(15) это не мой запрос - просто интересуюсь, а в каких выразить быстрее , а в каких медленнее ?насколько я понимаю здесь составной тип, вот он и выражает нет...я именно так понимал оптимизацию запроса в данном контексте

(20) не, там индекс начинается с TREF :)

(24) Индекс!

StmtText                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                          
--------                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                                          
Nested Loops(Inner Join, OUTER REFERENCES:([T1].[_Fld16423_TYPE], [T1].[_Fld16423_RTRef], [T1].[_Fld16423_RRRef], [T1].[_Fld16424RRef]))                                                                                                                                                                                                                                                                                                                                                                                          
 |--Index Scan(OBJECT:([KATAP].[dbo].[_InfoRg16422].[_InfoR16422_ByDims16426_RR] AS [T1]),  WHERE:(CASE WHEN [KATAP].[dbo].[_InfoRg16422].[_Fld16423_TYPE] as [T1].[_Fld16423_TYPE]=[@P1] AND [KATAP].[dbo].[_InfoRg16422].[_Fld16423_RTRef] as [T1].[_Fld16423_RTRef]=[@P2] THEN [KATAP].[dbo].[_InfoRg16422].[_Fld16423_RRRef] as [T1].[_Fld16423_RRRef] ELSE NULL END=[@P3]))                                                                                                                                                  
 |--Clustered Index Seek(OBJECT:([KATAP].[dbo].[_InfoRg16422].[_InfoR16422_ByDims_RR] AS [T1]), SEEK:([T1].[_Fld16423_TYPE]=[KATAP].[dbo].[_InfoRg16422].[_Fld16423_TYPE] as [T1].[_Fld16423_TYPE] AND [T1].[_Fld16423_RTRef]=[KATAP].[dbo].[_InfoRg16422].[_Fld16423_RTRef] as [T1].[_Fld16423_RTRef] AND [T1].[_Fld16423_RRRef]=[KATAP].[dbo].[_InfoRg16422].[_Fld16423_RRRef] as [T1].[_Fld16423_RRRef] AND [T1].[_Fld16424RRef]=[KATAP].[dbo].[_InfoRg16422].[_Fld16424RRef] as [T1].[_Fld16424RRef]) LOOKUP ORDERED FORWARD)

(24) Другой вопрос, что без Выразить будет просто

StmtText                                                    --------                                                                              
Clustered Index Seek(OBJECT:([KATAP].[dbo].[_InfoRg16422].[_InfoR16422_ByDims_RR] AS [T1]), SEEK:([T1].[_Fld16423_TYPE]=[@P1] AND [T1].[_Fld16423_RTRef]=[@P2] AND [T1].[_Fld16423_RRRef]=[@P3]) ORDERED FORWARD)

Без Выразить даже за данными ходить не надо, все в индексе, поэтому да - без Выразить шустрее, просто под SQL это не чувствуется :-)

ВЫБРАТЬ РАЗРЕШЕННЫЕ
   СвойстваОбъектов.Ссылка КАК Свойство
ПОМЕСТИТЬ СвойстваОбъектов
ИЗ
   ПланВидовХарактеристик.СвойстваОбъектов КАК СвойстваОбъектов
ГДЕ
   СвойстваОбъектов.НазначениеСвойства = ЗНАЧЕНИЕ(ПланВидовХарактеристик.НазначенияСвойствКатегорийОбъектов.Справочник_Номенклатура)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
   СвойстваОбъектов.Свойство КАК Свойство,
   СвойстваОбъектов.Свойство.Представление КАК СвойствоНаименование,
   "ПВХ_" + СвойстваОбъектов.Свойство.Наименование КАК СвойствоПредставление,
   ЕСТЬNULL(ЗначенияСвойствОбъектов.Значение, ЗНАЧЕНИЕ(Справочник.ЗначенияСвойствОбъектов.ПустаяСсылка)) КАК ЗначениеСвойства,
   ВЫБОР
       КОГДА ЗначенияСвойствОбъектов.Значение ЕСТЬ NULL
           ТОГДА ЛОЖЬ
       ИНАЧЕ ИСТИНА
   КОНЕЦ КАК ЗначениеНайдено
ИЗ
   СвойстваОбъектов КАК СвойстваОбъектов
       ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов
       ПО (&Номенклатура = (ВЫРАЗИТЬ(ЗначенияСвойствОбъектов.Объект КАК Справочник.ДоговорыКонтрагентов)))
           И СвойстваОбъектов.Свойство = ЗначенияСвойствОбъектов.Свойство

(27) Индексировать временные таблицы в первых 2 запросах нет необходимости, индекс все равно не будет использоваться СУБД. Оптимизатор СУБД вероятно всего будет использовать SKAN, чем INDEX SEEK.

(29) почему не будет? а в каких случаях все таки будет?

(25) т е получается когд а индекс есть "выразить" не нужно, более того работает дольше?

(31) Напрямую к "выразить" ни имеет ни кого отношения.  

http://habrahabr.ru/post/164717/

(0) а обязательно запрос делать по 1 номенклатурной позиции? Может сразу все скопом обработать или логика решения требует обработку попозиционно?

(25) А мне вот западло в профайлер лезть, я просто для себя решил, что любая функция на индексированное поле не дает этот самый индекс использовать

(34) и выразить не проверял, по этому