Здравствуйте. Делаю запрос допустим по документам, с табличной частью Товары, на эти товары хочу получить срез последних цен на данный товар, но периодом данного среза будет дата документа, где дата документа выбирается между параметрами НачДата, кОндата. Как сделать такой запрос с такими хитрыми вложениями?

никак

точнее можно покурить "срез последних на каждую дату"

(1) + 1
через подзапрос - ни как

со срезом последних/первых в одном запросе не получится

а как по другому програмно обрабатывать?

(5) если для внутренних действий, то либо цикл, либо физ. таблица
в скд 2 набора данных

в условии соединения можно использовать вложенные запросы, в которых можно использовать данные внешних запросов

да и просто в условии можно

(7) а точнее?
(6) как в скд 2 набора данных ?

(6) попрет вариант, Как сделать его?

(10) Связь наборов данных по периодам
http://its.1c.ru/db/metod81#content:4303:1

(10) http://1c-wiki.ru/wiki/Ежедневные_остатки#.D0.9E.D1.81.D1.82.D0.B0.D1.82.D0.BA.D0.B8_.D0.BD.D0.B0_.D0.BA.D0.B0.D0.B6.D0.B4.D1.8B.D0.B9_.D0.B4.D0.B5.D0.BD.D1.8C_.D0.BF.D0.B5.D1.80.D0.B8.D0.BE.D0.B4.D0.B0_.28.D0.B4.D0.B0.D0.B6.D0.B5_.D0.B5.D1.81.D0.BB.D0.B8_.D0.BD.D0.B5_.D0.B1.D1.8B.D0.BB.D0.BE_.D0.B4.D0.B2.D0.B8.D0.B6.D0.B5.D0.BD.D0.B8.D0.B9.29

ВЫБРАТЬ
    1 КАК Период,
    "А" КАК Значение
ПОМЕСТИТЬ Данные

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    2,
    "Б"

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    4,
    "А"

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    9,
    "Б"
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Данные.Период,
    Данные.Значение,
    ДанныеПредыдущие.Период КАК Период1,
    ДанныеПредыдущие.Значение КАК Значение1
ИЗ
    Данные КАК Данные
        ЛЕВОЕ СОЕДИНЕНИЕ Данные КАК ДанныеПредыдущие
        ПО Данные.Значение = ДанныеПредыдущие.Значение
            И (ДанныеПредыдущие.Период В
                (ВЫБРАТЬ ПЕРВЫЕ 1
                    ДанныеУсловие.Период
                ИЗ
                    Данные КАК ДанныеУсловие
                ГДЕ
                    ДанныеУсловие.Значение = Данные.Значение
                    И ДанныеУсловие.Период < Данные.Период
                УПОРЯДОЧИТЬ ПО
                    ДанныеУсловие.Период УБЫВ))

как уже сказали:

1)2 раза соединять с основной таблицей регистра сведений
2)в скд соединением наборов (тогда можно взять срезпоследних)

отчет и данные выбираю в скд кстати забыл уточнить. все хочу сделать через него, чтобы не возится с макетами.

(12) таблицу дат как получил человек не понял.

хотя можно документами связать.

(12) там попроще там период и остатки, можно тупо соединением, думаю. а у меня дата от документа ... и связь по документу.

(18) еще проще

Один набор докуметы, другой срез последних

(20) я так и сделал, а потом сделал связи, и че-то цены вернулись не те...

сделал 2 набора данных
1-ый запрос:
ВЫБРАТЬ
    ПеремещениеТоваровТовары.Номенклатура,
    ПеремещениеТоваровТовары.СчетУчета,
    ПеремещениеТоваровТовары.Количество,
    ПеремещениеТоваровТовары.Ссылка.СкладОтправитель КАК Склад,
    ПеремещениеТоваровТовары.Ссылка.Дата
ИЗ
    Документ.ПеремещениеТоваров.Товары КАК ПеремещениеТоваровТовары
ГДЕ
    ПеремещениеТоваровТовары.Ссылка.ПометкаУдаления = ЛОЖЬ
    И ПеремещениеТоваровТовары.Ссылка.Проведен = ИСТИНА
    И ПеремещениеТоваровТовары.Ссылка.СкладОтправитель В(&СкладОтправитель)
    И ПеремещениеТоваровТовары.Ссылка.Дата МЕЖДУ &НачДата И &КонДата

2-ой запрос:
ВЫБРАТЬ
    ЦеныНоменклатурыСрезПоследних.Номенклатура,
    ЦеныНоменклатурыСрезПоследних.Период,
    ЦеныНоменклатурыСрезПоследних.Цена
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
            &Период,
            ТипЦен = &ТипЦен
                И Номенклатура = &Номенклатура) КАК ЦеныНоменклатурыСрезПоследних


и сделал связи набора данных:
где источник свзяи 1-ый запрос приемник 2-ой запрос.
по параметру дата -период
и номенклатуре и что-то ничего не возвращается.

(22)Ты просишь его найти записи в регистре сведений, которые по ПЕРИОДУ четко совпадают с датой документа. Конечно ничего не выходит.
Не обойтись тут срезом последних, сказали же. Надо имитировать срез последних на каждую нужную тебе дату.

Делай в первом наборе таблицу Дат на которые получаешь остатки, а во второй их передавай в качестве параметра

в (12) все описано же

(25) пробывал как в (12) не очень получилось, и мне с датами не как.

(26) ВЫБРАТЬ
    НачалоПериода(ПеремещениеТоваровТовары.Ссылка.Дата, День) как ПараметрСвязиДляСвязиНаборовДанныхСКД,
    ПеремещениеТоваровТовары.Номенклатура,
    ПеремещениеТоваровТовары.СчетУчета,
    ПеремещениеТоваровТовары.Количество,
    ПеремещениеТоваровТовары.Ссылка.СкладОтправитель КАК Склад,
    ПеремещениеТоваровТовары.Ссылка.Дата
ИЗ
    Документ.ПеремещениеТоваров.Товары КАК ПеремещениеТоваровТовары
ГДЕ
    ПеремещениеТоваровТовары.Ссылка.ПометкаУдаления = ЛОЖЬ
    И ПеремещениеТоваровТовары.Ссылка.Проведен = ИСТИНА

+(27) Связь наборов в скд по номенклатуре и параметр - ПараметрСвязиДляСвязиНаборовДанныхСКД
Ну все разжевано

(23) Если ты не умеешь пользоваться СКД, это не значит, что этого нельзя сделать. Просто дату нужно параметром передавать во второй набор

(29)Да, с этим скилом я не была знакома.

все сделал еще вчера, вот какие запросы получились, нужные вещи вроде выбирались.
вот первый набор запросом:
ВЫБРАТЬ
    ПеремещениеТоваровТовары.Номенклатура,
    ПеремещениеТоваровТовары.СчетУчета,
    ПеремещениеТоваровТовары.Количество,
    ПеремещениеТоваровТовары.Ссылка.СкладОтправитель КАК Склад,
    ПеремещениеТоваровТовары.Ссылка.Дата,
    ПеремещениеТоваровТовары.Номенклатура.Родитель КАК Группа
ИЗ
    Документ.ПеремещениеТоваров.Товары КАК ПеремещениеТоваровТовары
ГДЕ
    ПеремещениеТоваровТовары.Ссылка.ПометкаУдаления = ЛОЖЬ
    И ПеремещениеТоваровТовары.Ссылка.Проведен = ИСТИНА
    И ПеремещениеТоваровТовары.Ссылка.СкладОтправитель В(&СкладОтправитель)
    И ПеремещениеТоваровТовары.Ссылка.Дата МЕЖДУ &НачДата И &КонДата

вот второй запрос набором:
ВЫБРАТЬ
    ЦеныНоменклатурыСрезПоследних.Номенклатура,
    ЦеныНоменклатурыСрезПоследних.Цена,
    &Период
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
            &Период,
            ТипЦен = &ТипЦен
                И Номенклатура = &Номенклатура) КАК ЦеныНоменклатурыСрезПоследних

и все это в СКД связываю на вкладке связи наборов данных по периоду, номенклатуре. как в (12) ссылке. почему-то запросы получились проще чем у них выбрать в {выбрать как то так}

Такой запрос можно написать и причем в СКД. Отчет по продажам себестоимость в произвольных ценах. Пользуйся

ВЫБРАТЬ
    Продажи.Период,
    Продажи.Номенклатура КАК Номенклатура,
    Продажи.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    Продажи.Регистратор,
    Продажи.ДоговорКонтрагента,
    Продажи.Организация,
    Продажи.Контрагент,
    СУММА(Продажи.Количество) КАК Количество,
    СУММА(Продажи.Стоимость) КАК Стоимость,
    СУММА(Продажи.СтоимостьБезСкидок) КАК СтоимостьБезСкидок,
    СУММА(Продажи.НДС) КАК НДС,
    Продажи.Подразделение
ПОМЕСТИТЬ втПериодов
ИЗ
    РегистрНакопления.Продажи КАК Продажи
ГДЕ
    Продажи.Период МЕЖДУ &НачалоПериода И &КонецПериода

СГРУППИРОВАТЬ ПО
    Продажи.Период,
    Продажи.Номенклатура,
    Продажи.ХарактеристикаНоменклатуры,
    Продажи.Регистратор,
    Продажи.ДоговорКонтрагента,
    Продажи.Организация,
    Продажи.Контрагент,
    Продажи.Подразделение

ИНДЕКСИРОВАТЬ ПО
    Номенклатура,
    ХарактеристикаНоменклатуры
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ЦеныНоменклатуры.Период КАК Период,
    ЦеныНоменклатуры.Номенклатура КАК Номенклатура,
    ЦеныНоменклатуры.ХарактеристикаНоменклатуры КАК ХарактеристикаНоменклатуры,
    ЦеныНоменклатуры.Цена КАК Цена
ПОМЕСТИТЬ втЦен
ИЗ
    РегистрСведений.ЦеныНоменклатуры КАК ЦеныНоменклатуры
ГДЕ
    ЦеныНоменклатуры.ТипЦен = &ТипЦен
    И (ЦеныНоменклатуры.Номенклатура, ЦеныНоменклатуры.ХарактеристикаНоменклатуры) В
            (ВЫБРАТЬ
                втПериодов.Номенклатура,
                втПериодов.ХарактеристикаНоменклатуры
            ИЗ
                втПериодов КАК втПериодов)
    И ЦеныНоменклатуры.Период <= &КонецПериода
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    втПериодов.Номенклатура,
    втПериодов.ХарактеристикаНоменклатуры,
    втПериодов.Регистратор,
    МАКСИМУМ(втЦен.Период) КАК Период,
    втПериодов.ДоговорКонтрагента,
    втПериодов.Организация,
    втПериодов.Контрагент,
    втПериодов.Количество,
    втПериодов.Стоимость,
    втПериодов.СтоимостьБезСкидок,
    втПериодов.НДС,
    втПериодов.Подразделение
ПОМЕСТИТЬ втПериодовЦен
ИЗ
    втПериодов КАК втПериодов
        ЛЕВОЕ СОЕДИНЕНИЕ втЦен КАК втЦен
        ПО втПериодов.Номенклатура = втЦен.Номенклатура
            И втПериодов.ХарактеристикаНоменклатуры = втЦен.ХарактеристикаНоменклатуры
            И втПериодов.Период >= втЦен.Период

СГРУППИРОВАТЬ ПО
    втПериодов.Номенклатура,
    втПериодов.ХарактеристикаНоменклатуры,
    втПериодов.Регистратор,
    втПериодов.ДоговорКонтрагента,
    втПериодов.Организация,
    втПериодов.Контрагент,
    втПериодов.Количество,
    втПериодов.Стоимость,
    втПериодов.СтоимостьБезСкидок,
    втПериодов.НДС,
    втПериодов.Подразделение
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    втПериодовЦен.Номенклатура КАК Номенклатура,
    втПериодовЦен.ХарактеристикаНоменклатуры,
    втПериодовЦен.Организация,
    втПериодовЦен.Контрагент,
    втПериодовЦен.ДоговорКонтрагента,
    втПериодовЦен.Регистратор,
    втЦен.Цена,
    СУММА(втПериодовЦен.Количество) КАК Количество,
    СУММА(втПериодовЦен.Стоимость) КАК Стоимость,
    СУММА(втПериодовЦен.СтоимостьБезСкидок) КАК СтоимостьБезСкидок,
    СУММА(втПериодовЦен.НДС) КАК НДС,
    СУММА(втПериодовЦен.Количество * ЕСТЬNULL(втЦен.Цена, 0)) КАК СтоимостьВУказанныхЦенах,
    втПериодовЦен.Подразделение
ПОМЕСТИТЬ втВспомогательная
ИЗ
    втПериодовЦен КАК втПериодовЦен
        ЛЕВОЕ СОЕДИНЕНИЕ втЦен КАК втЦен
        ПО втПериодовЦен.Номенклатура = втЦен.Номенклатура
            И втПериодовЦен.ХарактеристикаНоменклатуры = втЦен.ХарактеристикаНоменклатуры
            И втПериодовЦен.Период = втЦен.Период

СГРУППИРОВАТЬ ПО
    втПериодовЦен.Номенклатура,
    втПериодовЦен.ХарактеристикаНоменклатуры,
    втПериодовЦен.Регистратор,
    втПериодовЦен.ДоговорКонтрагента,
    втПериодовЦен.Организация,
    втПериодовЦен.Контрагент,
    втЦен.Цена,
    втПериодовЦен.Подразделение
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    втВспомогательная.Номенклатура,
    втВспомогательная.ХарактеристикаНоменклатуры,
    втВспомогательная.Организация,
    втВспомогательная.Контрагент,
    втВспомогательная.ДоговорКонтрагента,
    втВспомогательная.Регистратор,
    втВспомогательная.Цена,
    втВспомогательная.Количество,
    втВспомогательная.Стоимость,
    втВспомогательная.СтоимостьБезСкидок,
    втВспомогательная.НДС,
    втВспомогательная.СтоимостьВУказанныхЦенах,
    втВспомогательная.Подразделение
ИЗ
    втВспомогательная КАК втВспомогательная

(32) все одним запросом сделано? я прсото все сделал в СКД но тока 2 запросами и связал.

(0) Коррелированный подзапрос в 1С? Никак...
Обходной путь - http://kb.mista.ru/article.php?id=92

(33) это запрос из рабочего отчета в СКД. Схему скопировал из СКД и выложил.

(35) временные таблицы?