Здравствуйте. Подскажите, пож-ста, как можно вытащить остатки по номенклатуре? Дорабатываю "Бухгалтерию", там написан док с табличной частью, для номенклатуры из этой табличной части и нужны остатки. Делаю запрос с левым соединением таблицы дока (беру номенклатуру) и регистра хозрасчётный (беру Субконто 1, номенклатура). Пока остатки не выводит запрос. Может, кто сталкивался с этим в 1С?

Счет точно верный указываешь?

(1)[Может, кто сталкивался с этим в 1С]
1С тут точно не причем

> Дорабатываю "Бухгалтерию"

с этого момента по-подробнее

Это зависит от того на каком счете ты держишь номенклатуру(обычно 41).А дальше что-то вроде
   Запрос = Новый Запрос;
   Запрос.Текст =
   "ВЫБРАТЬ
   |    СпрСклады.Ссылка КАК Склад,
   |    СпрСклады.Представление,
   |    СпрНоменклатура.Ссылка КАК Номенклатура,
   |    СпрНоменклатура.НаименованиеПолное КАК Наименование,
   |    СпрНоменклатура.Представление КАК Представление1,
   |    СУММА(ХозрасчетныйОстатки.КоличествоОстатокДт) КАК КоличествоОстатокДт,
   |    СУММА(ХозрасчетныйОстатки.СуммаОстатокДт) КАК СуммаОстатокДт,
   |    ЕСТЬNULL(СУММА(ХозрасчетныйОстатки.КоличествоОстатокДт),0)+ЕСТЬNULL(РезервированиеТоваровОстатки.КоличествоЗарезервированноОстаток, 0) КАК КоличествоСвободно,
   |    СУММА(-РезервированиеТоваровОстатки.КоличествоЗарезервированноОстаток)  Как КоличествоЗарезервированно
   |ИЗ
   |    РегистрБухгалтерии.Хозрасчетный.Остатки(&ВыбКонПериода, , , ) КАК ХозрасчетныйОстатки
   |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Склады КАК СпрСклады
   |        ПО ХозрасчетныйОстатки.Субконто2 = СпрСклады.Ссылка
   |        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК СпрНоменклатура
   |        ПО ХозрасчетныйОстатки.Субконто1 = СпрНоменклатура.Ссылка
   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.РезервированиеТоваров.Остатки(&ВыбКонПериода,ДатаОкончания >= &ВыбКонПериода ) КАК РезервированиеТоваровОстатки
   |        ПО (ХозрасчетныйОстатки.Субконто2 = РезервированиеТоваровОстатки.Склад
   |                И ХозрасчетныйОстатки.Субконто1 = РезервированиеТоваровОстатки.Номенклатура)
   |ГДЕ
   |    ХозрасчетныйОстатки.Счет В ИЕРАРХИИ(&ВыбСчета)";

и условие где перенеси в условие таблицы

(1), (3) Вроде сам дошёл. Там трудно под их специфику переработать реализацию товаров и услуг, поэтому под них сделан документ на списание материалов. Код пока такой сделал, в отладчике остаток  получил (извините, не знаю, как тут код вставить правильно.
   МенеджерВТ = Новый МенеджерВременныхТаблиц;

   Запрос = Новый Запрос;
   //укажем, какой менеджер временных таблиц использует этот запрос
   Запрос.МенеджерВременныхТаблиц = МенеджерВТ;
   
   Запрос.Текст =
       "ВЫБРАТЬ
       |    НакладнаяНаСписаниеМатериалы.Наименование,
       |    НакладнаяНаСписаниеМатериалы.Количество,
       |    НакладнаяНаСписаниеМатериалы.ОбщаяПлощадь,
       |    НакладнаяНаСписаниеМатериалы.Цена,
       |    НакладнаяНаСписаниеМатериалы.Сумма,
       |    НакладнаяНаСписаниеМатериалы.ЕдИзм,
       |    НакладнаяНаСписаниеМатериалы.Ссылка
       |ПОМЕСТИТЬ НоменклатураДокумента
       |ИЗ
       |    Документ.НакладнаяНаСписание.Материалы КАК НакладнаяНаСписаниеМатериалы
       |ГДЕ
       |    НакладнаяНаСписаниеМатериалы.Ссылка = &Ссылка";

   Запрос.УстановитьПараметр("Ссылка", Ссылка);

   Результат = Запрос.Выполнить();
    Запрос2 = Новый Запрос;
    Запрос2.МенеджерВременныхТаблиц = МенеджерВТ;
        Запрос2.Текст = "ВЫБРАТЬ
                        |    НоменклатураДокумента.Наименование,
                        |    НоменклатураДокумента.Количество,
                        |    НоменклатураДокумента.ОбщаяПлощадь,
                        |    НоменклатураДокумента.Сумма,
                        |    ЦеныНоменклатуры.ТипЦен,
                        |    ЦеныНоменклатуры.Номенклатура,
                        |    ЦеныНоменклатуры.Цена,
                        |    НоменклатураДокумента.Ссылка,
                        |    ЕСТЬNULL(ХозрасчетныйОстатки.СуммаОстаток, 0) КАК ОстатокПоСумме,
                        |    ЕСТЬNULL(ХозрасчетныйОстатки.КоличествоОстаток, 0) КАК ОстатокПоКоличеству,
                        |    ХозрасчетныйОстатки.Субконто1
                        |ИЗ
                        |    НоменклатураДокумента КАК НоменклатураДокумента
                        |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
                        |        ПО НоменклатураДокумента.Наименование = ЦеныНоменклатуры.Номенклатура
                        |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.Остатки КАК ХозрасчетныйОстатки
                        |        ПО НоменклатураДокумента.Наименование = ХозрасчетныйОстатки.Субконто1.Ссылка
                        |ГДЕ
                        |    ЦеныНоменклатуры.ТипЦен = &ТипЦен
                        |    И НоменклатураДокумента.Ссылка = &Ссылка";
                    Запрос2.УстановитьПараметр("ТипЦен", ЗакупочнаяЦена);
                    Запрос2.УстановитьПараметр("Ссылка", Ссылка);
                    Результат = Запрос2.Выполнить();
   ВыборкаДетальныеЗаписи = Результат.Выбрать();

нельзя это сделать в в8, это еще сырой продукт, там половина функций не рабтает

|ИЗ
                         |    НоменклатураДокумента КАК НоменклатураДокумента
                         |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
                         |        ПО НоменклатураДокумента.Наименование = ЦеныНоменклатуры.Номенклатура
                         |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.Остатки КАК ХозрасчетныйОстатки
                         |        ПО НоменклатураДокумента.Наименование = ХозрасчетныйОстатки.Субконто1.Ссылка
??????????????????????????????????????????????????????
Ты как наименование со ссылкой связываешь?

(8) Да временную таблицу сделал, так как кроме остатков ещё данные нужно получить. Кодить, можно сказать, только начинаю, Радченко передо мной, вот и тренируюсь.
А как вы предлагаете? (4)?

(7) Все отлично
работает)

Ещё текущий вопрос - как в запросе для остатков период установить?

2(10) Все отлично врут

(11) ну возьми типовой документ списания и скопируй оттуда.

Ты на каком счете остатки проверяешь и какие  него субконто?

(13, 14) Сейчас посмотрю типовую реализацию. Счет 10.01 Материалы

за выражение

ХозрасчетныйОстатки.Субконто1.Ссылка

надо не только руки поотрубать, но и ноги.

(16)Может быть. Не спорю.

МенеджерВТ = Новый МенеджерВременныхТаблиц;

   Запрос = Новый Запрос;
   //укажем, какой менеджер временных таблиц использует этот запрос

   Запрос.МенеджерВременныхТаблиц = МенеджерВТ;
   
   Запрос.Текст =
       "ВЫБРАТЬ
       |    НакладнаяНаСписаниеМатериалы.Номенклатура,
       |    НакладнаяНаСписаниеМатериалы.Количество,
       |    НакладнаяНаСписаниеМатериалы.ОбщаяПлощадь,
       |    НакладнаяНаСписаниеМатериалы.Цена,
       |    НакладнаяНаСписаниеМатериалы.Сумма,
       |    НакладнаяНаСписаниеМатериалы.ЕдИзм,
       |    НакладнаяНаСписаниеМатериалы.Ссылка
       |ПОМЕСТИТЬ НоменклатураДокумента
       |ИЗ
       |    Документ.НакладнаяНаСписание.Материалы КАК НакладнаяНаСписаниеМатериалы
       |ГДЕ
       |    НакладнаяНаСписаниеМатериалы.Ссылка = &Ссылка";

   Запрос.УстановитьПараметр("Ссылка", Ссылка);

   Результат = Запрос.Выполнить();
    Запрос2 = Новый Запрос;
    Запрос2.МенеджерВременныхТаблиц = МенеджерВТ;
    Запрос2.Текст = "ВЫБРАТЬ
                    |    НоменклатураДокумента.Номенклатура,
                    |    НоменклатураДокумента.Количество,
                    |    НоменклатураДокумента.ОбщаяПлощадь,
                    |    НоменклатураДокумента.Сумма,
                    |    ЦеныНоменклатурыСрезПоследних.ТипЦен,
                    |    ЦеныНоменклатурыСрезПоследних.Номенклатура КАК Номенклатура1,
                    |    ЦеныНоменклатурыСрезПоследних.Цена,
                    |    НоменклатураДокумента.Ссылка,
                    |    ЕСТЬNULL(ХозрасчетныйОстатки.СуммаОстаток, 0) КАК ОстатокПоСумме,
                    |    ЕСТЬNULL(ХозрасчетныйОстатки.КоличествоОстаток, 0) КАК ОстатокПоКоличеству,
                    |    ХозрасчетныйОстатки.Субконто1
                    |ИЗ
                    |    НоменклатураДокумента КАК НоменклатураДокумента
                    |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.Остатки(&ДатаНаКоторуюПроверяешь, Счет В ИЕРАРХИИ (&Счет10), , Субконто2 = &Склад) КАК ХозрасчетныйОстатки
                    |        ПО НоменклатураДокумента.Номенклатура = ХозрасчетныйОстатки.Субконто1
                    |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(&ДатаНаКоторуюПроверяешь, ТипЦен = &ТипЦен) КАК ЦеныНоменклатурыСрезПоследних
                    |        ПО НоменклатураДокумента.Номенклатура = ЦеныНоменклатурыСрезПоследних.Номенклатура
                    |ГДЕ
                    |    НоменклатураДокумента.Ссылка = &Ссылка";
    Запрос2.УстановитьПараметр("ТипЦен", ЗакупочнаяЦена);
    Запрос2.УстановитьПараметр("Ссылка", Ссылка);
    Запрос2.УстановитьПараметр("ДатаНаКоторуюПроверяешь",ссылка.Дата);
     Запрос2.УстановитьПараметр("Склад", Ссылка.Склад);
           Запрос2.УстановитьПараметр("Счет10", ПланыСчетов.Хозрасчетный.Материалы);


    Результат = Запрос2.Выполнить();
   ВыборкаДетальныеЗаписи = Результат.Выбрать();

и то я сам как попало написал.но взлететь должно

(16) Человек же сам сказал Учится)))

а вот пример процедуры общей проверки(написана ручками)
//Проверяет остаток на складе с учетом резервации  ЗМ
Функция  ПроверитьОстатокНаСкладе(отказ,Ссылка,ДокументОбъект)Экспорт
   ИмяДокумента = ДокументОбъект.метаданные().Имя;
   ТипЗначения = ТипЗнч(Ссылка) = Тип("ДокументСсылка.ПеремещениеТоваров");
   Запрос = новый Запрос;
   Запрос.Текст =
   "ВЫБРАТЬ
   |    ЕСТЬNULL(ХозрасчетныйОстатки.КоличествоОстатокДт, 0) + ЕСТЬNULL(РезервированиеТоваровОстатки.КоличествоЗарезервированноОстаток, 0) КАК КоличествоОстатокДт,
   |    ДокументТовары.Номенклатура КАК Субконто1
   |ИЗ
   |    Документ."+ИмяДокумента+".Товары КАК ДокументТовары
   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.Остатки(&ДатаКон, Счет В ИЕРАРХИИ (&Счет), , ) КАК ХозрасчетныйОстатки
   |        ПО ДокументТовары.Номенклатура = ХозрасчетныйОстатки.Субконто1
   |            И ДокументТовары.Ссылка."+?(ТипЗначения = Истина ,"СкладОтправитель","Склад")+" = ХозрасчетныйОстатки.Субконто2
   |        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.РезервированиеТоваров.Остатки(&ДатаКон, ДатаОкончания >= &ДатаКон) КАК РезервированиеТоваровОстатки
   |        ПО ДокументТовары.Номенклатура = РезервированиеТоваровОстатки.Номенклатура
   |            И ДокументТовары.Ссылка."+?(ТипЗначения = Истина ,"СкладОтправитель","Склад")+" = РезервированиеТоваровОстатки.Склад
   |ГДЕ
   |    ДокументТовары.Ссылка = &Ссылка
   |    И ЕСТЬNULL(ХозрасчетныйОстатки.КоличествоОстатокДт, 0) + ЕСТЬNULL(РезервированиеТоваровОстатки.КоличествоЗарезервированноОстаток, 0) < ДокументТовары.Количество" ;
   Запрос.УстановитьПараметр("Ссылка" ,Ссылка);
   Запрос.УстановитьПараметр("ДатаКон" ,Ссылка.Дата);
   Запрос.УстановитьПараметр("Счет" ,ПланыСчетов.Хозрасчетный.ТоварыНаСкладах);
   
   Выборка = Запрос.Выполнить().Выбрать();
   пока Выборка.Следующий() цикл
       отказ =Истина;
       Сообщить("Остаток на складе номенклатуры "+Выборка.Субконто1+" равен "+Выборка.КоличествоОстатокДт+" .Проведение документа невозможно");
   КонецЦикла;
   Возврат отказ;
КонецФункции

(20)спасибо большое. Там цель вся в том, чтобы списать товар по средней стоимости. А так как это не реализация, а дорабатываемый по специфике организации документ, то и проводки по хозрасчётному регистру прописываю для него вручную.

НЗ удачи (22)

кстати получилось все у тебя?

(24) сижу проверяю. Пока, правда, без периода, на оперативном проведении.

Если что я тут пиши попробуем решить задачку

хорошо

пока нормально считает

гудненько)