Нужно получить остатки на каждый день из регистра бухгалтерии. В самом запросе для дальнейшей обработки в запросе. Порядки обхода По периодам и СКД не подойдет. Накидал такой запрос, но он показывает только когда были движения.

ВЫБРАТЬ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК День
ПОМЕСТИТЬ Календарь
ИЗ
    РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря МЕЖДУ &НачДата И &КонДата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ХозрасчетныйОстаткиИОбороты.Период,
    ХозрасчетныйОстаткиИОбороты.Субконто1 КАК Контрагент,
    ХозрасчетныйОстаткиИОбороты.Субконто2 КАК Договор,
    ХозрасчетныйОстаткиИОбороты.СуммаНачальныйОстатокКт
ИЗ
    Календарь КАК Календарь
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачДата, &КонДата, День, ДвиженияИГраницыПериода, Счет = &Счет, , Организация = &Организация) КАК ХозрасчетныйОстаткиИОбороты
        ПО Календарь.День = ХозрасчетныйОстаткиИОбороты.Период

обновим

МАКСИМУМ(СуммаНачальныйОстатокКт) + СУММА(СуммаОборотКт) КАК СуммаНачальныйОстатокКт_НаДату
...
ПО Календарь.День >= ХозрасчетныйОстаткиИОбороты.Период
СГРУППИРОВАТЬ ПО ...

ПОЛНОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачДата, &КонДата, День, ДвиженияИГраницыПериода, Счет = &Счет, , Организация = &Организация) КАК ХозрасчетныйОстаткиИОбороты
        ПО Календарь.День = началоПериода(ХозрасчетныйОстаткиИОбороты.Период, День)

ну тут конечно вопрос что быстрей, полное или Левое, надо смотреть

ВЫБРАТЬ
    //ХозрасчетныйОстаткиИОбороты.Период,
    Календарь.День,

(3) он показывает только те дни, где были движения, (2) так я уже делал, он показывает несколько строк по одной дате

(6) Он и должен показывать несколько строк по одной дате, поскольку Субконто1 и Субконто2 могут быть разными.
(4) При чём тут скорость, если вы не придумали, как остаток за этот день выводить?

(7)Нет я пока отбираю только по одному значению субконто. Сколько было движений до этой даты - все выводит, с разными суммами.

всё придумано за меня
http://1c-wiki.ru/wiki/Ежедневные_остатки
http://kb.mista.ru/article.php?id=579&;

(2) Почему МАКСИМУМ. движения могут быть как по Дт так и по Кь, и сальдо не только увеличивается, но может и уменьшаться.

(8) если нужны остатки - зачем используешь ОстаткиИОбороты? по русски же написано, используй Остатки

(11) в остатках нет Периода, (9) СКД не подойдет, говорю же дальше нужно обрабатывать в запросе.

(12) да, с остатками погорячился, пример нужного тебе запроса есть в http://kb.mista.ru/article.php?id=579&;

(13) + смотри там второй запрос, но вместо КурсыВалют используй производственный календарь

(14) да пробовал я так, точно так. выводит то же самое что и (2)

да и непрозрачно там все как то

(16) кто мешает потом сгруппировать по дате то?

вот смотри:
по факту:
01.10.13 - остаток 100
02.10.13 - остаток 100
03.10.13 - остаток 200
04.10.13 - остаток 500
05.10.13 - остаток 50

наш запрос выводит:
01.10.13 - остаток 100
02.10.13 - остаток 100
03.10.13 - остаток 200
03.10.13 - остаток 100
04.10.13 - остаток 300
04.10.13 - остаток 200
04.10.13 - остаток 100
05.10.13 - остаток 50
05.10.13 - остаток 300
05.10.13 - остаток 200
05.10.13 - остаток 100

что тут как группировать? ну должно же быть простое решение такой простой задачи

(0) Общая идея такая. Сначала получаешь остатки на дни, когда были движения (с периодом День) и помещаешь в ВТ. А теперь представь, что ВТ это записи регистра сведений; И нужно получить срезы на каждый день. Аналогично курсу валюты на каждый день. Соединяем с календарем по Дата >= Период, группируем, берем ближайший период, соединяем еще раз с ВТ по этому периоду. Примеров таких запросов много в типовых.

(18) запрос из (13) не должен давать в таком виде... надо попробовать

С максимумом я погорячился, это из другой задачи, где НачальныйОстаток всегда одинаков.

ВЫБРАТЬ
    ХозрасчетныйОстаткиИОбороты.Период,
    ХозрасчетныйОстаткиИОбороты.Субконто1,
    ХозрасчетныйОстаткиИОбороты.Субконто2,
    ХозрасчетныйОстаткиИОбороты.СуммаНачальныйОстатокКт,
    ХозрасчетныйОстаткиИОбороты.СуммаОборотКт
ПОМЕСТИТЬ ОстаткиИОбороты
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачДата, &КонДата, День, ДвиженияИГраницыПериода, Счет = &Счет, , Организация = &Организация) КАК ХозрасчетныйОстаткиИОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ОстаткиИОбороты.Период,
    ОстаткиИОбороты.Субконто1,
    ОстаткиИОбороты.Субконто2,
    ОстаткиИОбороты.СуммаНачальныйОстатокКт
ИЗ
    ОстаткиИОбороты КАК ОстаткиИОбороты
ГДЕ
    ОстаткиИОбороты.Период = &НачДата

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    ОстаткиИОбороты.Период,
    ОстаткиИОбороты.Субконто1,
    ОстаткиИОбороты.Субконто2,
    СУММА(ОстаткиИОбороты.СуммаОборотКт)
ИЗ
    Календарь КАК Календарь
        ЛЕВОЕ СОЕДИНЕНИЕ ОстаткиИОбороты КАК ОстаткиИОбороты
        ПО Календарь.День > ОстаткиИОбороты.Период

СГРУППИРОВАТЬ ПО
    ОстаткиИОбороты.Период,
    ОстаткиИОбороты.Субконто1,
    ОстаткиИОбороты.Субконто2

(19) вот я остановился как раз на (18), а как взять ближайший период, если на каждую дату календаря он берет все даты остатков которые меньше текущей календарной

Кажется, кто-то пишет отчет "Расчет сумм агентских вознаграждений"?

ага, задача похожая)) проценты по полученным кредитам нужно читать на каждый день

(24) + тут задача немного другая

(24) я так её и не решил. Сдал другим разом, другой отчет в билете был...

а я оба раза провалил и вообще забил на этот экзамен((

(21) нет не то, попробуй сам запусти

Это если тебе для одного договора надо

ВЫБРАТЬ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК День
ПОМЕСТИТЬ Календарь
ИЗ
    РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря МЕЖДУ &НачДата И &КонДата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ХозрасчетныйОстаткиИОбороты.Период,
    ЕСТЬNULL(ХозрасчетныйОстаткиИОбороты.СуммаНачальныйОстаток, 0) КАК Остаток
ИЗ
    Календарь КАК Календарь
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
                &НачДата,
                &КонДата,
                День,
                ,
                Счет = &Счет,
                ,
                Организация = &Организация
                    И Субконто1 = &Контрагент
                    И Субконто2 = &Договор) КАК ХозрасчетныйОстаткиИОбороты
        ПО Календарь.День = ХозрасчетныйОстаткиИОбороты.Период

Обороты бери.

ХозрасчетныйОстаткиИОбороты.Период на Календарь.День заменить надо

а вот примерно так можно получить по списку контрагентов/договоров хоть и через одно место.

ВЫБРАТЬ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК День
ПОМЕСТИТЬ Календарь
ИЗ
    РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
    РегламентированныйПроизводственныйКалендарь.ДатаКалендаря МЕЖДУ &НачДата И &КонДата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ДоговорыКонтрагентов.Владелец КАК Контрагент,
    ДоговорыКонтрагентов.Ссылка КАК Договор
ПОМЕСТИТЬ ДоговорКонтрагента
ИЗ
    Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Календарь.День,
    ДоговорКонтрагента.Контрагент,
    ДоговорКонтрагента.Договор
ПОМЕСТИТЬ КалендарьДоговор
ИЗ
    Календарь КАК Календарь,
    ДоговорКонтрагента КАК ДоговорКонтрагента
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    КалендарьДоговор.День,
    КалендарьДоговор.Контрагент,
    КалендарьДоговор.Договор,
    ЕСТЬNULL(ХозрасчетныйОстаткиИОбороты.СуммаНачальныйОстаток, 0) КАК Остаток
ИЗ
    КалендарьДоговор КАК КалендарьДоговор
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачДата, &КонДата, День, , Счет = &Счет, , Организация = &Организация) КАК ХозрасчетныйОстаткиИОбороты
        ПО КалендарьДоговор.День = ХозрасчетныйОстаткиИОбороты.Период
            И КалендарьДоговор.Контрагент = ХозрасчетныйОстаткиИОбороты.Субконто1
            И КалендарьДоговор.Договор = ХозрасчетныйОстаткиИОбороты.Субконто2

(32) все остатки показывает, так как по всем договорам, не только по определенному счету

(33) и в чем проблема?

в чем суть задачи? не получения данных а именно задачи?

(33) У меня создаётся впечатление, что сам не понимаешь, что хочешь.
Если подойти строго к (18), то Субконто1 и Субконто2 совсем убери - и будет щасте.

(35) у меня должна получиться таблица

01.10.13 - Счет, Субконто1, Субконто1, Сальдо
02.10.13 - Счет, Субконто1, Субконто1, Сальдо
........
и т.д.

(37) для чего тебе эта таблица.
огласи начальную задачу, иначе не совсем понятно что в конечном итоге надо получить.
может ты вообще не то делаешь.

(37) запрос в (32) показывает то ты хочешь, но тебя это не устраивает по своим причинам, поэтому огласи задачу сначала и до конца.

мне нужно рассчитать процент кредитов на каждый день на счетах учета 66.01, 66.03 пока каждому контрагенту и договору

когда у меня получится такая таблица, я за день рассчитаю проценты, сгруппирую как нужно и все выгружу в табличную часть документа.

был бы отчет на СКД, легко можно было бы сделать давно

(42) а в чем проблема получить коллекцию через скд ?

(0) если я правильно понял, используй наращиваемый запрос. вот прим. только по месяцам, переделай по дням.
Функция СформироватьВТПоОстаткам(Запрос, НазваниеВТ,Тип = "СНД")
        
        Текст = ?(Тип = "СНД","Сальдо начальное ДТ","Сальдо конечное ДТ");
        
        Состояние("Формирование выборки остатков");
        ТекстЗапроса = "";    
        Для Каждого СтрокаМесяца Из ТаблицаМесяцев Цикл
            Ид = ТаблицаМесяцев.Индекс(СтрокаМесяца);
            Период = НачалоДня(СтрокаМесяца.Месяц);
            НазваниеПараметраПериод = "Период"+Ид+"_"+НазваниеВТ+"_"+Тип;
            Запрос.УстановитьПараметр(НазваниеПараметраПериод, Период);    
            Если ПустаяСтрока(ТекстЗапроса)  Тогда
                ТекстЗапроса =
                "ВЫБРАТЬ  
                |&"+НазваниеПараметраПериод+" КАК МесяцСписка,
                |"""+ Текст +""" КАК Документ,
                |ХозрасчетныйОстатки.Счет КАК Счет,
                |ХозрасчетныйОстатки.Субконто1 КАК Аналитика,
                |ХозрасчетныйОстатки.СуммаОстатокДт КАК Сумма
                |ПОМЕСТИТЬ " + НазваниеВТ
            Иначе
                ТекстЗапроса = ТекстЗапроса +
                " ОБЪЕДИНИТЬ ВСЕ
                |ВЫБРАТЬ
                |&"+НазваниеПараметраПериод+" КАК Период,
                |"""+ Текст +""",
                |ХозрасчетныйОстатки.Счет КАК Счет,
                |ХозрасчетныйОстатки.Субконто1 КАК Аналитика,
                |ХозрасчетныйОстатки.СуммаОстатокДт КАК Сумма";
            КонецЕсли;
            ТекстЗапроса = ТекстЗапроса +
            " ИЗ    
            |РегистрБухгалтерии.Хозрасчетный.Остатки("+?(Тип = "СКД","ДОБАВИТЬКДАТЕ(&"+НазваниеПараметраПериод+", МЕСЯЦ, 1)","&"+НазваниеПараметраПериод)+", Счет В ИЕРАРХИИ (&СписокСчетовОтчета),&ВидыСубконто, Организация = &Организация) КАК ХозрасчетныйОстатки"
            +
            ?(ЗначениеЗаполнено(Подразделение)," ГДЕ ХозрасчетныйОстатки.Подразделение В ИЕРАРХИИ(&Подразделение) " + Символы.ПС,Символы.ПС);    
        КонецЦикла;    
        
        Возврат ТекстЗапроса;
        
    КонецФункции

в (32) поменяй


ВЫБРАТЬ
    ДоговорыКонтрагентов.Владелец КАК Контрагент,
    ДоговорыКонтрагентов.Ссылка КАК Договор
ПОМЕСТИТЬ ДоговорКонтрагента
ИЗ
    Справочник.ДоговорыКонтрагентов КАК ДоговорыКонтрагентов


НА


ВЫБРАТЬ
    ХозрасчетныйОстаткиИОбороты.Субконто1 КАК Контрагент,
    ХозрасчетныйОстаткиИОбороты.Субконто2 КАК Договор
ПОМЕСТИТЬ ДоговорКонтрагента
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачДата, &КонДата, , , Счет = &Счет, , Организация = &Организация) КАК ХозрасчетныйОстаткиИОбороты

(44) да ненадо мне в цикле дни обрабатывать, тогда уж я количество дней посчитаю с одного оборота до следующего оборота.

(45) в дни без движений сальдо не показывает. Друзья Большое всем спасибо. Сам пока занят, а то получается вас задергал а сам не участвую. Что у меня получится, я напишу. Всем еще раз спасибо!!!

Все же пришлось сделать в цикле:
Запрос = Новый Запрос;
    Запрос.Текст =
    "ВЫБРАТЬ
    |    ХозрасчетныйОстаткиИОбороты.Субконто1 КАК Контрагент,
    |    ХозрасчетныйОстаткиИОбороты.Субконто2 КАК Договор,
    |    ХозрасчетныйОстаткиИОбороты.Счет КАК Счет,
    |    ХозрасчетныйОстаткиИОбороты.Период КАК День,
    |    ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокКт + ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокДт КАК СуммаКонечныйОстатокКт
    |ИЗ
    |    РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачДата, &КонДата, День, ДвиженияИГраницыПериода, Счет В (&СчетаКредитовИЗаймов), &ПорядокСубконто, Организация = &Организация) КАК ХозрасчетныйОстаткиИОбороты
    |
    |УПОРЯДОЧИТЬ ПО
    |    Контрагент,
    |    Договор,
    |    Счет,
    |    День
    |ИТОГИ
    |    СУММА(СуммаКонечныйОстатокКт)
    |ПО
    |    Контрагент,
    |    Договор,
    |    Счет,
    |    День ПЕРИОДАМИ(ДЕНЬ, &НачДата, &КонДата)
    |АВТОУПОРЯДОЧИВАНИЕ";
    
    Запрос.УстановитьПараметр("НачДата", НачДата);
    Запрос.УстановитьПараметр("КонДата", КонДата);
    Запрос.УстановитьПараметр("Организация", Организация);
    Запрос.УстановитьПараметр("СчетаКредитовИЗаймов", СчетаКредитовИЗаймов);
    Запрос.УстановитьПараметр("ПорядокСубконто", ПорядокСубконто);
    
    Результат = Запрос.Выполнить();
    
    ВыборкаКонтрагент = Результат.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
    
    Пока ВыборкаКонтрагент.Следующий() Цикл
        
        ВыборкаДоговор = ВыборкаКонтрагент.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
        
        Пока ВыборкаДоговор.Следующий() Цикл
            
            ВыборкаСчет = ВыборкаДоговор.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
            
            Пока ВыборкаСчет.Следующий() Цикл
                
                ВыборкаДень = ВыборкаСчет.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам, "День", "ВСЕ");   //Проценты на каждый день

ВЫБРАТЬ
    ХозрасчетныйОстаткиИОбороты.Субконто1 КАК Контрагент,
    ХозрасчетныйОстаткиИОбороты.Субконто2 КАК Договор,
    ХозрасчетныйОстаткиИОбороты.Счет КАК Счет,
    ХозрасчетныйОстаткиИОбороты.Период КАК День,
    ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокКт + ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокДт КАК СуммаКонечныйОстатокКт
ПОМЕСТИТЬ ОстаткиОбороты
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачДата, &КонДата, День, ДвиженияИГраницыПериода, Счет В (&СчетаКредитовИЗаймов), &ПорядокСубконто, Организация = &Организация) КАК ХозрасчетныйОстаткиИОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ОстаткиОбороты.Контрагент,
    ОстаткиОбороты.Договор,
    ОстаткиОбороты.Счет,
    ОстаткиОбороты.День,
    ОстаткиОбороты.СуммаКонечныйОстатокКт,
    ЕСТЬNULL(МИНИМУМ(ДОБАВИТЬКДАТЕ(ОстаткиОбороты1.День, ДЕНЬ, -1)), ОстаткиОбороты.День) КАК День1
ПОМЕСТИТЬ ОстаткиПериоды
ИЗ
    ОстаткиОбороты КАК ОстаткиОбороты
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ОстаткиОбороты КАК ОстаткиОбороты1
        ПО ОстаткиОбороты.Контрагент = ОстаткиОбороты1.Контрагент
            И ОстаткиОбороты.Договор = ОстаткиОбороты1.Договор
            И ОстаткиОбороты.Счет = ОстаткиОбороты1.Счет
            И ОстаткиОбороты.День < ОстаткиОбороты1.День

СГРУППИРОВАТЬ ПО
    ОстаткиОбороты.Контрагент,
    ОстаткиОбороты.Договор,
    ОстаткиОбороты.Счет,
    ОстаткиОбороты.День,
    ОстаткиОбороты.СуммаКонечныйОстатокКт
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Календарь.ДатаКалендаря КАК День,
    ОстаткиПериоды.Контрагент,
    ОстаткиПериоды.Договор,
    ОстаткиПериоды.Счет,
    ОстаткиПериоды.СуммаКонечныйОстатокКт
ИЗ
    ОстаткиПериоды КАК ОстаткиПериоды
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК Календарь
        ПО (Календарь.ДатаКалендаря МЕЖДУ ОстаткиПериоды.День И ОстаткиПериоды.День1)

(49) Наконец-то правильное решение

(49) Самое правильное решение. Спасибо!