СОЕДИНИТЬ ПО "В ИЕРАРХИИ"

Были темы
v8: В запросе связать таблицу номенклатуры с таблицей ее корневых родителей
v8: Запрос иерархия
v8: Справочник - ссылка и родитель верхнего уровня
Ещё нарыть можно, при желании. Думаю многие поймут, почему нельзя соединять две таблицы по условию реквизит Таблицы1 В ИЕРАРХИИ реквизит Таблицы2.
Думаю многие, кто знает SQL этого не поймут. А кто знает ещё и CTE задумаются о кроссплатформенности CTE для DB2 oracle и postgre.
Мне миста много помогла в оперативной работе, спасибо мистяне.
Если сочтете годным такой способ решения проблемы - берите.
Добавляем регистр сведений "ИерархияНоменклатуры"
с измерениями:
"НоменклатураГруппа" - номенклатура
"НоменклатураРодитель" - номенклатура
и можно ресурс
"УровеньВИерархии" - число
Добавляем подписку на событие
"АктуализироватьЛинейкуГруппНоменклатуры"
Источник: "СправочникОбъект.Номенклатура"
Событие:  "ПриЗаписи"
Обработчик: в отдельном серверном привилегированном модуле
Процедура АктуализироватьЛинейкуГруппНоменклатурыПриЗаписи(Источник, Отказ) Экспорт
    // Вставить содержимое обработчика.
    Если Источник.ЭтоГруппа Тогда
        РегистрыСведений.ИерархияНоменклатуры.АктуализироватьЛинейкуГрупп();
    КонецЕсли;
КонецПроцедуры
Затем, добавляем в модуль менеджера регистра три процедуры:
Процедура ЗаписатьГруппу(СтруктураСКлючами)

    НаборЗапРега = СоздатьНаборЗаписей();

    НаборЗапРега.Отбор.НоменклатураГруппа.Установить(СтруктураСКлючами.НоменклатураГруппа);
    НаборЗапРега.Отбор.НоменклатураРодитель.Установить(СтруктураСКлючами.НоменклатураРодитель);

    НаборЗапРега.Прочитать();

    НаборЗапРега.Записывать = Истина;

    НоваЗапа = 0;
    Если НаборЗапРега.Количество() = 0 Тогда
        НоваЗапа = НаборЗапРега.Добавить();
    Иначе
        НоваЗапа = НаборЗапРега[0];
        Если НоваЗапа.УровеньВИерархии = СтруктураСКлючами.УровеньВИерархии Тогда
            Возврат;
        КонецЕсли;
    КонецЕсли;

    ЗаполнитьЗначенияСвойств(НоваЗапа,СтруктураСКлючами);
    НаборЗапРега.УстановитьАктивность(Истина);

    НаборЗапРега.Записать();
КонецПроцедуры

Процедура УдалитьГруппу(СтруктураСКлючами)

    НаборЗапРега = СоздатьНаборЗаписей();

    НаборЗапРега.Отбор.НоменклатураГруппа.Установить(СтруктураСКлючами.НоменклатураГруппа);
    НаборЗапРега.Отбор.НоменклатураРодитель.Установить(СтруктураСКлючами.НоменклатураРодитель);

    НаборЗапРега.Прочитать();

    НаборЗапРега.Записывать = Истина;
    НаборЗапРега.Очистить();

    НаборЗапРега.Записать();
КонецПроцедуры

Процедура АктуализироватьЛинейкуГрупп() Экспорт

    ЗапорНах = Новый Запрос;
    ЗапорНах.Текст = "ВЫБРАТЬ
                     |    Номенклатура.Ссылка КАК НоменклатураГруппа,
                     |    Номенклатура.Родитель КАК НоменклатураРодитель,
                     |    0 КАК УровеньВИерархии
                     |ИЗ
                     |    Справочник.Номенклатура КАК Номенклатура
                     |ГДЕ
                     |    Номенклатура.ЭтоГруппа = ИСТИНА
                     |    И Номенклатура.ПометкаУдаления = ЛОЖЬ";
    ТабаРодов = ЗапорНах.Выполнить().Выгрузить();

    СтрокиУдалить = Новый Массив;

    ПоследИнда = ТабаРодов.Количество() - 1;
    СчИнда = 0;
    Для СчИнда = 0 По ПоследИнда Цикл

        ТекаСтро = ТабаРодов[СчИнда];

        Если ТекаСтро.НоменклатураРодитель.Пустая() Тогда
            СтрокиУдалить.Добавить(ТекаСтро);
        Иначе
            ТекаСтро.УровеньВИерархии = ТекаСтро.НоменклатураРодитель.Уровень();
        КонецЕсли;

        ЕщёРодитель = ТекаСтро.НоменклатураРодитель.Родитель;
        Пока Не ЕщёРодитель.Пустая() Цикл

            НоваСтро = ТабаРодов.Добавить();
            НоваСтро.НоменклатураГруппа   = ТекаСтро.НоменклатураГруппа;
            НоваСтро.НоменклатураРодитель = ЕщёРодитель;
            НоваСтро.УровеньВИерархии     = ЕщёРодитель.Уровень();
            ЕщёРодитель = ЕщёРодитель.Родитель;
        КонецЦикла;

        СамоСтро = ТабаРодов.Добавить();
        СамоСтро.НоменклатураГруппа   = ТекаСтро.НоменклатураГруппа;
        СамоСтро.НоменклатураРодитель = ТекаСтро.НоменклатураГруппа;
        СамоСтро.УровеньВИерархии     = ТекаСтро.НоменклатураГруппа.Уровень();
    КонецЦикла;

    Для Каждого Эл Из СтрокиУдалить Цикл

        ТабаРодов.Удалить(Эл);
    КонецЦикла;

    ТабаРодов.Сортировать("НоменклатураГруппа Возр,УровеньВИерархии Возр,НоменклатураРодитель Возр",);

    Для Каждого Стр Из ТабаРодов Цикл

        ЗаписатьГруппу(Стр);
    КонецЦикла;

    ЗапорНах.Текст = "ВЫБРАТЬ
                     |    ТабаРодов.НоменклатураГруппа,
                     |    ТабаРодов.НоменклатураРодитель,
                     |    ТабаРодов.УровеньВИерархии
                     |ПОМЕСТИТЬ ТАБАРОДОВ
                     |ИЗ
                     |    &ТабаРодов КАК ТабаРодов
                     |;
                     |
                     |////////////////////////////////////////////////////////////////////////////////
                     |ВЫБРАТЬ
                     |    ИерархияНоменклатуры.НоменклатураГруппа,
                     |    ИерархияНоменклатуры.НоменклатураРодитель,
                     |    ИерархияНоменклатуры.УровеньВИерархии
                     |ИЗ
                     |    РегистрСведений.ИерархияНоменклатуры КАК ИерархияНоменклатуры
                     |        ЛЕВОЕ СОЕДИНЕНИЕ ТАБАРОДОВ КАК ТАБАРОДОВ
                     |        ПО ИерархияНоменклатуры.НоменклатураГруппа = ТАБАРОДОВ.НоменклатураГруппа
                     |            И ИерархияНоменклатуры.НоменклатураРодитель = ТАБАРОДОВ.НоменклатураРодитель
                     |ГДЕ
                     |    ТАБАРОДОВ.НоменклатураГруппа ЕСТЬ NULL ";
    ЗапорНах.УстановитьПараметр("ТабаРодов",ТабаРодов);
    ТабаНеактуальные = ЗапорНах.ВыполнитьПакет()[1].Выгрузить();

    Для Каждого Стр Из ТабаНеактуальные Цикл

        УдалитьГруппу(Стр);
    КонецЦикла;
КонецПроцедуры
После чего можно заменять конструкциею "В ИЕРАРХИИ" внутри запроса
вот так:
"ВЫБРАТЬ
|        Номенклатура.Ссылка,
|        ИерархияНоменклатуры.НоменклатураРодитель,
|        ИерархияНоменклатуры.УровеньВИерархии
|    ИЗ
|        Справочник.Номенклатура КАК Номенклатура
|    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ИерархияНоменклатуры КАК ИерархияНоменклатуры
|    ПО Номенклатура.Родитель = ИерархияНоменклатуры.НоменклатураГруппа"