Дополнительная нумерация в документе

Перем ДатаЛиста;

    Если НЕ ПроверкаПериода() Тогда
        Возврат;
    КонецЕсли;

    Если Организация.Пустая() Тогда
        Сообщить("Не выбрана организация.");
        Возврат;
    КонецЕсли;

    // {ОбособленныеПодразделения
    Если ФормироватьПоПодразделению И НЕ ЗначениеЗаполнено(ПодразделениеОрганизации) Тогда
        Сообщить("Не выбрано подразделение.");
        Возврат;
    ИначеЕсли НЕ ФормироватьПоПодразделению И ЗначениеЗаполнено(ПодразделениеОрганизации) Тогда
        Сообщить("При снятом флажке ""Подразделение"" подразделение должно быть очищено.");
        Возврат;
    КонецЕсли;
    // }ОбособленныеПодразделения

    ДокументРезультат.Очистить();
    ДокументРезультат.ИмяПараметровПечати = "ПАРАМЕТРЫ_ПЕЧАТИ_КассоваяКнига";

    НачалоГода = НачалоГода(ДатаНач);

    // расчет номера начального листа
    // осуществляется по проводкам так как не все операции по
    // кассе оформляются приходными/расходными ордерами

    ЛистовЗаГод   = 0;
    ЛистовЗаМесяц = 0;

    Попытка //для случая, когда к организации нет доступа
        Если ПересчитатьНомера Тогда

            Запрос = Новый Запрос;
            Запрос.УстановитьПараметр("Организация",    Организация);
            Запрос.УстановитьПараметр("ПлатежныйАгент", ПлатежныйАгент);
            Запрос.УстановитьПараметр("НачалоГода",     НачалоГода);
            // {ОбособленныеПодразделения
            Запрос.УстановитьПараметр("Подразделение", ПодразделениеОрганизации);
            // }ОбособленныеПодразделения
            ТекстЗапроса =
            "ВЫБРАТЬ
            |    НомераЛистовКассовойКниги.Период,
            |    НомераЛистовКассовойКниги.Организация,
            // {ОбособленныеПодразделения
            |    НомераЛистовКассовойКниги.ПодразделениеОрганизации,
            // }ОбособленныеПодразделения
            |    НомераЛистовКассовойКниги.ПлатежныйАгент,
            |    НомераЛистовКассовойКниги.НомерЛиста
            |ИЗ
            |    РегистрСведений.НомераЛистовКассовойКниги КАК НомераЛистовКассовойКниги
            |ГДЕ
            |    НомераЛистовКассовойКниги.Период >= &НачалоГода
            |    И НомераЛистовКассовойКниги.Организация = &Организация
            // {ОбособленныеПодразделения
            |    И НомераЛистовКассовойКниги.ПодразделениеОрганизации = &Подразделение
            // }ОбособленныеПодразделения
            |    И НомераЛистовКассовойКниги.ПлатежныйАгент = &ПлатежныйАгент";

            Запрос.Текст = ТекстЗапроса;
            Выборка = Запрос.Выполнить().Выбрать();

            Пока Выборка.Следующий() Цикл
                Менеджер = РегистрыСведений.НомераЛистовКассовойКниги.СоздатьМенеджерЗаписи();
                ЗаполнитьЗначенияСвойств(Менеджер, Выборка);
                Менеджер.Удалить();
            КонецЦикла;

        Иначе

            Если ДатаНач <> НачалоГода Тогда

                Отбор = Новый Структура();
                Отбор.Вставить("Организация",    Организация);
                Отбор.Вставить("ПлатежныйАгент", ПлатежныйАгент);
                // {ОбособленныеПодразделения
                Отбор.Вставить("ПодразделениеОрганизации", ПодразделениеОрганизации);
                // }ОбособленныеПодразделения
                Номера = РегистрыСведений.НомераЛистовКассовойКниги.СрезПоследних(ДатаНач - 86400, Отбор);

                Если (Номера.Количество() > 0) И (Номера[0].Период >= НачалоГода) Тогда

                    ЛистовЗаГод = Номера[0].НомерЛиста;

                    ЛистовЗаПредыдущиеМесяцы = 0;
                    НомераПредМесяцев = РегистрыСведений.НомераЛистовКассовойКниги.СрезПоследних(НачалоМесяца(ДатаНач) - 86400, Отбор);
                    Если (НомераПредМесяцев.Количество() > 0) И (НомераПредМесяцев[0].Период >= НачалоГода) Тогда
                        ЛистовЗаПредыдущиеМесяцы = НомераПредМесяцев[0].НомерЛиста;
                    КонецЕсли;

                    ЛистовЗаМесяц = ЛистовЗаГод - ЛистовЗаПредыдущиеМесяцы;

                КонецЕсли;

            КонецЕсли;

        КонецЕсли;
    Исключение
        //Эта ветка сработает при выборе организации на которю нет прав
        Предупреждение(НСтр("ru = 'Нарушение прав доступа!'"));
        Возврат;
    КонецПопытки;

    // Инициируем области отчета

    Макет = ПолучитьМакет("КассоваяКнига");

    //////////////////////////////////////////////////////////////////////////////////////////

    ОбластьВалОстатокОтчет                 = Макет.ПолучитьОбласть("ВалОстаток|Отчет");
    ОбластьПодвалОтчет                     = Макет.ПолучитьОбласть("Подвал|Отчет");
    ОбластьВТомЧислеОтчет                 = Макет.ПолучитьОбласть("ВТомЧисле|Отчет");
    ОбластьОстатокОтчет                 = Макет.ПолучитьОбласть("Остаток|Отчет");
    ОбластьЛистовЗаМесяцОтчет             = Макет.ПолучитьОбласть("ЛистовЗаМесяц|Отчет");
    ОбластьЛистовЗаГодОтчет             = Макет.ПолучитьОбласть("ЛистовЗаГод|Отчет");
    ОбластьВкладнойЛистОтчет             = Макет.ПолучитьОбласть("ВкладнойЛист|Отчет");
    ОбластьВкладнойЛист373ПОтчет        = Макет.ПолучитьОбласть("ВкладнойЛист373П|Отчет");
    ОбластьОтчетКассираОтчет             = Макет.ПолучитьОбласть("ОтчетКассира|Отчет");
    ОбластьОтчетКассира373ПОтчет        = Макет.ПолучитьОбласть("ОтчетКассира373П|Отчет");
    ОбластьШапкаОтчет                     = Макет.ПолучитьОбласть("Шапка|Отчет");
    ОбластьОстатокНаНДОтчет             = Макет.ПолучитьОбласть("ОстатокНаНД|Отчет");
    ОбластьКурсовыеРазницыОтчет         = Макет.ПолучитьОбласть("КурсовыеРазницы|Отчет");
    ОбластьКурсовыеРазницыПоВалютеОтчет = Макет.ПолучитьОбласть("КурсовыеРазницыПоВалюте|Отчет");
    ОбластьПереносОтчет                 = Макет.ПолучитьОбласть("Перенос|Отчет");
    ОбластьСтрокаВалШирокаяОтчет         = Макет.ПолучитьОбласть("СтрокаВалШирокая|Отчет");
    ОбластьСтрокаВалОтчет                 = Макет.ПолучитьОбласть("СтрокаВал|Отчет");
    ОбластьСтрокаШирокаяОтчет             = Макет.ПолучитьОбласть("СтрокаШирокая|Отчет");
    ОбластьСтрокаОтчет                     = Макет.ПолучитьОбласть("Строка|Отчет");
    ОбластьОборотОтчет                     = Макет.ПолучитьОбласть("Оборот|Отчет");
    ОбластьОборотРубОтчет                 = Макет.ПолучитьОбласть("ОборотРуб|Отчет");
    ОбластьОборотВалОтчет                 = Макет.ПолучитьОбласть("ОборотВал|Отчет");
    ОбластьКурсоваяРазницаОтчет         = Макет.ПолучитьОбласть("КурсоваяРазница|Отчет");
    ОбластьКурсоваяРазницаПоВалютеОтчет = Макет.ПолучитьОбласть("КурсоваяРазницаПоВалюте|Отчет");
    ОбластьКонечныйОстатокОтчет         = Макет.ПолучитьОбласть("КонечныйОстаток|Отчет");

    ////////////////////////////////////////////////////////////////////////////////////////////////

    НачИтоги = ?(ПересчитатьНомера,НачалоГода,ДатаНач);

    МассивСчетов = Новый Массив;
    Если ПлатежныйАгент Тогда
        МассивСчетов.Добавить(ПланыСчетов.Хозрасчетный.КассаПлатежногоАгента);
    Иначе
        МассивСчетов.Добавить(ПланыСчетов.Хозрасчетный.КассаОрганизации);
        МассивСчетов.Добавить(ПланыСчетов.Хозрасчетный.КассаОрганизацииВал);
    КонецЕсли;

    ЗапросПоИтогам = Новый Запрос;
    ЗапросПоИтогам.Текст =
    "ВЫБРАТЬ РАЗРЕШЕННЫЕ
    |    ХозрасчетныйОстаткиИОбороты.Период КАК Период,
    |    ХозрасчетныйОстаткиИОбороты.Валюта КАК Валюта,
    |    ХозрасчетныйОстаткиИОбороты.СуммаНачальныйОстатокДт КАК СуммаНачальныйОстатокДт,
    |    ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаНачальныйОстатокДт КАК ВалютнаяСуммаНачальныйОстатокДт,
    |    ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокДт КАК СуммаКонечныйОстатокДт,
    |    ХозрасчетныйОстаткиИОбороты.ВалютнаяСуммаКонечныйОстатокДт КАК ВалютнаяСуммаКонечныйОстатокДт,
    |    ХозрасчетныйОстаткиИОбороты.СуммаОборотДт КАК СуммаОборотДт,
    |    ХозрасчетныйОстаткиИОбороты.СуммаОборотКт КАК СуммаОборотКт
    |ИЗ
    |    РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(
    |            &НачИтоги,
    |            &ДатаКон,
    |            ДЕНЬ,
    |            ДвиженияИГраницыПериода,
    |            Счет В ИЕРАРХИИ (&МассивСчетов),
    |            ,
    |            Организация = &Организация
    // {ОбособленныеПодразделения
    |                И ((НЕ &ФормироватьПоПодразделению) ИЛИ Подразделение = &ПодразделениеОрганизации)
    // }ОбособленныеПодразделения
    |                    ) КАК ХозрасчетныйОстаткиИОбороты
    |
    |УПОРЯДОЧИТЬ ПО
    |    Период
    |ИТОГИ
    |    СУММА(СуммаНачальныйОстатокДт),
    |    СУММА(ВалютнаяСуммаНачальныйОстатокДт),
    |    СУММА(СуммаКонечныйОстатокДт),
    |    СУММА(ВалютнаяСуммаКонечныйОстатокДт),
    |    СУММА(СуммаОборотДт),
    |    СУММА(СуммаОборотКт)
    |ПО
    |    ОБЩИЕ,
    |    Период ПЕРИОДАМИ(ДЕНЬ, , ),
    |    Валюта
    |АВТОУПОРЯДОЧИВАНИЕ";

    ЗапросПоИтогам.УстановитьПараметр("НачИтоги",     НачалоДня(НачИтоги));
    ЗапросПоИтогам.УстановитьПараметр("ДатаКон",      КонецДня(ДатаКон));
    ЗапросПоИтогам.УстановитьПараметр("Организация",  Организация);
    ЗапросПоИтогам.УстановитьПараметр("МассивСчетов", МассивСчетов);
    // {ОбособленныеПодразделения
    ЗапросПоИтогам.УстановитьПараметр("ПодразделениеОрганизации",   ПодразделениеОрганизации);
    ЗапросПоИтогам.УстановитьПараметр("ФормироватьПоПодразделению", ФормироватьПоПодразделению);
    // }ОбособленныеПодразделения
    РезультатЗапросаПоИтогам = ЗапросПоИтогам.Выполнить();

    ЗапросПоДокументам = Новый Запрос;
    ЗапросПоДокументам.Текст=
    "ВЫБРАТЬ РАЗРЕШЕННЫЕ
    |    КассовыеДокументы.Документ КАК Документ,
    |    НАЧАЛОПЕРИОДА(КассовыеДокументы.Документ.Дата, ДЕНЬ) КАК День,
    |    КассовыеДокументы.Документ.Дата КАК ДатаДок,
    |    КассовыеДокументы.Документ.Номер КАК НомерДок,
    |    КассовыеДокументы.Документ.ВалютаДокумента КАК Валюта,
    |    ПОДСТРОКА(КассовыеДокументы.Документ.Основание, 1, 200) КАК Основание,
    |    ВЫБОР
    |        КОГДА КассовыеДокументы.Документ ССЫЛКА Документ.ПриходныйКассовыйОрдер
    |            ТОГДА КассовыеДокументы.Документ.ПринятоОт
    |        ИНАЧЕ КассовыеДокументы.Документ.Выдать
    |    КОНЕЦ КАК ТекстДок,
    |    ВЫБОР
    |        КОГДА КассовыеДокументы.Документ ССЫЛКА Документ.ПриходныйКассовыйОрдер
    |            ТОГДА КассовыеДокументы.Документ.СуммаДокумента
    |        ИНАЧЕ 0
    |    КОНЕЦ КАК Приход,
    |    ВЫБОР
    |        КОГДА КассовыеДокументы.Документ ССЫЛКА Документ.РасходныйКассовыйОрдер
    |            ТОГДА КассовыеДокументы.Документ.СуммаДокумента
    |        ИНАЧЕ 0
    |    КОНЕЦ КАК Расход,
    |    ВЫБОР
    |        КОГДА КассовыеДокументы.Документ ССЫЛКА Документ.РасходныйКассовыйОрдер
    |            ТОГДА Проводки.СчетДт
    |        ИНАЧЕ ВЫБОР
    |                КОГДА КассовыеДокументы.Документ.ВидОперации = &ОперацияПриемРозничнойВыручки
    |                    ТОГДА КассовыеДокументы.Документ.СчетУчетаРасчетовСКонтрагентом
    |                ИНАЧЕ Проводки.СчетКт
    |            КОНЕЦ
    |    КОНЕЦ КАК Счет
    |ИЗ
    |    (ВЫБРАТЬ
    |        ПриходныйКассовыйОрдер.Ссылка КАК Документ
    |    ИЗ
    |        Документ.ПриходныйКассовыйОрдер КАК ПриходныйКассовыйОрдер
    |    ГДЕ
    |        ПриходныйКассовыйОрдер.ПометкаУдаления = ЛОЖЬ
    |        И ПриходныйКассовыйОрдер.Дата МЕЖДУ &НачИтоги И &ДатаКон
    |        И ПриходныйКассовыйОрдер.Организация = &Организация
    // {ОбособленныеПодразделения
    |        И ((НЕ &ФормироватьПоПодразделению)
    |                ИЛИ ПриходныйКассовыйОрдер.ПодразделениеОрганизации = &ПодразделениеОрганизации)
    // }ОбособленныеПодразделения
    |        И ПриходныйКассовыйОрдер.СчетКасса В ИЕРАРХИИ(&Счет)
    |        И ПриходныйКассовыйОрдер.Проведен
    |        И ПриходныйКассовыйОрдер.ПометкаУдаления = ЛОЖЬ
    |
    |    ОБЪЕДИНИТЬ ВСЕ
    |
    |    ВЫБРАТЬ
    |        РасходныйКассовыйОрдер.Ссылка
    |    ИЗ
    |        Документ.РасходныйКассовыйОрдер КАК РасходныйКассовыйОрдер
    |    ГДЕ
    |        РасходныйКассовыйОрдер.Дата МЕЖДУ &НачИтоги И &ДатаКон
    |        И РасходныйКассовыйОрдер.Организация = &Организация
    // {ОбособленныеПодразделения
    |        И ((НЕ &ФормироватьПоПодразделению)
    |                ИЛИ РасходныйКассовыйОрдер.ПодразделениеОрганизации = &ПодразделениеОрганизации)
    // }ОбособленныеПодразделения
    |        И РасходныйКассовыйОрдер.СчетКасса В ИЕРАРХИИ(&Счет)
    |        И РасходныйКассовыйОрдер.Проведен
    |        И РасходныйКассовыйОрдер.ПометкаУдаления = ЛОЖЬ) КАК КассовыеДокументы
    |        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
    |            Хозрасчетный.СчетДт КАК СчетДт,
    |            Хозрасчетный.СчетКт КАК СчетКт,
    |            Хозрасчетный.Регистратор КАК Регистратор
    |        ИЗ
    |            РегистрБухгалтерии.Хозрасчетный КАК Хозрасчетный
    |        ГДЕ
    |            (Хозрасчетный.СчетДт В ИЕРАРХИИ (&Счет)
    |                        И ((НЕ Хозрасчетный.СчетДт.Валютный)
    |                            ИЛИ Хозрасчетный.ВалютнаяСуммаДт <> 0)
    // {ОбособленныеПодразделения
    |                        И ((НЕ &ФормироватьПоПодразделению)
    |                            ИЛИ Хозрасчетный.ПодразделениеДт = &ПодразделениеОрганизации)
    // }ОбособленныеПодразделения
    |                    ИЛИ Хозрасчетный.СчетКт В ИЕРАРХИИ (&Счет)
    |                        И ((НЕ Хозрасчетный.СчетКт.Валютный)
    |                            ИЛИ Хозрасчетный.ВалютнаяСуммаКт <> 0)
    // {ОбособленныеПодразделения
    |                        И ((НЕ &ФормироватьПоПодразделению)
    |                            ИЛИ Хозрасчетный.ПодразделениеКт = &ПодразделениеОрганизации)
    // }ОбособленныеПодразделения
    |                        И (Хозрасчетный.Период МЕЖДУ &НачИтоги И &ДатаКон)
    |                        И Хозрасчетный.Организация = &Организация
    |                        И Хозрасчетный.Активность = ИСТИНА)) КАК Проводки
    |        ПО КассовыеДокументы.Документ = Проводки.Регистратор
    |
    |УПОРЯДОЧИТЬ ПО
    |    День,
    |    ДатаДок,
    |    Документ
    |ИТОГИ ПО
    |    День,
    |    Документ,
    |    Счет
    |АВТОУПОРЯДОЧИВАНИЕ";

    ЗапросПоДокументам.УстановитьПараметр("НачИтоги",    НачалоДня(НачИтоги));
    ЗапросПоДокументам.УстановитьПараметр("ДатаКон",     КонецДня(ДатаКон));
    ЗапросПоДокументам.УстановитьПараметр("Организация", Организация);
    ЗапросПоДокументам.УстановитьПараметр("Счет",        МассивСчетов);
    // {ОбособленныеПодразделения
    ЗапросПоДокументам.УстановитьПараметр("ПодразделениеОрганизации",      ПодразделениеОрганизации);
    ЗапросПоДокументам.УстановитьПараметр("ФормироватьПоПодразделению",    ФормироватьПоПодразделению);
    // }ОбособленныеПодразделения
    ЗапросПоДокументам.УстановитьПараметр("ОперацияПриемРозничнойВыручки", Перечисления.ВидыОперацийПКО.РозничнаяВыручка);

    РезультатЗапросаПоДокументам = ЗапросПоДокументам.Выполнить();

    ТаблицаДокументы = РезультатЗапросаПоДокументам.Выгрузить();
    ТаблицаДокументы.Очистить();
    ТаблицаДокументы.Колонки.Добавить("СтрокаСчет");
    ТаблицаДокументы.Колонки.Добавить("Валютный");
    ТаблицаДокументы.Колонки.Добавить("ВидДокумента");

    ТипЧисло=ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(15,2);

    РабочаяТаблица = Новый ТаблицаЗначений;
    РабочаяТаблица.Колонки.Добавить("Валюта",Новый ОписаниеТипов("СправочникСсылка.Валюты"));
    РабочаяТаблица.Колонки.Добавить("ВалютаПредставление", ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(100));
    РабочаяТаблица.Колонки.Добавить("ВалОстаток",ТипЧисло);
    РабочаяТаблица.Колонки.Добавить("Остаток",ТипЧисло);
    РабочаяТаблица.Колонки.Добавить("ВалПриход",ТипЧисло);
    РабочаяТаблица.Колонки.Добавить("Приход",ТипЧисло);
    РабочаяТаблица.Колонки.Добавить("ВалРасход",ТипЧисло);
    РабочаяТаблица.Колонки.Добавить("Расход",ТипЧисло);
    РабочаяТаблица.Индексы.Добавить("Валюта");

    ВыборкаПоВалюте = РезультатЗапросаПоИтогам.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"Валюта");

    Пока ВыборкаПоВалюте.Следующий() Цикл
        Если НЕ ВыборкаПоВалюте.Валюта = Справочники.Валюты.ПустаяСсылка() Тогда
            Строка            = РабочаяТаблица.Добавить();
            Строка.Валюта     = ВыборкаПоВалюте.Валюта;
            Строка.ВалютаПредставление = Строка(ВыборкаПоВалюте.Валюта);
            Строка.Остаток    = ВыборкаПоВалюте.СуммаНачальныйОстатокДт;
            Строка.ВалОстаток = ВыборкаПоВалюте.ВалютнаяСуммаНачальныйОстатокДт;
        КонецЕсли;
    КонецЦикла;

    ВыборкаОбщихИтогов = РезультатЗапросаПоИтогам.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"Общие");

    Строка        = РабочаяТаблица.Добавить();
    Строка.Валюта = Справочники.Валюты.ПустаяСсылка();

    Если ВыборкаОбщихИтогов.Следующий() Тогда

        Строка.Остаток    = ВыборкаОбщихИтогов["СуммаНачальныйОстатокДт"]-РабочаяТаблица.Итог("Остаток");
        Строка.ВалОстаток = ВыборкаОбщихИтогов["ВалютнаяСуммаНачальныйОстатокДт"]-РабочаяТаблица.Итог("ВалОстаток");

    Иначе

        Строка.Остаток    = 0;
        Строка.ВалОстаток = 0;

    КонецЕсли;

    РабочаяТаблица.Сортировать("ВалютаПредставление");

    // Определяем последние дни месяцев за которые формируется кассовая книга

    СписокДней = Новый СписокЗначений;

    ВыборкаИтоговПоДням = РезультатЗапросаПоИтогам.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"Период");
    Пока ВыборкаИтоговПоДням.Следующий() Цикл
        СписокДней.Добавить(ВыборкаИтоговПоДням.Период);
    КонецЦикла;
    ВыборкаДокументовПоДням = РезультатЗапросаПоДокументам.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"День");
    Пока ВыборкаДокументовПоДням.Следующий() Цикл
        СписокДней.Добавить(ВыборкаДокументовПоДням.День);
    КонецЦикла;
    СписокДней.СортироватьПоЗначению();

    МассивПоследнихДней = Новый Массив;
    Для й = 2 По СписокДней.Количество() Цикл
        Если НачалоМесяца(СписокДней[й - 2].Значение) <> НачалоМесяца(СписокДней[й - 1].Значение) Тогда
            МассивПоследнихДней.Добавить(СписокДней[й - 2].Значение);
        КонецЕсли;
    КонецЦикла;

    // Формирование листов кассовой книги

    ВыборкаИтоговПоДням     = РезультатЗапросаПоИтогам.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"Период");
    ВыборкаДокументовПоДням = РезультатЗапросаПоДокументам.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам,"День");

    ПоПроводкам  = ВыборкаИтоговПоДням.Следующий();
    ПоДокументам = ВыборкаДокументовПоДням.Следующий();

    БылиОшибки    = Ложь;
    ВывестиПодвал = Ложь;

    СведенияОбОрганизации = УправлениеКонтактнойИнформацией.СведенияОЮрФизЛице(Организация, КонецДня(ДатаКон));

    ДатаДействияПриказа373П = '20120101';
    ТипПКО = Тип("ДокументСсылка.ПриходныйКассовыйОрдер");
    ТипРКО = Тип("ДокументСсылка.РасходныйКассовыйОрдер");

    Пока ПоПроводкам Или ПоДокументам  Цикл
        Если НЕ ПоПроводкам  Тогда
            ДатаЛиста = ВыборкаДокументовПоДням.День;
        ИначеЕсли НЕ ПоДокументам Тогда
            ДатаЛиста = ВыборкаИтоговПоДням.Период;
        Иначе
            ДатаЛиста = Мин(ВыборкаДокументовПоДням.День, ВыборкаИтоговПоДням.Период);
        КонецЕсли;
        Если ВыборкаИтоговПоДням.СуммаОборотДт = 0 И ВыборкаИтоговПоДням.СуммаОборотКт = 0 Тогда
            Если НЕ ПоДокументам ИЛИ ДатаЛиста <> ВыборкаДокументовПоДням.День Тогда
                ПоПроводкам = ВыборкаИтоговПоДням.Следующий();
                Продолжить;
            КонецЕсли;
        КонецЕсли;
        НомерЛиста = ЛистовЗаГод + 1;
        ЛистовЗаГод = ЛистовЗаГод + 1;
        ЛистовЗаМесяц = ЛистовЗаМесяц + 1;

        КоличествоПриходныхДокументов = 0;
        КоличествоРасходныхДокументов = 0;

        СчетКурсовыхРазниц = ПланыСчетов.Хозрасчетный.ПрочиеДоходыИРасходы;
        Остаток = РабочаяТаблица.Итог("Остаток");
        Если ДатаЛиста >= ДатаНач Тогда

            ЗаголовокЛиста = "  КАССА за " + Формат(ДатаЛиста, "ДФ=dd.MM.yyyy");
            НомерЛистаСтр  = "Лист " + НомерЛиста;
            Если ДатаЛиста < ДатаДействияПриказа373П Тогда
                ОбластьВкладнойЛистОтчет.Параметры.ЗаголовокЛиста = ЗаголовокЛиста;
                ДокументРезультат.Вывести(ОбластьВкладнойЛистОтчет);
                ОбластьОтчетКассираОтчет.Параметры.ЗаголовокЛиста = ЗаголовокЛиста;
                ДокументРезультат.Присоединить(ОбластьОтчетКассираОтчет);
                ОбластьШапкаОтчет.Параметры.ТекстНомерЛиста = НомерЛистаСтр;
            Иначе
                ЗаголовокЛиста = "  КАССА за " + Формат(ДатаЛиста, "ДЛФ=DD");
                ОбластьВкладнойЛист373ПОтчет.Параметры.ЗаголовокЛиста  = ЗаголовокЛиста;
                ОбластьОтчетКассира373ПОтчет.Параметры.ЗаголовокЛиста  = ЗаголовокЛиста;
                ОбластьВкладнойЛист373ПОтчет.Параметры.ТекстНомерЛиста = НомерЛистаСтр;
                ОбластьОтчетКассира373ПОтчет.Параметры.ТекстНомерЛиста = НомерЛистаСтр;
                ДокументРезультат.Вывести(ОбластьВкладнойЛист373ПОтчет);
                ДокументРезультат.Присоединить(ОбластьОтчетКассира373ПОтчет);
                ОбластьШапкаОтчет.Параметры.ТекстПлатежныйАгент = "";
                ОбластьШапкаОтчет.Параметры.ТекстНомерЛиста     = "";
            КонецЕсли;

            Если ПлатежныйАгент Тогда
                ОбластьШапкаОтчет.Параметры.ТекстПлатежныйАгент = "По деятельности платежного агента";
            КонецЕсли;

            ДокументРезультат.Вывести(ОбластьШапкаОтчет);
            ДокументРезультат.Присоединить(ОбластьШапкаОтчет);

            ОбластьОстатокНаНДОтчет.Параметры.ОстатокНачало=Остаток;
            ДокументРезультат.Вывести(ОбластьОстатокНаНДОтчет);
            ДокументРезультат.Присоединить(ОбластьОстатокНаНДОтчет);

        КонецЕсли;

        ПоВалютам = Ложь;
        Для Каждого Строка Из РабочаяТаблица Цикл
            Если ((Строка.Остаток <> 0) Или (Строка.ВалОстаток <> 0)) И (НЕ Строка.Валюта=Справочники.Валюты.ПустаяСсылка()) Тогда
                ПоВалютам = Истина;
                Прервать;
            КонецЕсли;
        КонецЦикла;

//        Высота каждой строки = 13 пунктов
//      На стандартную страницу помещается 59 строк

//        Высоты секций в строках:
//      Шапка = 5 стр
//        ВкладнойЛист = 3 стр (с 2013 2 стр)
//        ОтчетКассира = 3 стр (с 2013 2 стр)
//        ОстатокНаНачало = 1 стр
//        ВТомЧисле = 1 стр
//        Остаток = 1 стр
//        ВалОстаток = 2 стр
//        КурсовыеРазницы = 2 стр
//        КурсовыеРазницыПоВалюте = 1 стр
//        Строка = 2 стр
//        СтрокаШирокая = 4 стр
//        СтрокаВал = 2 стр
//        СтрокаВалШирокая = 4 стр
//        Перенос = 1 стр
//        Оборот = 1 стр
//        ОборотРуб = 1 стр
//        ОборотВал = 2 стр
//        КурсоваяРазница = 1 стр
//        КурсоваяРазницаПоВалюте = 1 стр
//        КонечныйОстаток = 1