Печать этикеток. Вывести Артикул товара

Конфигурация УТП для Казахстана 2.0.3.6. задачой была вывести в этикетки артикул. В типовой это не предусмотрено. Нашел обработку ПечатьЭтикеток. сделал внешней, а макет в общий. в макете добавил поле с текстом Артикул идентично как для номенклатуры. Отредактировал координаты областей. Вылазит ошибка при печати

{Форма.Форма.Форма(368)}: Поле объекта не обнаружено (ГраницаСправа)
        ОбластьГраницаСправа.Рисунки.ГраницаСправа.Высота = ВысотаЭтикетки*1.09;

Координаты перепроверил все сходится. Подскажите пжлста где ошибка и как ее решить

// Процедура печати этикеток
//
// Параметры:
//  ТаблицаТоваров     - Таблица значений, содержащая информацию о печатаемых этикетках.
//
Процедура Печать(ТаблицаТоваров) Экспорт

    КолвоПереданныхТоваров = ТаблицаТоваров.Количество();

    Если КолвоПереданныхТоваров = 0 Тогда
        Предупреждение("В списке нет ни одного товара со штрихкодом, заполните список товаров,"
                       + Символы.ПС + "для которых надо распечатать этикетки. ");
        Возврат;
    КонецЕсли;

    ПечататьБезЦены        = Ложь;
    Если ПечататьЦену Тогда
        Для Каждого СтрокаИзСписка Из ТаблицаТоваров Цикл
            Если СтрокаИзСписка.Цена = 0 И СтрокаИзСписка.Количество > 0 Тогда
                Ответ = Вопрос("У некоторых товаров не указаны цены! Печатать этикетки для этих товаров?",
                               РежимДиалогаВопрос.ДаНетОтмена);
                Если Ответ = КодВозвратаДиалога.Отмена Тогда
                    Возврат;
                ИначеЕсли Ответ = КодВозвратаДиалога.Да Тогда
                    ПечататьБезЦены = Истина;
                ИначеЕсли Ответ = КодВозвратаДиалога.Да Тогда
                    ПечататьБезЦены = Ложь;
                КонецЕсли;
                Прервать;
            КонецЕсли;
        КонецЦикла;
    КонецЕсли;

    ТекКолонка = 1;
    ТекСтрока  = 1;

    Таб                     = Новый ТабличныйДокумент;
    Таб.ИмяПараметровПечати =     "ПАРАМЕТРЫ_ПЕЧАТИ_Этикетка"+СокрЛП(ИмяКомпьютера());

    Макет                   = ПолучитьОбщийМакет("Этикетка");

    ЭтикеткаОбласть         = Макет.ПолучитьОбласть(1,1,5,2);

    ОбластьНоменклатура     = ЭтикеткаОбласть.Области.Номенклатура;
    //Сухраб от
    ОбластьАртикул          = ЭтикеткаОбласть.Области.Артикул;
    //Сухраб до

    ОбластьШтрихкод         = ЭтикеткаОбласть.Области.ОбластьШтрихкод;
    РисунокШтрихкод         = ЭтикеткаОбласть.Рисунки.Штрихкод;
    ОбластьЦена             = ЭтикеткаОбласть.Области.Цена;


    ОбластьНоменклатура.ВысотаСтроки = ВысотаЭтикетки * 2.65 * 0.3;
    //Сухраб от
    ОбластьАртикул.ВысотаСтроки      = ВысотаЭтикетки * 2.65 * 0.2;
    //Сухраб до

    ОбластьШтрихкод.ВысотаСтроки     = ВысотаЭтикетки * 2.65 * 0.5;
    РисунокШтрихкод.Расположить(ОбластьШтрихкод);
    ОбластьЦена.ВысотаСтроки         = ВысотаЭтикетки * 2.65 * 0.2;

    ЭтикеткаОбласть.Область(2,2,2,2).ШиринаКолонки = ШиринаЭтикетки*0.53;

    Если ФорматЭтикетки  = 1 Тогда //принтер этикеток.
        ВсегоСтрок       = 1;
        КоличествоКолонок=1;
    ИначеЕсли ФорматЭтикетки = 2 Тогда //А4 по колонкам.

        ОбластьГраницаСправа      = Макет.ПолучитьОбласть(2,4,5,4);
        ОбластьНизГраницыСправа   = Макет.ПолучитьОбласть(6,4,6,4);
        ОбластьГраницаСнизу       = Макет.ПолучитьОбласть(7,2,7,2);
        ОбластьНачалоГраницыСнизу = Макет.ПолучитьОбласть(7,1,7,1);

        ОбластьГраницаСправа.Рисунки.ГраницаСправа.Высота = ВысотаЭтикетки*1.09;
        ОбластьГраницаСнизу.Рисунки.ГраницаСнизу.Ширина   = ШиринаЭтикетки;

        ОбластьГраницаСправа.Область(1,1,1,1).ВысотаСтроки = ВысотаЭтикетки*2.65;
        ОбластьГраницаСнизу.Область(1,1,1,1).ШиринаКолонки = ШиринаЭтикетки*0.53;

        ВсегоСтрок        = 22;
        КоличествоКолонок = 5;
    КонецЕсли;

    ВсегоКолонок = КоличествоКолонок;
    Если ВсегоКолонок > 1 Тогда
        ВсегоКолонок = ВсегоКолонок+ВсегоКолонок - 1; //добавляем разделители колонок.
    КонецЕсли;

    ВывелиХотяБыОдинШтрихКод = Ложь;
    Для Каждого СтрокаИзСписка Из ТаблицаТоваров Цикл
        Если ПечататьЦену И СтрокаИзСписка.Цена = 0
           И Не ПечататьБезЦены Тогда
            Продолжить;
        КонецЕсли;

        ТипКода = ПолучитьЗначениеТипаШтрихкодаДляЭУ(СтрокаИзСписка.ТипШтрихкода);
        Если ТипКода = -1 Тогда
            ОбщегоНазначения.СообщитьОбОшибке("Для штрихкода формата """ + СтрокаИзСписка.ТипШтрихкода
                             + """ не существует соответствующего типа в ЭУ ""1С:Печать штрихкодов"".
                             | Позиция будет пропущена");
            Продолжить;
        КонецЕсли;

        Если УправлениеРозничнойТорговлей.ПроверитьШтрихКод(СтрокаИзСписка.ШтрихКод, СтрокаИзСписка.ТипШтрихкода) Тогда
            ЭтикеткаОбласть.Рисунки.Штрихкод.Объект.ТипКода = ТипКода;
            ЭтикеткаОбласть.Рисунки.Штрихкод.Объект.Сообщение = СтрокаИзСписка.ШтрихКод;
            ОбластьНоменклатура.Текст = СокрЛП(СтрокаИзСписка.Номенклатура) + ФормированиеПечатныхФорм.ПредставлениеСерий(СтрокаИзСписка);
            //Сухраб от
            ОбластьАртикул.Текст=СтрокаИзСписка.Артикул;
            //Сухраб до
            Если ПечататьЦену И СтрокаИзСписка.Цена <> 0 Тогда
                ОбластьЦена.Текст = "Цена: " + ОбщегоНазначения.ФорматСумм(СтрокаИзСписка.Цена,СтрокаИзСписка.Валюта)
                   + " за " + СтрокаИзСписка.ЕдиницаИзмерения;
            КонецЕсли;
            Для Копий = 1 По СтрокаИзСписка.Количество Цикл
                Если ТекКолонка > ВсегоКолонок Тогда //новая строка.
                    Если ВсегоСтрок <> 1 Тогда //выведем разделитель.
                        Для Сч = 1 по ВсегоКолонок Цикл
                            Если Сч = 1 Тогда
                                Таб.Вывести(ОбластьНачалоГраницыСнизу);
                            Иначе
                                Таб.Присоединить(ОбластьНачалоГраницыСнизу);
                            КонецЕсли;
                            Таб.Присоединить(ОбластьГраницаСнизу);
                            Таб.Присоединить(ОбластьНизГраницыСправа);
                            Сч = Сч + 1;
                        КонецЦикла;
                        ТекСтрока = ТекСтрока + 1;
                    КонецЕсли;
                    Если ТекСтрока/ВсегоСтрок = Цел(ТекСтрока/ВсегоСтрок) Тогда
                        Таб.ВывестиГоризонтальныйРазделительСтраниц();
                    КонецЕсли;
                    ТекСтрока = ТекСтрока + 1;
                    ТекКолонка=1;
                КонецЕсли;
                Если ТекКолонка<>1 Тогда //выведем разделитель.
                    Таб.Присоединить(ОбластьГраницаСправа);
                    ТекКолонка = ТекКолонка + 1;
                    Таб.Присоединить(ЭтикеткаОбласть);
                    ТекКолонка = ТекКолонка + 1;
                Иначе
                    Таб.Вывести(ЭтикеткаОбласть);
                    ТекКолонка = ТекКолонка + 1;
                КонецЕсли;

                ВывелиХотяБыОдинШтрихКод = Истина;
            КонецЦикла;
        Иначе
            ТекстСообщения = "У товара """ + СтрокаИзСписка.Номенклатура + """ штрихкод не задан или имеет неверный формат!";
            Если КолвоПереданныхТоваров = 1 Тогда
                Предупреждение(ТекстСообщения);
            Иначе
                Сообщить(ТекстСообщения,СтатусСообщения.БезСтатуса);
            КонецЕсли;
        КонецЕсли;
    КонецЦикла;

    Если ВывелиХотяБыОдинШтрихКод Тогда
        УниверсальныеМеханизмы.НапечататьДокумент(Таб, 1, СразуНаПринтер, "Этикетки");
    Иначе
        Сообщить("На печать не выведено ни одной этикетки!");
    КонецЕсли;

КонецПроцедуры // Печать()

макет Этикетка
http://s020.radikal.ru/i706/1402/e9/f8191ef606eb.png