Необходимо создать отчет, который отображает общую сумму осн и доп начислений по каждому сотруднику. Запросом создаю две временные таблицы, в первой "сотрудник", "период регистрации", "Результат" по осн.начислениям, во второй выбираю те же поля, только из доп.начислений. в 3м пакете запросов, выбираю первые два поля из осн.таблицы, естественно связанные с полями по доп.начислениям, а результат рассчитываю, как сумму результатов двух регистров. Период и Сотрудника в итоге я получаю, а колонка с результатом пустая((( Уже голову себе сломала, подскажите, как исправить??(

Покажи запросы.

Nuobu, Не нашла, как прикрепить файл, это внешний отчет.

ВЫБРАТЬ
    ОсновныеНачисленияРаботниковОрганизаций.ПериодРегистрации,
    ОсновныеНачисленияРаботниковОрганизаций.Сотрудник КАК Сотрудник,
    СУММА(ОсновныеНачисленияРаботниковОрганизаций.Результат) КАК Результат
ПОМЕСТИТЬ Осн
ИЗ
    РегистрРасчета.ОсновныеНачисленияРаботниковОрганизаций КАК ОсновныеНачисленияРаботниковОрганизаций

СГРУППИРОВАТЬ ПО
    ОсновныеНачисленияРаботниковОрганизаций.ПериодРегистрации,
    ОсновныеНачисленияРаботниковОрганизаций.Сотрудник
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ДополнительныеНачисленияРаботниковОрганизаций.ПериодРегистрации,
    ДополнительныеНачисленияРаботниковОрганизаций.Сотрудник,
    СУММА(ДополнительныеНачисленияРаботниковОрганизаций.Результат) КАК Результат
ПОМЕСТИТЬ Доп
ИЗ
    РегистрРасчета.ДополнительныеНачисленияРаботниковОрганизаций КАК ДополнительныеНачисленияРаботниковОрганизаций

СГРУППИРОВАТЬ ПО
    ДополнительныеНачисленияРаботниковОрганизаций.Сотрудник,
    ДополнительныеНачисленияРаботниковОрганизаций.ПериодРегистрации
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    Осн.ПериодРегистрации,
    Осн.Сотрудник КАК Сотрудник,
    СУММА(Осн.Результат + Доп.Результат) КАК Поле1
ИЗ
    Осн КАК Осн
        ЛЕВОЕ СОЕДИНЕНИЕ Доп КАК Доп
        ПО Осн.ПериодРегистрации = Доп.ПериодРегистрации
            И Осн.Сотрудник = Доп.Сотрудник

СГРУППИРОВАТЬ ПО
    Осн.ПериодРегистрации,
    Осн.Сотрудник

УПОРЯДОЧИТЬ ПО
    Сотрудник

(1)

(2) таки предположу что период регистрации разный и возможно его надо привести к одному значению. Насколько я помню у основных начислений начало месяца вообще, а у доп. когда угодно. Но ЗУП я не помню, это вариант. При суммировании не забудь ЕСТЬNULL

а если вдруг есть доп начисление а нет основного? и проверку на null не помешало бы, а то значение + null = null

возможно лучше объединить + сгруппировать

(2) Нужно пользоваться виртуальными таблицами.

(7) а можно поподробней? я еще стажер просто..(

(7) при выборке из 2-х разных регистров чем они помогут, а из регистров расчета итоговые данные обычно из физических таблиц берут

(0)
ВЫБРАТЬ
    Начисления.Сотрудник,
    СУММА(Начисления.Результат) КАК Результат
ИЗ
    (ВЫБРАТЬ
        ОсновныеНачисленияРаботниковОрганизаций.Сотрудник КАК Сотрудник,
        ОсновныеНачисленияРаботниковОрганизаций.Результат КАК Результат
    ИЗ
        РегистрРасчета.ОсновныеНачисленияРаботниковОрганизаций КАК ОсновныеНачисленияРаботниковОрганизаций
    ГДЕ
        ОсновныеНачисленияРаботниковОрганизаций.Организация = &Организация
        И ОсновныеНачисленияРаботниковОрганизаций.ПериодРегистрации МЕЖДУ &ДатаНачала И &ДатаОкончания
    
    ОБЪЕДИНИТЬ ВСЕ
    
    ВЫБРАТЬ
        ДополнительныеНачисленияРаботниковОрганизаций.Сотрудник,
        ДополнительныеНачисленияРаботниковОрганизаций.Результат
    ИЗ
        РегистрРасчета.ДополнительныеНачисленияРаботниковОрганизаций КАК ДополнительныеНачисленияРаботниковОрганизаций
    ГДЕ
        ДополнительныеНачисленияРаботниковОрганизаций.Организация = &Организация
        И ДополнительныеНачисленияРаботниковОрганизаций.ПериодРегистрации МЕЖДУ &ДатаНачала И &ДатаОкончания) КАК Начисления

СГРУППИРОВАТЬ ПО
    Начисления.Сотрудник

(2) Левое соединение здесь совершенно не нужно. Нужно использовать объединить

(10) да, но это надо во вложенный или в вт и потом сгруппировать, по задумке тс

(8) твоей проблеме это в данный момент не поможет :)
Проверь отдельно значения полей, по которым соединяешь, и увидишь, что они различаются

(10) а вдруг ей надо с периодами?

если уж соединение то полное, но на null каждое поле надо проверять

(13) Добавить периоды, убрать отборы если надо

(14) Посмотрите как подобные запросы делаются в типовых. Полное соединение никогда не используется. Оно будет работать медленнее чем объединить, да еще и проверку на Null надо добавлять.

(16) я изначально так и предложил

(10) уфф, сейчас попробую

(15) И еще периоды надо привести к началу месяца, например. Я о том и пишу. А зачем ей соединение, это не знаю. Вдруг так и задумано

(19) а период регистрации вроде изначально к началу месяца приведен

(20) В доп начислениях, вроде, нет, ЗУПа нет под рукой

(13) Нет же( одинаковые

(21) ну может быть...

(20)(21)
В регистре "ОсновныеНачисленияРаботниковОрганизаций" период регистрации приведен к началу месяца, в регистре "ДополнительныеНачисленияРаботниковОрганизаций" - нет.
Если в качестве "ДатаНачала" использовать Дату начала месяца, а в качестве "ДатаОкончания" использовать Дату окончания месяца, то периоды не нужно приводить к началу месяца.
Лучше один раз задать правильно параметры запроса, чем выполнять функцию преобразования периода для каждой записи регистра. Будет быстрее работать.

(19)Соединение там используется по "не знанию".

Мне по сути просто сказали сделать так, чтобы были след колонки:

Период регистрации/ Сотрудник/ Результат/

где результат это сумма осн и доп начислений. Может это можно вообще как-то проще реализовать??

(24) если надо сгруппировать в разрезе периодов а параметры за несколько периодов, то все равно преобразовывать

(27) Согласен

(26)
ВЫБРАТЬ
    Начисления.ПериодРегистрации,
    Начисления.Сотрудник,
    СУММА(Начисления.Результат) КАК Результат
ИЗ
    (ВЫБРАТЬ
        ОсновныеНачисленияРаботниковОрганизаций.ПериодРегистрации КАК ПериодРегистрации,
        ОсновныеНачисленияРаботниковОрганизаций.Сотрудник КАК Сотрудник,
        ОсновныеНачисленияРаботниковОрганизаций.Результат КАК Результат
    ИЗ
        РегистрРасчета.ОсновныеНачисленияРаботниковОрганизаций КАК ОсновныеНачисленияРаботниковОрганизаций
    ГДЕ
        ОсновныеНачисленияРаботниковОрганизаций.Организация = &Организация
        И ОсновныеНачисленияРаботниковОрганизаций.ПериодРегистрации МЕЖДУ &ДатаНачала И &ДатаОкончания
    
    ОБЪЕДИНИТЬ ВСЕ
    
    ВЫБРАТЬ
        НАЧАЛОПЕРИОДА(ДополнительныеНачисленияРаботниковОрганизаций.ПериодРегистрации, МЕСЯЦ),
        ДополнительныеНачисленияРаботниковОрганизаций.Сотрудник,
        ДополнительныеНачисленияРаботниковОрганизаций.Результат
    ИЗ
        РегистрРасчета.ДополнительныеНачисленияРаботниковОрганизаций КАК ДополнительныеНачисленияРаботниковОрганизаций
    ГДЕ
        ДополнительныеНачисленияРаботниковОрганизаций.Организация = &Организация
        И ДополнительныеНачисленияРаботниковОрганизаций.ПериодРегистрации МЕЖДУ &ДатаНачала И &ДатаОкончания) КАК Начисления

СГРУППИРОВАТЬ ПО
    Начисления.Сотрудник,
    Начисления.ПериодРегистрации

УПОРЯДОЧИТЬ ПО
    Начисления.ПериодРегистрации,
    Начисления.Сотрудник.Наименование

Проще некуда

(0) Создать? А уверена, что типового нет с нужным функционалом?

(30) Ну это мне заданька, я стажеруюсь) даже если и есть типовая, мне в любом случае надо самой написать)

а запрос из Расчетного листка посмотреть?

(32) убил