Доброго времени суток
есть переменная типа Тип("ПараметрыМакетаТабличногоДокумента")
"Для Каждого Из" получает значения всех параметров
Вопрос в том как получить имена этих самых параметров
По сути нужна коллекция {ИмяПараметра, ЗначениеПараметра}

В итераторе разве не хранится имя параметра?

(1) нет (((
получает только ЗначениеПараметра

и индекс

(3) в смысле по индексу можно получить значение, но как получить имя этого самого параметра?

(4) никак не получить, смирись

нельзя "смирись"
надо чесать правой ногой левое ухо :-(

(0) даю наводку

<SpreadsheetDocument xmlns="http://v8.1c.ru/8.2/data/spreadsheet"; xmlns:style="http://v8.1c.ru/8.1/data/ui/style"; xmlns:v8="http://v8.1c.ru/8.1/data/core"; xmlns:v8ui="http://v8.1c.ru/8.1/data/ui"; xmlns:xs="http://www.w3.org/2001/XMLSchema"; xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">;
    <languageSettings>
        <currentLanguage>ru</currentLanguage>
        <defaultLanguage>ru</defaultLanguage>
        <languageInfo>
            <id>ru</id>
            <code>Русский</code>
            <description>Русский</description>
        </languageInfo>
    </languageSettings>
    <columns>
        <size>1</size>
    </columns>
    <rowsItem>
        <index>0</index>
        <row>
            <c>
                <c>
                    <f>1</f>
                    <parameter>Параметр1</parameter>
                </c>
            </c>
        </row>
    </rowsItem>
    <templateMode>true</templateMode>
    <defaultFormatIndex>2</defaultFormatIndex>
    <height>1</height>
    <vgRows>1</vgRows>
    <format>
        <fillType>Parameter</fillType>
    </format>
    <format>
        <width>72</width>
    </format>
</SpreadsheetDocument>

(7) есть область макета и все её параметры
табличного документа ещё нет (((

(8) а Сообщить(""+ТипЗнч(ТвояОбластьМакета));
что пишет?

ну оно то да...
но если в документе пара сотен строк и каждую выгружать в файл а потом его парсить....
пользователи неправильно поймут

(10) зачем выгружать в файл?

(11) а как тогда получить SpreadsheetDocument

(7) ну или наводку уточните

(12)  например так

    Макет = тОбъект.ПолучитьМакет("Макет");
    СтрМакета = Макет.ПолучитьОбласть("СтрМакета");
    ЗаписьXML = Новый ЗаписьXML;
    ЗаписьXML.УстановитьСтроку();
    СериализаторXDTO.ЗаписатьXML(ЗаписьXML, СтрМакета);
    тСтр = ЗаписьXML.Закрыть();
    Сообщить(тСтр);

(14) спасибо, попробую поковырять

хотя бред получается : получить параметр по имени можно а получить имена параметров нельзя...

(14) не выйдет же, не сериализуется область макета..

максимум, так выйдет:

Макет = тОбъект.ПолучитьМакет("Макет");
СтрМакета = Макет.ПолучитьОбласть("СтрМакета");
Сообщить(ЗначениеВСтрокуВнутр(СтрМакета));

и далее парсить на вхождение "{24,"
там ужо будут имена параметра и расшифровки

(17) пробовал? запусти этот код на простейшем макете

(19) конечно

(20) и что? не сообшил ничего?

ну и..если бы область сериализовалась, то проще было бы писать просто
Сообщить(XMLСтрока (СтрМакета))

НО, это тоже не работает

(21) Почему ? Сообщил ошибку - неверный параметр 2

вот в этом методе СериализаторXDTO.ЗаписатьXML(ЗаписьXML, СтрМакета);

(23) а мне представляешь ничего такого не выдает
Только XML из (7)

(17) вышло

(25) может быть, я на 8.1 проверил

(27) 8,2

ща, посмотрим, че там в 8.2 и 8.3

да, на 8.3 работает

ну и ладно, всё равно , через ж..у
Могли бы и имена элементам коллекции в свойсто добавить

ОбластьЯчеекТабличногоДокумента (SpreadsheetDocumentRange)
Параметр (Parameter)
Использование:

Чтение и запись.
Описание:

Тип: Строка.
Имя параметра, используемого при выводе области.

Доступность:

Тонкий клиент, веб-клиент, сервер, толстый клиент, внешнее соединение.

(32) и ?

(33) он намекает на это:
Для каждого Область из СтрМакета.Области Цикл
    Сообщить("Область ="+Область.Параметр);
КонецЦикла;

(34) И ?

(34) и вот

Функция ПолучитьПараметрыОбласти(ОбластьТД)
    СтруктураПараметров = Новый Структура;
    Если ТипЗнч(ОбластьТД)<>Тип("ТабличныйДокумент") Тогда
        возврат СтруктураПараметров;
    КонецЕсли;
    Для каждого Область из ОбластьТД.Области Цикл
        Если Область.Заполнение=ТипЗаполненияОбластиТабличногоДокумента.Параметр ИЛИ Область.Заполнение=ТипЗаполненияОбластиТабличногоДокумента.Шаблон Тогда
               СтруктураПараметров.Вставить(Область.Параметр,"");
        КонецЕсли;
    КонецЦикла;
    Возврат СтруктураПараметров;
КонецФункции

(36) и.. не работает

(37) а у меня работает.

Макет = тОбъект.ПолучитьМакет("Макет");
СтрМакета = Макет.ПолучитьОбласть("СтрМакета");
ПараметрыТД = ПолучитьПараметрыОбласти(СтрМакета);
Для каждого параметр из ПараметрыТД Цикл
     Сообщить(""+Параметр.Ключ+" = "+Параметр.Значение);
КонецЦикла;

(38)
    Макет = ПолучитьМакет("Макет");
    ТабДок = Новый ТабличныйДокумент;
    
    Секция = Макет.ПолучитьОбласть("Строка");
    Для каждого Область из Секция.Области Цикл
     Сообщить("Область ="+Область.Параметр);
    КонецЦикла;

тут дырка от бублика

(40) а у меня выдает
Параметр1 =

(41) 8.3 ничего не выдает..

если пихать целиуом твой код - пустая структура соответственно возвращается

(43) ну так это ТС и требовалось а значения параметров он уже и сам как-нить установит - имена-то теперь у него есть в виде структуры

(44) ну ты наверное в своем тестовом макете какой-нибудь тестовый параметр сделал наверное или нет?

(45)->(42)

Посмотрел на 8.2 - выдает ТОЛЬКО первый параметр из секции..

(45) нет. Все параметры как Параметр или Шаблон

в 8.3 - пофик, там всегда пусто, в 8.2 возвращает имя только первого параметра.

в 8.1 тоже ничего не возвращает

Добавь в свой макет еще ячейку с параметром и всё, болт

Более того, твой код в 8.2 берет значение параметра только из первой ячейки в области

Ну и для 8.1 и 8.3.. не работает, никак
:)

(52) ты прав код кривой
вот поправил

Функция ПолучитьПараметрыОбласти(ОбластьТД)
    СтруктураПараметров = Новый Структура;
    Если ТипЗнч(ОбластьТД)<>Тип("ТабличныйДокумент") Тогда
        возврат СтруктураПараметров;
    КонецЕсли;
    ШиринаТаб = ОбластьТД.ШиринаТаблицы;
    ВысотаТаб = ОбластьТД.ВысотаТаблицы;
    Для стр=1 по высотаТаб Цикл
        Для кол=1 по ШиринаТаб Цикл
            Область = ОбластьТД.Область(стр,кол);
            Если Область.Заполнение=ТипЗаполненияОбластиТабличногоДокумента.Параметр ИЛИ Область.Заполнение=ТипЗаполненияОбластиТабличногоДокумента.Шаблон Тогда
                   СтруктураПараметров.Вставить(Область.Параметр,"");
            КонецЕсли;
        КонецЦикла;    
    КонецЦикла;
    Возврат СтруктураПараметров;
КонецФункции

(54)
ну вот...
все за ТС сделал.

(54) так работает, вот только в структуру помещать не стоит, ибо ежели в параметре будет типа
[Вася] - будет облом с именем структуры

на 8.1 тоже заработало

(56) вроде параметры проходят проверку на допустимость наименования в качестве ключа и записать параметр в именем [Вася] просто нельзя

(58) в Шаблон же можно

А если 2 параметра в шаблоне?

(60) а пофик, это потом по скобкам отпарсить можно будет

(59) и опять ты прав

поправил опять
Функция ПолучитьПараметрыОбласти(ОбластьТД)
    СтруктураПараметров = Новый Структура;
    Если ТипЗнч(ОбластьТД)<>Тип("ТабличныйДокумент") Тогда
        возврат СтруктураПараметров;
    КонецЕсли;
    ШиринаТаб = ОбластьТД.ШиринаТаблицы;
    ВысотаТаб = ОбластьТД.ВысотаТаблицы;
    Для стр=1 по высотаТаб Цикл
        Для кол=1 по ШиринаТаб Цикл
            Область = ОбластьТД.Область(стр,кол);
            Если Область.Заполнение=ТипЗаполненияОбластиТабличногоДокумента.Параметр Тогда
                   СтруктураПараметров.Вставить(Область.Параметр,"");
            ИначеЕсли Область.Заполнение=ТипЗаполненияОбластиТабличногоДокумента.Шаблон    Тогда
                ДобавитьПараметрыИзШаблона(СтруктураПараметров,Область.Текст);
            КонецЕсли;
        КонецЦикла;    
    КонецЦикла;
    Возврат СтруктураПараметров;
КонецФункции    

Процедура ДобавитьПараметрыИзШаблона(СтруктураПараметров,ОбластьТекст)
    тШаблон = ОбластьТекст;
    тПоз = Найти(тШаблон,"[");
    Пока тПоз>0 Цикл
        тШаблон = Сред(тШаблон,тПоз+1);
        тПоз = Найти(тШаблон,"]");
        Если тПоз=0 Тогда
            Прервать;
        КонецЕсли;
        тПараметр = СокрЛП(Лев(тШаблон,тПоз-1));
        Если тПараметр <>"" Тогда
            Попытка
                СтруктураПараметров.Вставить(тПараметр,"");
            Исключение
                Сообщить("В шаблоне "+ОбластьТекст+" ошибка: "+ОписаниеОшибки());
            КонецПопытки;    
        КонецЕсли;
    КонецЦикла;
КонецПроцедуры

(62)+ пропустил строчку кода

Процедура ДобавитьПараметрыИзШаблона(СтруктураПараметров,ОбластьТекст)
    тШаблон = ОбластьТекст;
    тПоз = Найти(тШаблон,"[");
    Пока тПоз>0 Цикл
        тШаблон = Сред(тШаблон,тПоз+1);
        тПоз = Найти(тШаблон,"]");
        Если тПоз=0 Тогда
            Прервать;
        КонецЕсли;
        тПараметр = СокрЛП(Лев(тШаблон,тПоз-1));
        Если тПараметр <>"" Тогда
            Попытка
                СтруктураПараметров.Вставить(тПараметр,"");
            Исключение
                Сообщить("В шаблоне "+ОбластьТекст+" ошибка: "+ОписаниеОшибки());
            КонецПопытки;    
        КонецЕсли;
        тПоз = Найти(тШаблон,"[");
    КонецЦикла;
КонецПроцедуры