Еще раз привет!

Находил похожие темы. Объясню в двух словах. В реквизите хранится значение чего либо. Тип реквизита - составной. Вот и вопрос: каким методом узнать (глобально), к чему относится выбранный объект в реквизите: к документу или к справочнику?

метаданные()?

есть ещё ТипЗнч()

(1) (2) И то и другое пригодилось в разных случаях. Спасибо!

Справочники.ТипВсеСсылки().СодержитТИп() или просто ли СОдержит() - не помню

а у меня не вышло с ТИПЗНАЧЕНИЯ, как на СКД это будет?
хочу отобрать заказчика с типом ссправочник контрагенты

я ему
Заказчик = ТИПЗНАЧЕНИЯ (Справочник.Контрагенты)- а он ругается)

как правильно, подскажите

ТИПЗНАЧЕНИЯ(Заказчик) = ТИП("Справочник.Контрагенты")

(6) спасибо :)

(6) и все равно ругается(

Элементарно:
Документы.ТипВсеСсылки().СодержитТип(ТипЗнч(Объект))
Метаданные.Документы.Содержит(Объект.Метаданные())
последний более универсален поскольку первый подходит только для ссылок

+ если в запросе: Заказчик ССЫЛКА Справочник.Контрагенты

(8) типзнч()

Получилось как в (6) , Если делать как (10), то возвращает "Да" "Нет"

Типовая БП
// Возвращает имя вида объектов метаданных по ссылке на объект.
// Ограничение: не обрабатываются точки маршрутов бизнес-процессов.
//
// Параметры:
//  Ссылка - ЛюбаяСсылка - объект, вид которого требуется получить.
//
// Возвращаемое значение:
//  Строка - имя вида объектов метаданных. Например: "Справочник", "Документ".
//

Функция ВидОбъектаПоСсылке(Ссылка) Экспорт
    
    Возврат ВидОбъектаПоТипу(ТипЗнч(Ссылка));
    
КонецФункции

// Возвращает имя вида объектов метаданных по типу объекта.
// Ограничение: не обрабатываются точки маршрутов бизнес-процессов.
//
// Параметры:
//  Тип - Тип - Тип прикладного объекта, определенный в конфигурации .
//
// Возвращаемое значение:
//  Строка - имя вида объектов метаданных. Например: "Справочник", "Документ".
//
Функция ВидОбъектаПоТипу(Тип) Экспорт
    
    Если Справочники.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "Справочник";
    
    ИначеЕсли Документы.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "Документ";
    
    ИначеЕсли БизнесПроцессы.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "БизнесПроцесс";
    
    ИначеЕсли ПланыВидовХарактеристик.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "ПланВидовХарактеристик";
    
    ИначеЕсли ПланыСчетов.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "ПланСчетов";
    
    ИначеЕсли ПланыВидовРасчета.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "ПланВидовРасчета";
    
    ИначеЕсли Задачи.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "Задача";
    
    ИначеЕсли ПланыОбмена.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "ПланОбмена";
    
    ИначеЕсли Перечисления.ТипВсеСсылки().СодержитТип(Тип) Тогда
        Возврат "Перечисление";
    
    Иначе
        ВызватьИсключение СтроковыеФункцииКлиентСервер.ПодставитьПараметрыВСтроку(
            НСтр("ru='Неверный тип значения параметра (%1)'"), Строка(Тип));
    
    КонецЕсли;
    
КонецФункции

Соответственно ОбщегоНазначения.ВидОбъектаПоСсылке(Ссылка)