Например, такое

<Doc xmlns:test="http://test11.ru"; >

Чтобы в переменную получить url сайта

Ну, наверное через чтение атрибутов узла. Есть принципиальная разница?

Создай документ DOM и читай что хочешь

ПостроительДом = Новый ПостроительDOM();
    ДанныеDOM = ПостроительДом.Прочитать(ДанныеXML);

    Для Каждого ЭлементDOM ИЗ ДанныеDOM.ПолучитьЭлементыПоИмени("Doc") Цикл
        ЭтаФорма.Тест = ЭлементDOM.ПолучитьАтрибут("xmlns:test");
    КонецЦикла;        


к сожалению, атрибут такого типа не считывает... как быть???

(4)
ЭлементDOM (DOMElement)
URIПространстваИмен (NamespaceURI)
Использование:

Только чтение.
Описание:

Тип: Строка; Неопределено.
URI пространства имен узла.
Свойство имеет значение Неопределено для узлов, отличных от Атрибут и Элемент, или для узлов, созданных при помощи метода DOM Level 1 (например, СоздатьЭлемент).

Доступность:

Сервер, толстый клиент, внешнее соединение, мобильное приложение(сервер).

(1) А вот это не совсем вменямая хотелка. Пространство имен к сайту не имеет никакого отношения.

<Doc xmlns:test="my_name_space"; >

и уже не URL

(8) не корректно выразился, но смысл все поняли.

(5) примерчик бы - гуглю, не получается

ДокументDOM (DOMDocument)
URIПространстваИмен (NamespaceURI)
Использование:

Только чтение.
Описание:

Тип: Строка; Неопределено.
URI пространства имен узла.
Свойство имеет значение Неопределено для узлов, отличных Атрибут и Элемент, или для узлов, созданных при помощи метода DOM Level 1 (например, СоздатьЭлемент).

Доступность:

Сервер, толстый клиент, внешнее соединение.

(9)
1) Чтобы получить пространство имен нужного узла, надо взять от него свойство URIПространстваИмен, например

    Чтение = Новый ЧтениеXML;
    Чтение.УстановитьСтроку(
        "<?xml version=""1.0"" encoding=""UTF-8"" standalone=""yes""?>
        |<Doc xmlns:test=""http://test11.ru""></Doc>;
        |");
        
    ПостроительДом = Новый ПостроительDOM();
    ДанныеDOM = ПостроительДом.Прочитать(Чтение);

    Для Каждого ЭлементDOM ИЗ ДанныеDOM.ПолучитьЭлементыПоИмени("Doc") Цикл
        Сообщить(ЭлементDOM.URIПространстваИмен);
    КонецЦикла;

Внезапно выведет пустую строку. И это правильно, потому что само имя "Doc" относится к пространству имен
по умолчанию (которое определяется выше и которое здесь пусто). Если изменить пример и указать, что
имя "Doc"" относится к декларируемому пространству:

    Чтение.УстановитьСтроку(
        "<?xml version=""1.0"" encoding=""UTF-8"" standalone=""yes""?>
        |<test:Doc xmlns:test=""http://test11.ru""></test:Doc>;
        |");
    ...
    
То получим ожидаемое.

Ну или аналогично, сразу через ЧтениеXML

    Чтение = Новый ЧтениеXML;
    Чтение.УстановитьСтроку(
        "<?xml version=""1.0"" encoding=""UTF-8"" standalone=""yes""?>
        |<test:Doc xmlns:test=""http://test11.ru""></test:Doc>;
        |");
    Чтение.ПерейтиКСодержимому();
    
    Сообщить("Пространство = " + Чтение.URIПространстваИмен);

2) Чтобы получить все текущие пространства имен достаточно получить массив имен у свойства чтения
"КонтекстПространствИмен" вызовом URIПространствИмен(). Например так:

    Чтение = Новый ЧтениеXML;
    Чтение.УстановитьСтроку(
        "<?xml version=""1.0"" encoding=""UTF-8"" standalone=""yes""?>
        |<test:Doc xmlns:test=""http://test11.ru""></test:Doc>;
        |");
    Чтение.ПерейтиКСодержимому();
    
    Для Каждого Имя Из Чтение.КонтекстПространствИмен.URIПространствИмен() Цикл
        Сообщить("Пространство = " + Имя);
    КонецЦикла;
    
Здесь уже нет разницы - на каком уровне и для чего было определено пространство - для документа или для вложенных элементов.
Аналогичный результат будет и при

    Чтение.УстановитьСтроку(
        "<?xml version=""1.0"" encoding=""UTF-8"" standalone=""yes""?>
        |<Doc xmlns:test=""http://test11.ru""></Doc>;
        |");

И при

    Чтение.УстановитьСтроку(
        "<?xml version=""1.0"" encoding=""UTF-8"" standalone=""yes""?>
        |<test:Doc xmlns:test=""http://test11.ru""></test:Doc>;
        |");