О выпуске версии 11.1.4 конфигурации "Управление торговлей" на платформе "1С:Предприятие 8.3"
http://www.1c.ru/news/info.jsp?id=17929
Кто нибудь уже успел пощупать?

Ну и за одно поздравляю всех нас с великолепным выступлением Аделины Сотниковой!

Юлю жалко.

ну круто че

(2) так там Такси или режим совместимости?

Почему здесь https://users.v8.1c.ru/ все еще нет 11.1.4 ?

(3) Не такси.
(4) Давно уже есть.

Странное чередование релизов!?
11.1.2.31 18.02.2014 март 2014 11.1.2.28
11.1.4.11 10.02.2014 март 2014 11.1.2.28, 11.1.4.10

(0) Я щупаю. Уже отчёт под неё портировал. Там теперь хитро с отчётами.

(6)а что странного?

(7) а что хитрого?

(9) Посмотри любой, к примеру Выручка и себестоимость продаж, глянь в свойства, глянь в модуль менеджера, призадумайся.

(10) ну если ты уже смотрел - тяжко пару строк черкнуть? может и посмотрел бы сразу, только скачать сначала нужно и ессно буду качать.

(10)а что именно вас там удивило?

#Если Сервер Или ТолстыйКлиентОбычноеПриложение Или ВнешнееСоединение Тогда


///////////////////////////////////////////////////////////////////////////////
// ПРОГРАММНЫЙ ИНТЕРФЕЙС

// СтандартныеПодсистемы.ВариантыОтчетов

// Настройки вариантов этого отчета.
// Подробнее - см. ВариантыОтчетовПереопределяемый.НастроитьВариантыОтчетов.
//
Процедура НастроитьВариантыОтчета(Настройки, ОписаниеОтчета) Экспорт
    
    // Отключение контекстных вариантов
    ВариантыОтчетовУТПереопределяемый.ОтключитьВариантОтчета(Настройки, ОписаниеОтчета, "ДинамикаПродажКонтекст");
    ВариантыОтчетовУТПереопределяемый.ОтключитьВариантОтчета(Настройки, ОписаниеОтчета, "ПоНоменклатуреКонтекст");
    ВариантыОтчетовУТПереопределяемый.ОтключитьВариантОтчета(Настройки, ОписаниеОтчета, "ПродажиПоЗаказуКонтекст");
    
    // Настройка размещения, видимости по умолчанию, важности
    ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "ПродажиПоПартнерам");
    ОписаниеВарианта.Размещение.Удалить(Метаданные.Подсистемы.Продажи.Подсистемы.РозничныеПродажи);
    
    ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "ДинамикаПродаж");
    ОписаниеВарианта.Размещение.Очистить();
    ОписаниеВарианта.Размещение.Вставить(Метаданные.Подсистемы.Продажи.Подсистемы.АналитическаяОтчетность);
    ВариантыОтчетовУТПереопределяемый.УстановитьВажностьВариантаОтчета(ОписаниеВарианта, "Важный");
    ОписаниеВарианта.ФункциональныеОпции.Добавить("НеИспользоватьБизнесРегионы");
    
    ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "ДинамикаПродажБизнесРегионы");
    ОписаниеВарианта.Размещение.Очистить();
    ОписаниеВарианта.Размещение.Вставить(Метаданные.Подсистемы.Продажи.Подсистемы.АналитическаяОтчетность);
    ВариантыОтчетовУТПереопределяемый.УстановитьВажностьВариантаОтчета(ОписаниеВарианта, "Важный");
    ОписаниеВарианта.ФункциональныеОпции.Добавить("ИспользоватьБизнесРегионы");
    
    ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "ПродажиСводно");
    ОписаниеВарианта.Размещение.Удалить(Метаданные.Подсистемы.Продажи.Подсистемы.РозничныеПродажи);
    ВариантыОтчетовУТПереопределяемый.УстановитьВажностьВариантаОтчета(ОписаниеВарианта, "Важный");
    
    ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "ПродажиПоСделкам");
    ОписаниеВарианта.Размещение.Очистить();
    ОписаниеВарианта.Размещение.Вставить(Метаданные.Подсистемы.Продажи.Подсистемы.ПроведениеСделок);
    ОписаниеВарианта.ВидимостьПоУмолчанию = Ложь;
    ОписаниеВарианта.ФункциональныеОпции.Добавить("ИспользоватьСделкиСКлиентами");
    
    ОписаниеВарианта = ВариантыОтчетов.ОписаниеВарианта(Настройки, ОписаниеОтчета, "ПродажиПоПоставщикам");
    ОписаниеВарианта.Размещение.Удалить(Метаданные.Подсистемы.Продажи.Подсистемы.РозничныеПродажи);
    ОписаниеВарианта.ФункциональныеОпции.Добавить("ФормироватьВидыЗапасовПоПоставщикам");
    
КонецПроцедуры

// Конец СтандартныеПодсистемы.ВариантыОтчетов

// Методы расширения общей формы отчетов
//

// Вызывается в одноименном обработчике формы отчета после выполнения кода формы.
//
// Подробнее - см. ФормаОтчетаПереопределяемый.ПриСозданииНаСервере
//
Процедура ПриСозданииНаСервере(ЭтаФорма, Отказ, СтандартнаяОбработка) Экспорт
    // Дополнительные команды
    КомпоновщикНастроек = ЭтаФорма.Отчет.КомпоновщикНастроек;
    Параметры = ЭтаФорма.Параметры;
    
    Если Параметры.Свойство("РасширенныйОтбор") Тогда
        РасширенныйОтбор = КомпоновщикНастроек.ФиксированныеНастройки.Отбор.Элементы.Добавить(
            Тип("ЭлементОтбораКомпоновкиДанных"));
        РасширенныйОтбор.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Партнер");
        Если ТипЗнч(Параметры.РасширенныйОтбор) = Тип("Массив") Тогда
            ЭтоМассив = Истина;
            Если Параметры.РасширенныйОтбор.Количество() > 0 Тогда
                ПервыйЭлемент = Параметры.РасширенныйОтбор[0];
            Иначе
                ПервыйЭлемент = Неопределено;
            КонецЕсли;
        Иначе
            ЭтоМассив = Ложь;
            ПервыйЭлемент = Параметры.РасширенныйОтбор;
        КонецЕсли;
        Если ТипЗнч(ПервыйЭлемент) = Тип("СправочникСсылка.Партнеры") Тогда
            Если ЭтоМассив Тогда
                ЕстьПодчиненныеПартнеры = Ложь;
                Для Каждого ЭлементПараметраКоманды Из Параметры.РасширенныйОтбор Цикл
                    Если ПартнерыИКонтрагенты.ЕстьПодчиненныеПартнеры(ЭлементПараметраКоманды) Тогда
                        ЕстьПодчиненныеПартнеры = Истина;
                        Прервать;
                    КонецЕсли;
                КонецЦикла;
            Иначе
                ЕстьПодчиненныеПартнеры = ПартнерыИКонтрагенты.ЕстьПодчиненныеПартнеры(Параметры.РасширенныйОтбор);
            КонецЕсли;
            Если ЕстьПодчиненныеПартнеры И ЭтоМассив Тогда
                РасширенныйОтбор.ВидСравнения = ВидСравненияКомпоновкиДанных.ВСпискеПоИерархии;
            ИначеЕсли ЕстьПодчиненныеПартнеры Тогда
                РасширенныйОтбор.ВидСравнения = ВидСравненияКомпоновкиДанных.ВИерархии;
            ИначеЕсли ЭтоМассив Тогда
                РасширенныйОтбор.ВидСравнения = ВидСравненияКомпоновкиДанных.ВСписке;
            Иначе
                РасширенныйОтбор.ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
            КонецЕсли;
            РасширенныйОтбор.ПравоеЗначение = Параметры.РасширенныйОтбор;
        ИначеЕсли ТипЗнч(Параметры.РасширенныйОтбор) = Тип("СправочникСсылка.СегментыПартнеров") Тогда
            РасширенныйОтбор.ВидСравнения = ВидСравненияКомпоновкиДанных.ВСписке;
            РасширенныйОтбор.ПравоеЗначение = СегментыСервер.МассивЭлементов(
                ПервыйЭлемент);
        КонецЕсли;
        РасширенныйОтбор.Использование = Истина;
    КонецЕсли;
    
КонецПроцедуры

// Вызывается в одноименном обработчике формы отчета после выполнения кода формы.
//
// Подробнее - см. ФормаОтчетаПереопределяемый.ПередЗагрузкойВариантаНаСервере
//
Процедура ПередЗагрузкойВариантаНаСервере(ЭтаФорма, НовыеНастройкиКД) Экспорт
    Отчет = ЭтаФорма.Отчет;
    КомпоновщикНастроек = Отчет.КомпоновщикНастроек;
    
    КомпоновщикНастроек.Настройки.ДополнительныеСвойства.Вставить("КлючТекущегоВарианта", ЭтаФорма.КлючТекущегоВарианта);
    
    // Изменение настроек по функциональным опциям
    НастроитьПараметрыОтборыПоФункциональнымОпциям(КомпоновщикНастроек);
    
    НовыеНастройкиКД = КомпоновщикНастроек.Настройки;
КонецПроцедуры

// Вызывается в одноименном обработчике формы отчета после выполнения кода формы.
//
// Подробнее - см. ФормаОтчетаПереопределяемый.ПриЗагрузкеВариантаНаСервере
//
Процедура ПриЗагрузкеВариантаНаСервере(ЭтаФорма, НовыеНастройкиКД) Экспорт
    Отчет = ЭтаФорма.Отчет;
    Параметры = ЭтаФорма.Параметры;
    КомпоновщикНастроек = Отчет.КомпоновщикНастроек;
    
    Если Параметры.Свойство("Расшифровка") И Параметры.Расшифровка <> Неопределено
        И Параметры.Расшифровка.ПрименяемыеНастройки.ДополнительныеСвойства.Свойство("ФиксированныеНастройки") Тогда
        КомпоновщикНастроек.ЗагрузитьНастройки(Параметры.Расшифровка.ПрименяемыеНастройки);
    КонецЕсли;
    
    НовыеНастройкиКД = КомпоновщикНастроек.Настройки;
КонецПроцедуры

///////////////////////////////////////////////////////////////////////////////
// СЛУЖЕБНЫЕ ПРОЦЕДУРЫ И ФУНКЦИИ

Процедура НастроитьПараметрыОтборыПоФункциональнымОпциям(КомпоновщикНастроек) Экспорт
    
    Если ПолучитьФункциональнуюОпцию("ИспользоватьПартнеровКакКонтрагентов") Тогда
        КомпоновкаДанныхСервер.УдалитьЭлементОтбораИзВсехНастроекОтчета(КомпоновщикНастроек, "Контрагент");
    КонецЕсли;
    
    Если Не ПолучитьФункциональнуюОпцию("ИспользоватьНесколькоОрганизаций") Тогда
        КомпоновкаДанныхСервер.УдалитьЭлементОтбораИзВсехНастроекОтчета(КомпоновщикНастроек, "Организация");
    КонецЕсли;
    
    Если Не ПолучитьФункциональнуюОпцию("ИспользоватьНесколькоСкладов") Тогда
        КомпоновкаДанныхСервер.УдалитьЭлементОтбораИзВсехНастроекОтчета(КомпоновщикНастроек, "Склад");
    КонецЕсли;
    
КонецПроцедуры

// Конец СтандартныеПодсистемы.ВариантыОтчетов

#КонецЕсли