Как организовать отбор в форме выбора документа? УФ.

Всё намного проще на УФ.
Учитесь готовить кошек правильно.

- На форму кидаешь поле ввода(соответственно выстави правильный тип значения реквизита) например Реквизит "ОтборКлиент" с типом СправочникСсылка.Клиенты.
- Устанавливаешь обработчик ПриИзменении:

&НаКлиенте
Процедура ОтборКлиентПриИзменении(Элемент)
    РаботаСФормамиКлиент.ИзменитьЭлементОтбораСписка(Список, "Клиент", ОтборКлиент, ЗначениеЗаполнено(ОтборКлиент));
КонецПроцедуры

Содержимое самого клиентского модуля "РаботаСФормамиКлиент":

// ПРОЦЕДУРЫ И ФУНКЦИИ РАБОТЫ С ДИНАМИЧЕСКИМИ СПИСКАМИ

// Удаляет элемент отбора динамического списка
//
//Параметры:
//Список  - обрабатываемый динамический список,
//ИмяПоля - имя поля компоновки, отбор по которому нужно удалить
//
Процедура УдалитьЭлементОтбораСписка(Список, ИмяПоля) Экспорт

    ПолеКомпоновки = Новый ПолеКомпоновкиДанных(ИмяПоля);
    Счетчик = 1;
    Пока Счетчик <= Список.Отбор.Элементы.Количество() Цикл
        ЭлементОтбора = Список.Отбор.Элементы[Счетчик - 1];
        Если ТипЗнч(ЭлементОтбора) = Тип("ЭлементОтбораКомпоновкиДанных")
            И ЭлементОтбора.ЛевоеЗначение = ПолеКомпоновки Тогда
            Список.Отбор.Элементы.Удалить(ЭлементОтбора);
        Иначе
            Счетчик = Счетчик + 1;
        КонецЕсли;
    КонецЦикла;

КонецПроцедуры // УдалитьЭлементОтбораСписка()

// Устанавливает элемент отбор динамического списка
//
//Параметры:
//Список            - обрабатываемый динамический список,
//ИмяПоля            - имя поля компоновки, отбор по которому нужно установить,
//ВидСравнения        - вид сравнения отбора, по умолчанию - Равно,
//ПравоеЗначение     - значение отбора
//
Процедура УстановитьЭлементОтбораСписка(Список, ИмяПоля, ПравоеЗначение, ВидСравнения = Неопределено) Экспорт

    ЭлементОтбора = Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    ЭлементОтбора.ЛевоеЗначение    = Новый ПолеКомпоновкиДанных(ИмяПоля);
    ЭлементОтбора.ВидСравнения     = ?(ВидСравнения = Неопределено, ВидСравненияКомпоновкиДанных.Равно, ВидСравнения);
    ЭлементОтбора.Использование    = Истина;
    ЭлементОтбора.ПравоеЗначение   = ПравоеЗначение;
    ЭлементОтбора.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный;

КонецПроцедуры // УстановитьЭлементОтбораСписка()

// Изменяет элемент отбора динамического списка
//
//Параметры:
//Список         - обрабатываемый динамический список,
//ИмяПоля        - имя поля компоновки, отбор по которому нужно установить,
//ВидСравнения   - вид сравнения отбора, по умолчанию - Равно,
//ПравоеЗначение - значение отбора,
//Установить     - признак необходимости установить отбор
//
Процедура ИзменитьЭлементОтбораСписка(Список, ИмяПоля, ПравоеЗначение = Неопределено, Установить = Ложь, ВидСравнения = Неопределено, ОтборПоПериоду = Ложь) Экспорт

    УдалитьЭлементОтбораСписка(Список, ИмяПоля);

    Если Установить Тогда
        Если ОтборПоПериоду Тогда
            УстановитьЭлементОтбораСписка(Список, ИмяПоля, ПравоеЗначение.ДатаНачала, ВидСравненияКомпоновкиДанных.БольшеИлиРавно);
            УстановитьЭлементОтбораСписка(Список, ИмяПоля, ПравоеЗначение.ДатаОкончания, ВидСравненияКомпоновкиДанных.МеньшеИлиРавно);
        Иначе
            УстановитьЭлементОтбораСписка(Список, ИмяПоля, ПравоеЗначение, ВидСравнения);
        КонецЕсли;
    КонецЕсли;

КонецПроцедуры // ИзменитьЭлементОтбораСписка()

З.Ы. При желании, отблагодарить разрешаю пивом, территориально МСК :)