Привет. Конструктор запросов.
Имею запрос

ВЫБРАТЬ
    ЦеныНоменклатурыСрезПоследних.Номенклатура КАК Номенклатура,
    ЦеныНоменклатурыСрезПоследних.Цена КАК Цена,
    ЦеныНоменклатурыСрезПоследних.ТипЦен КАК ТипЦен
ИЗ
    РегистрСведений.ЦеныНоменклатуры.СрезПоследних(
            ,
            ТипЦен В (&ТипЦен1, &ТипЦен2)
                И Номенклатура.Родитель В ИЕРАРХИИ (&Родитель)) КАК ЦеныНоменклатурыСрезПоследних

ТипЦен1 = Закупочная(грн)
ТипЦен2 = Закупочная(дол)

в одной номенклатуры может быть две закупочные цены как ТипЦен1 так ТипЦен2, хотелось бы видеть в такой номенклатуры только одну цену

(0) Какую из двух?

(1) не принципиально, хотя давайте ТипЦен1

я бы сделал два разных запроса по типам цен и соединение между ними по номенклатуре.

(3) типа с соединением ПОЛНОЕ?

Чего-то бредом попахивает..

ТипЦен В (&ТипЦен1, &ТипЦен2)
->
ТипЦен = &ТипЦен1
?

Сделай через ВЫБОР КОГДА ТОГДА..

(4) типа да

(2) Я охреневаю с вас. Непринципиально ему. У какой-то из двух цен должен быть приоритет, иначе эта задачка лучше рандомайзером решается.
Я бы левое соединение справочника с регистром сделал дважды(для двух типов цен), и ВЫБОР КОГДА ТОГДА.

(5) не понял вашего сарказма

(8) мне не важно какая цена, мне всеровно одну из цен придеться на курс умножать или делить, я же не просто так написал что "непринципиально".

(8) не могу придумать как с выбор когда тогда реализовать, что вы имеете ввиду?

ВЫБРАТЬ
    ВЫБОР
        КОГДА ЦеныНоменклатурыВВалюте.Цена ЕСТЬ NULL
            ТОГДА ЦеныНоменклатуры.Цена
        ИНАЧЕ ЦеныНоменклатурыВВалюте.Цена
    КОНЕЦ КАК Цена,
    ВЫБОР
        КОГДА ЦеныНоменклатурыВВалюте.Цена ЕСТЬ NULL
            ТОГДА ЦеныНоменклатуры.ТипЦен
        ИНАЧЕ ЦеныНоменклатурыВВалюте.ТипЦен
    КОНЕЦ КАК ТипЦен,
    Номенклатура.Ссылка КАК Номенклатура
ИЗ
    Справочник.Номенклатура КАК Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ТипЦен = &ТипЦенДоллары) КАК ЦеныНоменклатурыВВалюте
        ПО Номенклатура.Ссылка = ЦеныНоменклатурыВВалюте.Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ТипЦен = &ТипЦенГривны) КАК ЦеныНоменклатуры
        ПО Номенклатура.Ссылка = ЦеныНоменклатуры.Номенклатура
ГДЕ
    Номенклатура.Ссылка В ИЕРАРХИИ(&Родитель)


Как-то так. Этот запрос, правда, покажет всю номенклатуру(даже ту, у которой цен нет вообще). Если такие строчки не нужны - надо условие на ЕСТЬ NULL добавить. Ну и есть другой минус - соединений столько, сколько типов цен. Зато предсказуемо и приоритеты можно расставить(что в каком случае выводить, в ВЫБОР). В данном случае если есть цена в долларах - выводится она, если нет - выводится в гривнах. Можно наоборот сделать.

(12) дякую

в запросах "непринципиально" = МАКСИМУМ(ТипЦены)
потом по полученному полю внутреннее соединение...

У меня дежавю?

Выбрать Различные поля по условию в Запросе

(0) ты вернулся чтоб нас мучать. сгинь сгинь

(16) :D (15) :D у меня плохая память, я забываю и глядел на пред. вариант и шо то ничего не понял ) простите меня.

Я в итоге сделал, не знаю оптимально ли но вышло вот что

ВЫБРАТЬ
    ТоварыНаСкладахОстатки.Склад КАК Склад,
    ТоварыНаСкладахОстатки.Номенклатура КАК Номенклатура,
    СУММА(ТоварыНаСкладахОстатки.КоличествоОстаток) КАК Остаток,
    ЦеныНоменклатурыВГривне.Цена КАК ЦенаГривна,
    ЦеныНоменклатурыВГривне.ТипЦен КАК Гривна,
    ЦеныНоменклатурыВДолларах.Цена КАК ЦенаДоллар,
    ЦеныНоменклатурыВДолларах.ТипЦен КАК Доллар
ИЗ
    РегистрНакопления.ТоварыНаСкладах.Остатки(, Склад В (&Склад1, &Склад2)) КАК ТоварыНаСкладахОстатки
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ТипЦен = &гривна) КАК ЦеныНоменклатурыВГривне
        ПО ТоварыНаСкладахОстатки.Номенклатура = ЦеныНоменклатурыВГривне.Номенклатура
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ЦеныНоменклатуры.СрезПоследних(, ТипЦен = &доллар) КАК ЦеныНоменклатурыВДолларах
        ПО ТоварыНаСкладахОстатки.Номенклатура = ЦеныНоменклатурыВДолларах.Номенклатура
ГДЕ
    ТоварыНаСкладахОстатки.КоличествоОстаток > 0

СГРУППИРОВАТЬ ПО
    ТоварыНаСкладахОстатки.Склад,
    ТоварыНаСкладахОстатки.Номенклатура,
    ЦеныНоменклатурыВГривне.Цена,
    ЦеныНоменклатурыВГривне.ТипЦен,
    ЦеныНоменклатурыВДолларах.Цена,
    ЦеныНоменклатурыВДолларах.ТипЦен

УПОРЯДОЧИТЬ ПО
    Склад,
    Остаток УБЫВ

(16) (15) в итоге ж я гарантировано получу все остатки, а уже по остаткам получу цены?! пока не могу понять тот вариант, которые рекомендовали мне в пред. ветке, поэтому и забыл как его правильно делать (((