Конфигурация КА 1.1.39.1.
Программно создается текст сообщения и затем вызывется процедура на отправку письма. но письмо не отправляется. Документ сохраняется. Но когда в него захожу то поле кому заполнено но в тоже время и не заполнено, как будто ссылку не передал на него.
Вот текст отправки письма.
    
Документ = Документы.ЭлектронноеПисьмо.СоздатьДокумент();
    Документ.ОтправительАдресЭлектроннойПочты = адресотправителя;
    Документ.ОтправительИмя = имяотправителя;
    Запрос = Новый Запрос;
    Запрос.Текст =
        "ВЫБРАТЬ
        |    КонтактнаяИнформация.Объект,
        |    КонтактнаяИнформация.Тип,
        |    КонтактнаяИнформация.Вид,
        |    КонтактнаяИнформация.Представление
        |ИЗ
        |    РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
        |ГДЕ
        |    КонтактнаяИнформация.Объект.Ссылка = &Ссылка";
    Запрос.УстановитьПараметр("Ссылка", Контрагент);
    Результат = Запрос.Выполнить();
    ВыборкаДетальныеЗаписи = Результат.Выбрать();
    Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
        Если ВыборкаДетальныеЗаписи.Тип = Перечисления.ТипыКонтактнойИнформации.АдресЭлектроннойПочты Тогда
            Документ.Кому = ВыборкаДетальныеЗаписи.Представление;
            документ.КомуПредставление = ВыборкаДетальныеЗаписи.Представление;
        КонецЕсли;
    КонецЦикла;
    Документ.Тема = "Тема";
    
    Документ.ТекстПисьма = ТекстПисьма;
    Документ.Дата = ТекущаяДата();
    Документ.Записать();
    документ.ОтправитьПисьмо();

это хорошо или плохо?

(1) это плохо)))
письмо не отправляется)))

точно, вопрос то я не задал)))
вопрос такой - как сделать правильно???

а кто будет проверять учетная запись под который отправляется письмо? как минимум.

(3) а вдруг так и есть правильно? дождись того, кто знает, что происходит в ОтправитьПисьмо()

(4) чего то ничего не понял. то есть как это проверять учетную запись.

справочник УчетныеЗаписиЭлПочты

если есть в вашей КА

(7) справочник есть. а каким образом проверить учетную запись?

(9) бывает кнопка такая у элемента

http://s2.ipicture.ru/uploads/20131209/2PDxe4AC.png

(11) это то сразу проверил)))я даже когда дкоумент создаю в режиме 1с предприятие письмо отправляется.
а вот с конфигуратора не хочет

(6) Видимо не то не понял :)
Код функции ОтправитьПисьмо() нужно. И платформа чтоб не 18-цатая была. У меня глючила, 17 и 19 нормально с почтой работала.

(13) у меня как раз 18-ая((

(13) а код функции ОтправитьПисьмо()там стандартный

(15) отладчик, наверное, тоже штатный?

(0) В  Документы.ЭлектронноеПисьмо случаем нету  табличной части КомуТЧ?
ее тож надо заполнить ;)

(17)
+ проверь авторизацию в почте (smtp pop3 ну ты понел

(17) Поменял текст на
СписокАдресов = Новый СписокЗначений;
            СписокАдресов.Добавить(ВыборкаДетальныеЗаписи.Представление, ВыборкаДетальныеЗаписи.Представление);
            Документ.Кому = СписокАдресов;
            Документ.КомуТЧ = СписокАдресов;
            документ.КомуПредставление = ВыборкаДетальныеЗаписи.Представление;

выдает что поле КомуТЧ недоступно для записи

(18) авторизация проходит

(19) в ут тож делаю электронку.
Сделал  пока так.

ДокПисьмо = Документы.ЭлектронноеПисьмо.СоздатьДокумент();
    
    ДокПисьмоТЧ = ДокПисьмо.КомуТЧ;
    ДокПисьмоТЧ.Очистить();
    Тч = ДокПисьмоТЧ.Добавить();
    Тч.Представление = Кому;
    Тч.АдресЭлектроннойПочты = Кому;
        
    ДокПисьмо.Дата = ТекущаяДата();
    ДокПисьмо.УчетнаяЗапись = ЕмаилОтправителя;
    ДокПисьмо.Тема = Шапка;
    ДокПисьмо.ТекстПисьма = Тело;
    ДокПисьмо.Кому = Кому;
    ДокПисьмо.Записать();
    ДокПисьмо.ОтправитьПисьмо();

Работало и отправляло )

(22) через пару часов попробую)))а то с офиса выпинывают, надо домой ехать))) обязательно отпишусь - думаю должно получится

(22) спасибо получилось))))))

(24) Пжалусть )

работает уже 7 лет......


Функция ОтправитьПисьмо (Письмо, МассивАдресов, СсылкаНаОбъект, Регистратор, Комментарий = "", УчетнаяЗапись = Неопределено, РегистрироватьОшибки = Истина, Отправка = Истина) Экспорт
    
    _УчетнаяЗапись = УчетнаяЗапись;
    Если УчетнаяЗапись = Неопределено Тогда
        _УчетнаяЗапись = ПолучитьСистемнуюУчетнуюЗапись();
    КонецЕсли;
    
    Если не _УчетнаяЗапись.ИспользоватьДляОтправки Тогда
        Возврат Ложь;
    КонецЕсли;
    
    Если Не Письмо.ОправлятьПочтовыеУведомления Тогда
        Возврат Ложь;
    КонецЕсли;
    
    Если МассивАдресов = Неопределено Тогда
        Возврат Ложь;                            
    КонецЕсли;
    
    Если МассивАдресов.Количество() = 0 Тогда
        Возврат Ложь;
    КонецЕсли;                                                  
    
    Если ТипЗнч(СсылкаНаОбъект) = Тип("ДокументСсылка.Сделка") Тогда
        Если СсылкаНаОбъект.ОтправленыеУведомления.Найти(Регистратор,"Источник") <> Неопределено Тогда
            Возврат Ложь;
        КонецЕсли;
    КонецЕсли;
    
    
    _Отправка = Отправка;
    Если не Отправка Тогда
        Если не _УчетнаяЗапись.ОтложенаяОтправкаПочты Тогда
            _Отправка = Истина;
        КонецЕсли;
    КонецЕсли;
    
    Если не _Отправка Тогда
        // запись в регистр отложеной отправки
        Запись = РегистрыСведений.ДоставкаПочты.СоздатьМенеджерЗаписи();
        Запись.МассивОтправки     = Новый ХранилищеЗначения(МассивАдресов);
        Запись.Объект             = СсылкаНаОбъект;
        Запись.ШаблонПисьма        = Письмо;
        Запись.Оправлен            = Ложь;
        Запись.Комментарий        = Комментарий;
        Запись.ДокументРегистратор    = Регистратор;
        Запись.Записать(Истина);
    Иначе
        // собствено отправка
        ТемаПисьма         = СобратьЭлементПочтовогоСообщения(Письмо.Тема, СсылкаНаОбъект);
        СообщениеПисьма = СобратьЭлементПочтовогоСообщения(Письмо.Сообщение, СсылкаНаОбъект, Комментарий);
        СистемнаяПочта  = СокрЛП(_УчетнаяЗапись.АдресЭлектроннойПочты);
        ТипСообщения = Неопределено;
        Профиль = СформироватьИнтернетПрофиль(_УчетнаяЗапись);
        
        Попытка
            Сообщение = Новый ИнтернетПочтовоеСообщение;
            Сообщение.Тема             = ТемаПисьма;
            Сообщение.Отправитель     = СистемнаяПочта;
            
            Для Каждого ПочтовыйАдрес из МассивАдресов Цикл
                Если Найти(ПочтовыйАдрес, "@") > 0 Тогда
                    Сообщение.Получатели.Добавить(ПочтовыйАдрес);
                КонецЕсли;
            КонецЦикла;
            
            Если      Письмо.ТипТекстаПисьма = Перечисления.ТипыТекстовЭлектронныхПисем.HTML
                  ИЛИ Письмо.ТипТекстаПисьма = Перечисления.ТипыТекстовЭлектронныхПисем.HTMLСКартинками Тогда
                  
                Сообщение.Тексты.Добавить(СообщениеПисьма, ТипТекстаПочтовогоСообщения.HTML);
                
            ИначеЕсли Письмо.ТипТекстаПисьма = Перечисления.ТипыТекстовЭлектронныхПисем.РазмеченныйТекст Тогда
                
                Сообщение.Тексты.Добавить(СообщениеПисьма, ТипТекстаПочтовогоСообщения.РазмеченныйТекст);
                
            Иначе
                Сообщение.Тексты.Добавить(СообщениеПисьма, ТипТекстаПочтовогоСообщения.ПростойТекст);
            КонецЕсли;
            
            Почта = Новый ИнтернетПочта;
            Почта.Подключиться(Профиль);
            Почта.Послать(Сообщение);
            Почта.Отключиться();
            
            
            Если ТипЗнч(СсылкаНаОбъект) = Тип("ДокументСсылка.Сделка") Тогда
                оСделка = СсылкаНаОбъект.ПолучитьОбъект();
                НоваяСтрока = оСделка.ОтправленыеУведомления.Добавить();
                НоваяСтрока.Источник = Регистратор;
                оСделка.ОбменДанными.Загрузка = Истина;
                оСделка.Записать();
            КонецЕсли;
            
            
        Исключение
            Если РегистрироватьОшибки Тогда
                ЗарегистрироватьОшибкуОтправкиПочты(СсылкаНаОбъект, Письмо, МассивАдресов, ОписаниеОшибки(), Регистратор, Комментарий);
            КонецЕсли;
            Возврат Ложь;
        КонецПопытки;
    КонецЕсли;
    
    Возврат Истина;
КонецФункции