Добрый день, колеги! Запрос в таком виде работает около 10-15 сек, используется в формировании отчета большое количество раз. Из-за этого отчет формируется оооочень долго. Нужна Ваша помощь в оптимизации.

ВЫБРАТЬ ПЕРВЫЕ 1
                              |    ХозрасчетныйДвиженияССубконто.Регистратор.Дата КАК РегистраторДата
                              |ИЗ
                              |    РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(, &НачДата, , , ) КАК ХозрасчетныйДвиженияССубконто
                              |ГДЕ
                              |    (ХозрасчетныйДвиженияССубконто.СчетКт = &СчетКт
                              |                И ХозрасчетныйДвиженияССубконто.СубконтоКт1 = &СубконтоКт1
                              |            ИЛИ ХозрасчетныйДвиженияССубконто.СчетДт = &СчетКт
                              |                И ХозрасчетныйДвиженияССубконто.СубконтоДт1 = &СубконтоКт1)
                              |    И ТИПЗНАЧЕНИЯ(ХозрасчетныйДвиженияССубконто.Регистратор) <> ТИП(Документ.ОперацияБух)
                              |    И ТИПЗНАЧЕНИЯ(ХозрасчетныйДвиженияССубконто.Регистратор) <> ТИП(Документ.ЗакрытиеМесяца)
                              |
                              |УПОРЯДОЧИТЬ ПО
                              |    РегистраторДата УБЫВ

http://v8.1c.ru/metod/books/book.jsp?id=436

"используется в формировании отчета большое количество раз" - не использовать запрос в цикле

(2) приходится, т.к. циклом перебирается таблица значений и по каждой строке нужно находить дату последнего движения по регистру в разрезе контрагента (субконто)

(3) так не делают. Делают так: тз загоняют в запрос как ВТ (параметр)и левое соединение.
Да еще и "РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто(, &НачДата, , , )" - это вообще "песня" - обращение к виртуальной таблице без параметров-отборов. Мда. Верную книжку порекомендовали выше.
Ну или курс хоть того же Чистова (с тырнета бесплатный, если денег жалко) - а лучше новый платный (хоть от кого).

а так не стоит использовать конструкцию                              
ТИПЗНАЧЕНИЯ(ХозрасчетныйДвиженияССубконто.Регистратор) <> ТИП(Документ.ОперацияБух)
                              |    И ТИПЗНАЧЕНИЯ(ХозрасчетныйДвиженияССубконто.Регистратор) <> ТИП(Документ.ЗакрытиеМесяца)

изменить ее на "равно"

(0) а конфа какая?

дак а зачем ХозрасчетныйДвиженияССубконто если только дата по регистратору?
и  "И не ТИПЗНАЧЕНИЯ(ХозрасчетныйДвиженияССубконто.Регистратор) в (искл типы)"

ХозрасчетныйДвиженияССубконто.Регистратор.Дата
на порядок медленнее чем
ХозрасчетныйДвиженияССубконто.Период

Но главная проблема в (3), запроса в цикле быть не должно

(0) Дарю:
ВЫБРАТЬ ПЕРВЫЕ 1
   ХозрасчетныйСубконто.Регистратор
ИЗ
   РегистрБухгалтерии.Хозрасчетный.Субконто КАК ХозрасчетныйСубконто
ГДЕ
   ХозрасчетныйСубконто.Значение = &СубконтоКт1
   И ХозрасчетныйСубконто.Период <= &НачДата
   И НЕ ХозрасчетныйСубконто.Регистратор ССЫЛКА Документ.ОперацияБух
   И НЕ ХозрасчетныйСубконто.Регистратор ССЫЛКА Документ.ЗакрытиеМесяца
УПОРЯДОЧИТЬ ПО
   ХозрасчетныйСубконто.Период УБЫВ

Можно topt воткнуть условие на вид субконто (поле Вид).

+ к (10) Но соглащусь с остальными по поводу запроса в цикле. Это идиотизм и главная причина тормозов.

(3) >> нужно находить дату последнего движения по регистру в разрезе контрагента

За неправильный выбор нужных виртуальных таблиц на экзамене 1С Специалист ставят сразу незачет.

Поставленная задача решается обращение к реальной(!) таблице Субконто, а не к виртуальной таблице ДвиженияССубконто. См. (10)

+ к (10) только выбирать не Регистратор, а Период.

За выбор Регистратор.Дата тоже надо бы расстреливать.

Посмотри v8: v8: Вcтречаем! Версия 8.2.18, вышла в релизе 8.2.18.82 + опубликована версия 8.2.18.96

Как минимум можно подправить так:

ВЫБРАТЬ
    ХозрасчетныйДвиженияССубконто.Период КАК РегистраторДата
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто( , &НачДата, СчетДт = &СчетКт Или СчетКт = &СчетКт, , ) КАК ХозрасчетныйДвиженияССубконто
ГДЕ
    (ХозрасчетныйДвиженияССубконто.СчетКт = &СчетКт
    И ХозрасчетныйДвиженияССубконто.СубконтоКт1 = &СубконтоКт1
    ИЛИ ХозрасчетныйДвиженияССубконто.СчетДт = &СчетКт
    И ХозрасчетныйДвиженияССубконто.СубконтоДт1 = &СубконтоКт1)
    И Не ХозрасчетныйДвиженияССубконто.Регистратор ССЫЛКА Документ.ОперацияБух
    И Не ХозрасчетныйДвиженияССубконто.Регистратор ССЫЛКА Документ.ЗакрытиеМесяца

УПОРЯДОЧИТЬ ПО
    РегистраторДата УБЫВ

(12) в целом соглашусь, но в данном случае придется соединять таблицу движений (фильтр на Счета) с ДВУМЯ таблицами субконто: по Дт и по Кт.

*(16) две таблицы субконто отменяются, "ИЛИ" я не заметил.

(15) Даже пожалуй так:

ВЫБРАТЬ
    ХозрасчетныйДвиженияССубконто.Период КАК РегистраторДата
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто( , &НачДата, СчетДт = &СчетКт Или СчетКт = &СчетКт И Не Регистратор ССЫЛКА Документ.ОперацияБух И Не Регистратор ССЫЛКА Документ.ЗакрытиеМесяца, , ) КАК ХозрасчетныйДвиженияССубконто
ГДЕ
    (ХозрасчетныйДвиженияССубконто.СчетКт = &СчетКт
    И ХозрасчетныйДвиженияССубконто.СубконтоКт1 = &СубконтоКт1
    ИЛИ ХозрасчетныйДвиженияССубконто.СчетДт = &СчетКт
    И ХозрасчетныйДвиженияССубконто.СубконтоДт1 = &СубконтоКт1)

УПОРЯДОЧИТЬ ПО
    РегистраторДата УБЫВ

(18) Ошибочка в строке:

РегистрБухгалтерии.Хозрасчетный.ДвиженияССубконто( , &НачДата, ( СчетДт = &СчетКт Или СчетКт = &СчетКт ) И Не Регистратор ССЫЛКА Документ.ОперацияБух И Не Регистратор ССЫЛКА Документ.ЗакрытиеМесяца, , ) КАК ХозрасчетныйДвиженияССубконто