УТП для Украины, есть несложный отчёт на СКД, входных данных немного, три вложенные группировки, одна из которых "Детальные записи". Что может быть не так, куда копать?

может там 3 миллиона строк

(1) Данных мало.

Ну может у вас в условиях указано "Где Реквизит В (тут подзапрос)", или в выбираемых полях указано значение реквизита через точку и реквизит имеет составной тип данных с кучей вариантов или, что еще хуже, может иметь тип Хранилище значений

(3) Нет, ничего такого нет. И не в железе проблема, на разных компьютерах пробовал. Могу кинуть запрос, если интересно.

(4) Кидай конечно!

ВЫБРАТЬ
    НАЧАЛОПЕРИОДА(ПлатежноеПоручениеВходящее.Дата, ДЕНЬ) КАК ДатаОплаты,
    ПлатежноеПоручениеВходящее.СуммаДокумента КАК СуммаОплаты,
    РеализацияТоваровУслуг.Номер,
    РеализацияТоваровУслуг.Дата КАК Дата,
    РеализацияТоваровУслуг.Контрагент,
    РеализацияТоваровУслуг.СуммаДокумента КАК Сумма,
    РеализацияТоваровУслуг.Организация.Префикс,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(РеализацияТоваровУслуг.Сделка) = ТИП(Документ.ЗаказПокупателя)
                И РеализацияТоваровУслуг.Сделка <> ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)
            ТОГДА РеализацияТоваровУслуг.Сделка.Ответственный
        ИНАЧЕ РеализацияТоваровУслуг.Ответственный
    КОНЕЦ КАК Менеджер
ИЗ
    Документ.ПлатежноеПоручениеВходящее КАК ПлатежноеПоручениеВходящее
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        ПО ПлатежноеПоручениеВходящее.ДокументОснование = РеализацияТоваровУслуг.Ссылка
ГДЕ
    ПлатежноеПоручениеВходящее.Дата МЕЖДУ &НачалоПериода И &КонецПериода
    И РеализацияТоваровУслуг.Организация = &Организация
    И &ВключатьППВ = ИСТИНА

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    НАЧАЛОПЕРИОДА(ПриходныйКассовыйОрдер.Дата, ДЕНЬ),
    ПриходныйКассовыйОрдер.СуммаДокумента,
    РеализацияТоваровУслуг.Номер,
    РеализацияТоваровУслуг.Дата,
    РеализацияТоваровУслуг.Контрагент,
    РеализацияТоваровУслуг.СуммаДокумента,
    РеализацияТоваровУслуг.Организация.Префикс,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(РеализацияТоваровУслуг.Сделка) = ТИП(Документ.ЗаказПокупателя)
                И РеализацияТоваровУслуг.Сделка <> ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)
            ТОГДА РеализацияТоваровУслуг.Сделка.Ответственный
        ИНАЧЕ РеализацияТоваровУслуг.Ответственный
    КОНЕЦ
ИЗ
    Документ.ПриходныйКассовыйОрдер КАК ПриходныйКассовыйОрдер
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        ПО (РеализацияТоваровУслуг.Сделка = ПриходныйКассовыйОрдер.ДокументОснование)
ГДЕ
    РеализацияТоваровУслуг.Организация = &Организация

И ещё. На демо-базе УТП летало, на клиентской падает. Может, дело в базе?

(6) для начала Реализации во временную таблицу свали, а затем ее юзай для соединений

ну и и вариант с получением этой требухи из регистров рассмотри
тащить из документов - моветон

Во втором запросе период отбора ПКО ограничить не хочешь?

(6) Может ПКОшек в базе много? А у тебя условия отбора по периоду нет.
Какие ссылки могут стоять в поле РеализацияТоваровУслуг.Сделка - тоже тип ограничить не лишним будет...

(9) Не стоит, они разбросаны как попало.
(10) Мало. Насчёт второго. Как сделать, чтоб имелись ввиду только ЗаказПокупателя?

(11) ТИПЗНАЧЕНИЯ(РеализацияТоваровУслуг.Сделка) = ТИП(Документ.ЗаказПокупателя)
или так
РеализацияТоваровУслуг.Сделка ССЫЛКА Документ.ЗаказПокупателя

(12) Но это имеет смысл только если тип многосоставной, к сожалению, конфигурации под рукой нет...

Переписал через ВТ. Не помогло. На демо-базе и ещё одной УТП отрабатывает песня.

(14) Ну значит проблема в данных, подозреваю что именно в объеме.Попробуй через консоль запросов сначала первый запрос прогони, потом второй, затем попробуй объединить, потом добавь какие нибудь ограничения...так хоть понятно будет конкретнее где проблема...

Применяется RLS? Если да, то попробуй оставить одну роль пользователю.

(16) Нет.
(15) Ограничил период выборки ППВ и ПКО. Тепреь выводит. Только мне сдаётся, что задваивает.

ЛЕВОЕ СОЕДИНЕНИЕ Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        ПО (РеализацияТоваровУслуг.Сделка = ПриходныйКассовыйОрдер.ДокументОснование)
ГДЕ
    РеализацияТоваровУслуг.Организация = &Организация

тут прям видно, что это внутреннее соединение

КОГДА ТИПЗНАЧЕНИЯ(РеализацияТоваровУслуг.Сделка) = ТИП(Документ.ЗаказПокупателя)
                И РеализацияТоваровУслуг.Сделка <> ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)
            ТОГДА РеализацияТоваровУслуг.Сделка.Ответственный

тут выразить не хватает

также нужно посмотреть итоговый запрос, который выдает СКД, может там условие из соединения пропадает (мало ли что)

(18) Исправил.
(19) Где именно?

Вот что сейчас получилось.
ВЫБРАТЬ РАЗЛИЧНЫЕ
    РеализацияТоваровУслуг.СуммаДокумента КАК Сумма,
    РеализацияТоваровУслуг.Номер,
    РеализацияТоваровУслуг.Дата КАК Дата,
    РеализацияТоваровУслуг.Контрагент,
    РеализацияТоваровУслуг.Организация.Префикс,
    РеализацияТоваровУслуг.Сделка КАК Сделка,
    РеализацияТоваровУслуг.Сделка.Ответственный КАК СделкаОтветственный
ПОМЕСТИТЬ ВТ_Реализация
ИЗ
    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
ГДЕ
    РеализацияТоваровУслуг.Организация = &Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    НАЧАЛОПЕРИОДА(ПлатежноеПоручениеВходящее.Дата, ДЕНЬ) КАК ДатаОплаты,
    ПлатежноеПоручениеВходящее.СуммаДокумента КАК СуммаОплаты,
    ВТ_Реализация.Номер,
    ВТ_Реализация.Дата,
    ВТ_Реализация.Контрагент,
    ВТ_Реализация.ОрганизацияПрефикс,
    ВТ_Реализация.Сделка,
    ВТ_Реализация.СделкаОтветственный,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ВТ_Реализация.Сделка) = ТИП(Документ.ЗаказПокупателя)
                И ВТ_Реализация.Сделка <> ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)
            ТОГДА ВТ_Реализация.СделкаОтветственный
        ИНАЧЕ ВТ_Реализация.СделкаОтветственный
    КОНЕЦ КАК Менеджер,
    ВТ_Реализация.Сумма
ИЗ
    ВТ_Реализация КАК ВТ_Реализация
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПлатежноеПоручениеВходящее КАК ПлатежноеПоручениеВходящее
        ПО ВТ_Реализация.Сделка = ПлатежноеПоручениеВходящее.ДокументОснование
ГДЕ
    &ВключатьППВ = ИСТИНА
    И ПлатежноеПоручениеВходящее.Дата МЕЖДУ &НачалоПериода И &КонецПериода

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    НАЧАЛОПЕРИОДА(ПриходныйКассовыйОрдер.Дата, ДЕНЬ),
    ПриходныйКассовыйОрдер.СуммаДокумента,
    ВТ_Реализация.Номер,
    ВТ_Реализация.Дата,
    ВТ_Реализация.Контрагент,
    ВТ_Реализация.ОрганизацияПрефикс,
    ВТ_Реализация.Сделка,
    ВТ_Реализация.СделкаОтветственный,
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ВТ_Реализация.Сделка) = ТИП(Документ.ЗаказПокупателя)
                И ВТ_Реализация.Сделка <> ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)
            ТОГДА ВТ_Реализация.СделкаОтветственный
        ИНАЧЕ ВТ_Реализация.СделкаОтветственный
    КОНЕЦ,
    ВТ_Реализация.Сумма
ИЗ
    ВТ_Реализация КАК ВТ_Реализация
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПриходныйКассовыйОрдер КАК ПриходныйКассовыйОрдер
        ПО ВТ_Реализация.Сделка = ПриходныйКассовыйОрдер.ДокументОснование
ГДЕ
    ПриходныйКассовыйОрдер.Дата МЕЖДУ &НачалоПериода И &КонецПериода

вот этот кусок надо получить в первой таблице
    ВЫБОР
        КОГДА ТИПЗНАЧЕНИЯ(ВТ_Реализация.Сделка) = ТИП(Документ.ЗаказПокупателя)
                И ВТ_Реализация.Сделка <> ЗНАЧЕНИЕ(Документ.ЗаказПокупателя.ПустаяСсылка)
            ТОГДА ВТ_Реализация.СделкаОтветственный
        ИНАЧЕ ВТ_Реализация.СделкаОтветственный
    КОНЕЦ КАК Менеджер,

и лучше через

ЕстьNULL(ЗаказПокупателя.Ответственный, РеализацияТоваровУслуг.Ответственный) КАК Ответственный
Из
    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
Левое соединение Документ.ЗаказПокупателя КАК ЗаказПокупателя
по РеализацияТоваровУслуг.Сделка = ЗаказПокупателя.Ссылка

условие из ГДЕ в условия соединения

и потерялось условие по организации

ВЫБРАТЬ РАЗЛИЧНЫЕ
    РеализацияТоваровУслуг.СуммаДокумента КАК Сумма,
    РеализацияТоваровУслуг.Номер,
    РеализацияТоваровУслуг.Дата КАК Дата,
    РеализацияТоваровУслуг.Контрагент,
    РеализацияТоваровУслуг.Организация.Префикс,
    РеализацияТоваровУслуг.Сделка КАК Сделка,
    ЕСТЬNULL(ЗаказПокупателя.Ответственный, РеализацияТоваровУслуг.Ответственный) КАК Менеджер
ПОМЕСТИТЬ ВТ_Реализация
ИЗ
    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЗаказПокупателя КАК ЗаказПокупателя
        ПО РеализацияТоваровУслуг.Сделка = ЗаказПокупателя.Ссылка
ГДЕ
    РеализацияТоваровУслуг.Организация = &Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    НАЧАЛОПЕРИОДА(ПлатежноеПоручениеВходящее.Дата, ДЕНЬ) КАК ДатаОплаты,
    ПлатежноеПоручениеВходящее.СуммаДокумента КАК СуммаОплаты,
    ВТ_Реализация.Номер,
    ВТ_Реализация.Дата,
    ВТ_Реализация.Контрагент,
    ВТ_Реализация.ОрганизацияПрефикс,
    ВТ_Реализация.Сделка,
    ВТ_Реализация.Сумма,
    ВТ_Реализация.Менеджер КАК Менеджер
ИЗ
    ВТ_Реализация КАК ВТ_Реализация
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПлатежноеПоручениеВходящее КАК ПлатежноеПоручениеВходящее
        ПО ВТ_Реализация.Сделка = ПлатежноеПоручениеВходящее.ДокументОснование
ГДЕ
    &ВключатьППВ = ИСТИНА
    И ПлатежноеПоручениеВходящее.Дата МЕЖДУ &НачалоПериода И &КонецПериода

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    НАЧАЛОПЕРИОДА(ПриходныйКассовыйОрдер.Дата, ДЕНЬ),
    ПриходныйКассовыйОрдер.СуммаДокумента,
    ВТ_Реализация.Номер,
    ВТ_Реализация.Дата,
    ВТ_Реализация.Контрагент,
    ВТ_Реализация.ОрганизацияПрефикс,
    ВТ_Реализация.Сделка,
    ВТ_Реализация.Сумма,
    ВТ_Реализация.Менеджер
ИЗ
    ВТ_Реализация КАК ВТ_Реализация
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПриходныйКассовыйОрдер КАК ПриходныйКассовыйОрдер
        ПО ВТ_Реализация.Сделка = ПриходныйКассовыйОрдер.ДокументОснование
ГДЕ
    ПриходныйКассовыйОрдер.Дата МЕЖДУ &НачалоПериода И &КонецПериода

ВЫБРАТЬ РАЗЛИЧНЫЕ
    РеализацияТоваровУслуг.СуммаДокумента КАК Сумма,
    РеализацияТоваровУслуг.Номер,
    РеализацияТоваровУслуг.Дата КАК Дата,
    РеализацияТоваровУслуг.Контрагент,
    РеализацияТоваровУслуг.Организация.Префикс,
    РеализацияТоваровУслуг.Сделка КАК Сделка,
    ЕСТЬNULL(ЗаказПокупателя.Ответственный, РеализацияТоваровУслуг.Ответственный) КАК Менеджер
ПОМЕСТИТЬ ВТ_Реализация
ИЗ
    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЗаказПокупателя КАК ЗаказПокупателя
        ПО РеализацияТоваровУслуг.Сделка = ЗаказПокупателя.Ссылка
ГДЕ
    РеализацияТоваровУслуг.Организация = &Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    НАЧАЛОПЕРИОДА(ПлатежноеПоручениеВходящее.Дата, ДЕНЬ) КАК ДатаОплаты,
    ПлатежноеПоручениеВходящее.СуммаДокумента КАК СуммаОплаты,
    ВТ_Реализация.Номер,
    ВТ_Реализация.Дата,
    ВТ_Реализация.Контрагент,
    ВТ_Реализация.ОрганизацияПрефикс,
    ВТ_Реализация.Сделка,
    ВТ_Реализация.Сумма,
    ВТ_Реализация.Менеджер КАК Менеджер
ИЗ
    Документ.ПлатежноеПоручениеВходящее КАК ПлатежноеПоручениеВходящее
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Реализация КАК ВТ_Реализация
        ПО (ВТ_Реализация.Сделка = ПлатежноеПоручениеВходящее.ДокументОснование)
ГДЕ
    &ВключатьППВ = ИСТИНА
    И ПлатежноеПоручениеВходящее.Дата МЕЖДУ &НачалоПериода И &КонецПериода

ОБЪЕДИНИТЬ ВСЕ

ВЫБРАТЬ
    НАЧАЛОПЕРИОДА(ПриходныйКассовыйОрдер.Дата, ДЕНЬ),
    ПриходныйКассовыйОрдер.СуммаДокумента,
    ВТ_Реализация.Номер,
    ВТ_Реализация.Дата,
    ВТ_Реализация.Контрагент,
    ВТ_Реализация.ОрганизацияПрефикс,
    ВТ_Реализация.Сделка,
    ВТ_Реализация.Сумма,
    ВТ_Реализация.Менеджер
ИЗ
    Документ.ПриходныйКассовыйОрдер КАК ПриходныйКассовыйОрдер
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Реализация КАК ВТ_Реализация
        ПО (ВТ_Реализация.Сделка = ПриходныйКассовыйОрдер.ДокументОснование)
ГДЕ
    ПриходныйКассовыйОрдер.Дата МЕЖДУ &НачалоПериода И &КонецПериода

Вроде меньше уже, но что-то не так с соединениями.

Ап.

Ап.

Что такое "Кэпо"?

Кэш чистил?

(27) В первом запросе добавляй

ИНДЕКСИРОВАТЬ ПО
    Сделка
Это ускорит соединение в следующем запросе.

Там же: определись, какой тип значения будет в "РеализацияТоваровУслуг.Сделка" в твоем случае. Если там планируется только "ЗаказПокупателя", то так и пиши: вместо "РеализацияТоваровУслуг.Сделка как Сделка" - "Выразить(РеализацияТоваровУслуг.Сделка как Документ.Заказпокупателя) как Сделка". Или даже "Заказпокупателя.Ссылка как Сделка"

(27) Это какой-то контроль отгрузок и оплат по заказам? Меня сильно напрягает вот что:

ЕСТЬNULL(ЗаказПокупателя.Ответственный, РеализацияТоваровУслуг.Ответственный) КАК Менеджер
ПОМЕСТИТЬ ВТ_Реализация
ИЗ
    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЗаказПокупателя КАК ЗаказПокупателя
        ПО РеализацияТоваровУслуг.Сделка = ЗаказПокупателя.Ссылка

Т.е. предполагаем, что Заказа может и не быть в структуре подчиненности. Но при этом упорно стараемся группировать Реализации, Платежки и ПКО именно по полю "РеализацияТоваровУслуг.Сделка". Что может быть в этом поле в конфигурации, на которой исполняется отчет? И какой смысл в группировке по пустому полю для заказчика данного отчета?

(27) кстати, вот тебе и ответ, почему отчет валит сервер.
Смотри внимательно:

ВТ_Реализация КАК ВТ_Реализация
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПлатежноеПоручениеВходящее КАК ПлатежноеПоручениеВходящее
        ПО ВТ_Реализация.Сделка = ПлатежноеПоручениеВходящее.ДокументОснование

Представь, что в базе есть 1000 Реализаций, где пустое поле "Сделка".
И 1000 ПлатежноеПоручениеВходящее, где пустое поле "ДокументОснование".
Итого получаем 1000*1000 записей в выборке. Дальше разберешься?

Хотя дальше становится интереснее. Ок, можно элегантно обрубить пустые значения, заменив Левое соединение в первом запросе на Внутреннее (кто-то вроде уже советовал).
Но дальше ты уткнешься в дубли строк, если на основании одного Заказа создано более 1 Реализации.
Решение: из первой временной таблицы выбрать только уникальные Заказы, и уже именно их соединять с ПКО и ППВ в следующих запросах.
А еще более правильно, скорей всего, настроить использование типового регистра "ВзаиморасчетыСКонтрагентами", т.к. речь, похоже, идет всего лишь об учете дебиторки по заказам, а не по договорам. И тогда есть вероятность, что можно будет использовать какой-нибудь штатный отчет в конфигурации, а не писать свой.
Но вангую, что твой заказчик на это не пойдет, т.к. операторам надо будет немного переучиваться, а они этого не хотят, а цифры нужны вчера, а тыжпрограммист.... ну ты понял ))

Едрен батон, мы сильно ушли от изначального варианта запроса. А там было так:
(первая часть)
...ПО ПлатежноеПоручениеВходящее.ДокументОснование = РеализацияТоваровУслуг.Ссылка...

(вторая часть)
...ПО (РеализацияТоваровУслуг.Сделка = ПриходныйКассовыйОрдер.ДокументОснование)...

Вот вторая часть тебе базу валила, похоже. И тут какое-то противоречие между первой и второй частью запроса.