Есть регистр сведений с примерно 35К записей, его нужно экспортировать в эксель.
Делаю так:

Процедура ПриОткрытииНаСервере()
    имяФайла = "C:\excel-export-test.xlsx";
Попытка
    Попытка
        ExcelПриложение = Новый COMОбъект("Excel.Application");
    Исключение
        Сообщить("Ошибка при запуске Microsoft Excel."
        + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);
        Возврат;
    КонецПопытки;
    Книга = ExcelПриложение.WorkBooks.Add();
    Лист = Книга.WorkSheets(1);
    
    Лист.Cells(1, 1).Value = "Заголовок 1";
//     ...
    Лист.Cells(1, 49).Value = "Заголовок 49";

    Выборка = РегистрыСведений.Данные.Выбрать();
    Счетчик = 2;
    Пока Выборка.Следующий() Цикл
        ТекущаяСтрока = Выборка.ПолучитьМенеджерЗаписи();
        Лист.Cells(Счетчик, 1).Value = ТекущаяСтрока.Поле1;
        Лист.Cells(Счетчик, 2).Value = ТекущаяСтрока.Поле2;
        Лист.Cells(Счетчик, 3).Value = ТекущаяСтрока.Поле3;
        Лист.Cells(Счетчик, 4).Value = ТекущаяСтрока.Поле4;
        Лист.Cells(Счетчик, 5).Value = ТекущаяСтрока.Поле5;
        Лист.Cells(Счетчик, 13).Value = ТекущаяСтрока.Поле13;
        Лист.Cells(Счетчик, 14).Value = ТекущаяСтрока.Поле14;
        Лист.Cells(Счетчик, 20).Value = ТекущаяСтрока.Поле20;
        Лист.Cells(Счетчик, 29).Value = ТекущаяСтрока.Поле29;
        
        Счетчик = Счетчик + 1;
    КонецЦикла;

    Книга.SaveAs(имяФайла);
    ExcelПриложение.Quit();
    Сообщить("Файл выгружен успешно: " + имяФайла );
Исключение
    Сообщить("Ошибка записи данных файла :" + имяФайла);
    Сообщить(ОписаниеОшибки());
    Попытка
        ExcelПриложение.Quit();
    Исключение
    КонецПопытки;
КонецПопытки;
КонецПроцедуры


Обработка выполняется полтора часа. Вот так выглядит замер производительности http://i.imgur.com/6wrs2yh.png
Видно что почти все время уходит на запись значений в ячейки. При этом тип содержимого (там есть и числа и даты и строки) на скорость почти никак не влияет.

На мой взгляд полтора часа это как-то дофига, учитывая что никаких расчетов не происходит, просто запись в файл, при том что итоговый экселевский файл весит примерно 2 мегабайта. Или это нормально? Если нет, то куда копать?

а вывести список не пробовал?

(0) А табличный документ тоже сохраняет долго?

> ТекущаяСтрока = Выборка.ПолучитьМенеджерЗаписи();
бохмой

(3) Да уж...

банан долбобей нервно курит :)

да какой дивный регистр. так и вспоминаются ресурсы у одного РН (остатки обуви): Размер40, Размер42...

и полтора часа висит при открытии? а мне нравится

А кода "Счетчик" заканчивает считать?

(7) Да это видать компания Штирлиц...
зато название РС какое "Данные" :)))

(8) на 94й минуте матча

+(9) поле. русское поооле...

Да и исчо это фсио на сервере....

Началась, дискотека

ну ладно, поправим автора ;)
Видно что почти все время уходит на чтение значений

(14) Замер смотрел?

(0) Автор, а чё запросом-то через табличный документ низьзя никак?

(15) даже не поленился
http://i.imgur.com/6wrs2yh.png

(15) посмотрел и замер :)

Все время уходит на вывод в ячейку Excel.
Не используйте Excel через COM

(19) Откуда ты знаешь? Может на чтение записи :)

(17) ну ты зверюга ))))

Делаю ставку, что тормозит обращение к OLE-объектам Excel. Но и чтение из БД сделано отвратительно.
Почему бы не сделать отчёт,а потом его сохранить в Excel? Тем более что формат 2007 уже встроен в платформу и нет проблемы с 65500 строк на листе.

(3) И что? Надо было запросом? А смысл? Тормозит не в этом месте.

(8) Заканчивает когда заканчиваются записи. Не понял вопрос. Да и проблема явно не в этом.

(16) Попробую.

(19) А как его использовать?

Для особо умных трололо:
1) Названия полей я естественно поменял, на самом деле они называются по-другому.
2) РС таки называется "Данные". Не поверите, но бывают ситуации в которых это действительно самое подходящее и удобное название.

Вариантов много разных. Например, можно всё загнать в текст, скопировать текст в буфер обмена и вставить в Excel из буфера.

((19)(22)(23) ПолучитьМенеджерЗаписи
"Предназначен для интерактивной работы с записью регистра сведений."

(23) пиши нормальный код и все будет быстро

(23) см (17)
тебе показали, где тормозит.

Запороцем само быстро вроде, ADOX.Catalog

(23) Используй правильно:

МассивДанных=Новый COMSafeArray("VT_VARIANT",КоличествоСтрок-1,КоличествоСтолбцов-1);
Для СчетчикСтрок=0 По КоличествоСтрок-1 Цикл
    МассивДанных.SetValue(СчетчикСтрок,0,ТекущаяСтрока.Идентификатор);
    МассивДанных.SetValue(СчетчикСтрок,1,ТекущаяСтрока.Цена);
    //и.т.д, все колонки
КонецЦикла;

ВерхняяЛеваяЯчейка= WorkBook.WorkSheets[1].Cells[НачальнаяСтрока, НачальнаяКолонка];
НижняяПраваяЯчейка= WorkBook.WorkSheets[1].Cells[НачальнаяСтрока+КоличествоСтрок-1, НачальнаяКолонка+КоличествоСтолбцов-1];
Область= WorkBook.WorkSheets[1].Range[ВерхняяЛеваяЯчейка, НижняяПраваяЯчейка];
Область.Value= МассивДанных;

(25) Доступность: Сервер, толстый клиент, внешнее соединение.
Тонкого клиента в списке нет, странная интерактивность.

В (17) показали , что затык на Лист.Cells(х, у).Value, это минимум 3 обращения к внепроцессному COM-серверу, с маршалингом и всеми прелестями OLE.

Ну и данные, естественно - запросом, чтобы знать число строк.

(30) ну я с СП спорить точно не буду

(29) (31) Огромное спасибо! С использованием COMSafeArray время экспорта удалось уменьшить до 32 секунд :) http://i.imgur.com/y4Mv6FA.png

Вот какой код получился в итоге:

Процедура ПриОткрытииНаСервере()
    имяФайла = "C:\excel-export-test.xlsx";
Попытка
    Попытка
        ExcelПриложение = Новый COMОбъект("Excel.Application");
    Исключение
        Сообщить("Ошибка при запуске Microsoft Excel."
        + Символы.ПС + ОписаниеОшибки(), СтатусСообщения.Внимание);
        Возврат;
    КонецПопытки;
    Книга = ExcelПриложение.WorkBooks.Add();
    Лист = Книга.WorkSheets(1);
    
    Лист.Cells(1, 1).Value = "Заголовок 1";
//     ...
    Лист.Cells(1, 49).Value = "Заголовок 49";

    Запрос = Новый Запрос("ВЫБРАТЬ
        |    ....
        |    ИЗ РегистрСведений.Данные");
    Выборка = Запрос.Выполнить().Выбрать();
    КоличествоСтрок = Выборка.Количество();
    КоличествоСтолбцов = 50;

    МассивДанных = Новый COMSafeArray("VT_VARIANT",КоличествоСтолбцов-1, КоличествоСтрок);
    Счетчик = 0;
    Пока Выборка.Следующий() Цикл

        МассивДанных.SetValue(0, Счетчик, Выборка.Поле1);
        МассивДанных.SetValue(1, Счетчик, Выборка.Поле2);
        МассивДанных.SetValue(2, Счетчик, Выборка.Поле3);
        МассивДанных.SetValue(3, Счетчик, Выборка.Поле4);
        МассивДанных.SetValue(4, Счетчик, Выборка.Поле5);
        МассивДанных.SetValue(12, Счетчик, Выборка.Поле6);
        МассивДанных.SetValue(13, Счетчик, Выборка.Поле7);
        МассивДанных.SetValue(19, Счетчик, Выборка.Поле8);
        МассивДанных.SetValue(28, Счетчик, Выборка.Поле9);

        Счетчик = Счетчик + 1;
    КонецЦикла;
    Область = Лист.Range(Лист.Cells(2, 1), Лист.Cells(КоличествоСтрок+1, КоличествоСтолбцов-1));
    Область.Value = МассивДанных;

    ExcelПриложение.DisplayAlerts = False;
    Книга.SaveAs(имяФайла);
    ExcelПриложение.Quit();
    Сообщить("Файл выгружен успешно: " + имяФайла);
Исключение
    Сообщить("Ошибка записи данных файла :" + имяФайла);
    Сообщить(ОписаниеОшибки());
    Попытка
        ExcelПриложение.Quit();
    Исключение
    КонецПопытки;
КонецПопытки;
КонецПроцедуры