Блокировка регламентных заданий

Как то на скорую руку делал обработку для снятия/установки/просмотра текущего состояния блокировки соединений.

Код :

    ИмяБазы = "...";
    // ---- Инцилизиурем константы ----

    ИмяСервера = "имя:порт";        // адрес 1С сервер
    АдминКластера = "...";
    ПарольАдминаКластера = ПарольАдмКластера;
    Админ1С = "...";     // пользователь с полными правами
    ПарольАдмина1С = ПарольАдмБазы;        // пароль админа 1С

    // ---- Отписываемся от регламентых заданий ----
    Соединение = Новый COMОбъект("V82.COMConnector");               // Соединились с 1С
    Попытка
        СоединениеАгент = Соединение.ConnectAgent(ИмяСервера);      // Соединились с 1С Агентом
        Кластеры = СоединениеАгент.GetClusters();                   // Получитли массив кластеров (COMSafeArray)
    Исключение
        #Если НаКлиенте тогда
            Сообщить("Ошибка соединения с COM сервером: " + ОписаниеОшибки());
        #КонецЕсли
        Возврат;
    КонецПопытки;

    КоличествоКластеров = Кластеры.GetLength(0);
    Если КоличествоКластеров < 1 тогда
        #Если НаКлиенте тогда
            Сообщить("Не найден кластер на сервере " + ИмяСервера);
        #КонецЕсли
        Возврат;
    КонецЕсли;

    РабочийКластер = Кластеры.GetValue(0);
    Попытка
        // Авторизируемся на кластере (Кластер,Имя,Пароль)
        СоединениеАгент.Authenticate(РабочийКластер, АдминКластера, ПарольАдминаКластера);
    Исключение
        #Если НаКлиенте тогда
            Сообщить("Ошибка авторизации: " + ОписаниеОшибки());
        #КонецЕсли
        Возврат;
    КонецПопытки;

    // Подключаемся к рабочему процессу
    РабочийПроцесс = СоединениеАгент.GetWorkingProcesses(РабочийКластер).GetValue(0);
    Порт = СтрЗаменить(Строка(РабочийПроцесс.MainPort),Символы.НПП,"");  // убиваем непереносимые пробелы
    Сообщить(Порт);
    СтрокаПодлючения = РабочийПроцесс.HostName + ":" + Порт;
    СоединениеСРабочимПроцессом = Соединение.ConnectWorkingProcess(СтрокаПодлючения);
    СоединениеСРабочимПроцессом.AddAuthentication(Админ1С,ПарольАдмина1С);

    // Ищем текущую базу данных
    МассивБаз = СоединениеСРабочимПроцессом.GetInfoBases();
    БазаНайдена = Ложь;
    Для каждого РабочаяБаза из МассивБаз цикл
        Если НРег(РабочаяБаза.Name) = НРег(ИмяБазы) Тогда
            БазаНайдена = Истина;
            Прервать;
        КонецЕсли;
    КонецЦикла;

    Если Не БазаНайдена тогда
        #Если НаКлиенте тогда
            Сообщить("База (" + ИмяБазы + ") не найдена на сервере " + ИмяСервера);
        #КонецЕсли
        Возврат;
    КонецЕсли;

    Если Блокировка = 0 Тогда
        Сообщить("Текущее состояние: Блокировка " + РабочаяБаза.ScheduledJobsDenied);
    ИначеЕсли Блокировка = 1 Тогда
        РабочаяБаза.ScheduledJobsDenied = Ложь;   // Снимаем Блокировку выполнения регламентных заданий
        СоединениеСРабочимПроцессом.UpdateInfoBase(РабочаяБаза);
    ИначеЕсли Блокировка = 2 Тогда
        РабочаяБаза.ScheduledJobsDenied = Истина;   // Блокируем выполнения регламентных заданий
        СоединениеСРабочимПроцессом.UpdateInfoBase(РабочаяБаза);
    КонецЕсли;