Сложное условие на СКД

Дошли руки сделать набросок решения задачи, может кому пригодится:
На форме ТЗ СписокКомпетенция (Компетенция (Спр), Отбор (ТипОбластиОформленияВидСравнения), Оценка (Число))

И Отчет (ТабличныйДокумент)

&НаКлиенте
Функция КорректировкаСравнения(ТекстЗапроса)
ТекстЗапроса = СтрЗаменить(ТекстЗапроса,"Больше или равно",">=");
ТекстЗапроса = СтрЗаменить(ТекстЗапроса,"Меньше или равно","<=");
ТекстЗапроса = СтрЗаменить(ТекстЗапроса,"Не равно","<>");
ТекстЗапроса = СтрЗаменить(ТекстЗапроса,"Равно","=");
ТекстЗапроса = СтрЗаменить(ТекстЗапроса,"Меньше","<");
ТекстЗапроса = СтрЗаменить(ТекстЗапроса,"Больше",">");

Возврат ТекстЗапроса;
КонецФункции

&НаКлиенте
Процедура Сформировать(Команда)

МассивУсловийКомпетенции = Новый Массив;
МассивУсловийОценок = Новый Массив;

СтрокаГДЕ = "ГДЕ ";
СтрокаСоединение = "";
СтрокаПоляВыборки = "";
КолСоединений = 1;

Если ПоИли = Истина Тогда
    УсловияИ_Или = "ИЛИ";
Иначе
    УсловияИ_Или = "И";
КонецЕсли;

Для каждого Стр Из СписокКомпетенция Цикл

СтрПрефиксСоединения = "ВТ"+Строка(КолСоединений);
СтрокаСоединение = СтрокаСоединение + " ЛЕВОЕ СОЕДИНЕНИЕ ВТ КАК " + СтрПрефиксСоединения +
         " ПО ВТ.Кандидат = "+СтрПрефиксСоединения+".Кандидат " + Символы.ПС;

СтрокаГДЕ = СтрокаГДЕ + " " + СтрПрефиксСоединения+".Компетенция = &Компетенция"+СтрПрефиксСоединения;
СтрокаГДЕ = СтрокаГДЕ + " И " + СтрПрефиксСоединения+".Оценка "+ Строка(Стр.Отбор) +" &Оценка"+СтрПрефиксСоединения + Символы.ПС;

МассивУсловийКомпетенции.Добавить(Стр.Компетенция);
МассивУсловийОценок.Добавить(Стр.Оценка);

СтрокаГДЕ = СтрокаГДЕ + " " + УсловияИ_Или;

СтрокаПоляВыборки = СтрокаПоляВыборки + "," + СтрПрефиксСоединения+".Компетенция КАК Компетенция"+СтрПрефиксСоединения + Символы.ПС +
                                        "," + СтрПрефиксСоединения+".Оценка КАК Оценка"+СтрПрефиксСоединения + Символы.ПС;


КолСоединений = КолСоединений + 1;

КонецЦикла;

ТекстЗапрос = "ВЫБРАТЬ
               |    КомпетенцииКандидатовСрезПоследних.Кандидат,
               |    КомпетенцииКандидатовСрезПоследних.Компетенция,
               |    КомпетенцииКандидатовСрезПоследних.Оценка
               |ПОМЕСТИТЬ ВТ
               |ИЗ
               | РегистрСведений.КомпетенцииКандидатов.СрезПоследних(&МоментВремени, ) КАК КомпетенцииКандидатовСрезПоследних
               |;
               |
              |////////////////////////////////////////////////////////////////////////////////
               |ВЫБРАТЬ
               |    ВТ.Кандидат КАК Кандидат
               | //ПоляВыборки
               |ИЗ
               |    ВТ КАК ВТ
               |";

Если КолСоединений <> 1 Тогда
СтрокаГДЕ = Лев(СтрокаГДЕ, СтрДлина(СтрокаГДЕ)-СтрДлина(УсловияИ_Или));

ТекстЗапрос = ТекстЗапрос + СтрокаСоединение + СтрокаГДЕ;
КорректировкаСравнения(ТекстЗапрос);
ТекстЗапрос = СтрЗаменить(ТекстЗапрос,"//ПоляВыборки",СтрокаПоляВыборки);
КонецЕсли;

ТабДок = СформироватьОтчет(ТекстЗапрос,МассивУсловийКомпетенции,МассивУсловийОценок);

Отчет = ТабДок;

КонецПроцедуры

&НаСервере
Функция СформироватьОтчет(ТекстЗапроса,МассивУсловияКомпетенция,МассивУсловияОценок)

    СхемаКомпоновкиДанных = Новый СхемаКомпоновкиДанных;

    Источник = СхемаКомпоновкиДанных.ИсточникиДанных.Добавить();
    Источник.Имя = "ЛокальнаяБаза";
    Источник.СтрокаСоединения = "";
    Источник.ТипИсточникаДанных = "Local";

    НаборДанных = СхемаКомпоновкиДанных.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));
    НаборДанных.Имя = "Кандидат";
    НаборДанных.ИсточникДанных = "ЛокальнаяБаза";
    НаборДанных.АвтоЗаполнениеДоступныхПолей = Истина;
    НаборДанных.Запрос = ТекстЗапроса;


   КомпНастроек = Новый КомпоновщикНастроекКомпоновкиДанных;
   КомпНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаКомпоновкиДанных));
   КомпНастроек.ЗагрузитьНастройки(СхемаКомпоновкиДанных.НастройкиПоУмолчанию);

   ПараметрСКД = КомпНастроек.Настройки.ПараметрыДанных.Элементы.Найти("МоментВремени");
   ПараметрСКД.Использование = Истина;
   ПараметрСКД.Значение  = ТекущаяДата();

   Для ИндексСтрока = 0 По МассивУсловияКомпетенция.Количество() - 1 Цикл

       ПараметрСКД = КомпНастроек.Настройки.ПараметрыДанных.Элементы.Найти("КомпетенцияВТ" + Строка(ИндексСтрока+1));
       ПараметрСКД.Использование = Истина;
       ПараметрСКД.Значение  = МассивУсловияКомпетенция[ИндексСтрока];

       ПараметрСКД = КомпНастроек.Настройки.ПараметрыДанных.Элементы.Найти("ОценкаВТ" + Строка(ИндексСтрока+1));
       ПараметрСКД.Использование = Истина;
       ПараметрСКД.Значение  = МассивУсловияОценок[ИндексСтрока];

   КонецЦикла;



    ПолеОтчета = НаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));
    ПолеОтчета.Заголовок = "Кандидат";
    ПолеОтчета.ПутьКДанным = "Кандидат";
    ПолеОтчета.Поле = "Кандидат";

    //добавить группировку
    ГруппировкаПоКандидат =  КомпНастроек.Настройки.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));
    ГруппировкаПоКандидат.Имя = "Кандидат";
    ГруппировкаПоКандидат.Использование = Истина;

    //созданная группировка по полю "ТО"
    ПолеГруппировки = ГруппировкаПоКандидат.ПоляГруппировки.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
    ПолеГруппировки.Использование      = Истина;
    ПолеГруппировки.Поле               = Новый ПолеКомпоновкиДанных("Кандидат");
    ПолеГруппировки.ТипГруппировки = ТипГруппировкиКомпоновкиДанных.Элементы;
    ПолеГруппировки.ТипДополнения      = ТипДополненияПериодаКомпоновкиДанных.БезДополнения;

    //добавить выводимые поля в группировке: склад и количество остаток для данной группировки
    АвтоПоле = ГруппировкаПоКандидат.Выбор.Элементы.Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));
    АвтоПоле.Использование = Истина;

      Для ИндексСтрока = 0 По МассивУсловияКомпетенция.Количество() - 1 Цикл

        ПолеОтчета = НаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));
        ПолеОтчета.Заголовок = "Компетенция" + Строка(ИндексСтрока+1);
        ПолеОтчета.ПутьКДанным = "КомпетенцияВТ" + Строка(ИндексСтрока+1);
        ПолеОтчета.Поле = "КомпетенцияВТ" + Строка(ИндексСтрока+1);

        ПолеОченка = НаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));
        ПолеОченка.Заголовок = "Оценка" + Строка(ИндексСтрока+1);
        ПолеОченка.ПутьКДанным = "ОценкаВТ" + Строка(ИндексСтрока+1);
        ПолеОченка.Поле = "ОценкаВТ" + Строка(ИндексСтрока+1);

        ПолеГруппировки = ГруппировкаПоКандидат.ПоляГруппировки.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
        ПолеГруппировки.Использование = Истина;
            ПолеГруппировки.Поле = Новый ПолеКомпоновкиДанных("КомпетенцияВТ" + Строка(ИндексСтрока+1));

        ПолеГруппировки = ГруппировкаПоКандидат.ПоляГруппировки.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
        ПолеГруппировки.Использование = Истина;
        ПолеГруппировки.Поле = Новый ПолеКомпоновкиДанных("ОценкаВТ" + Строка(ИндексСтрока+1));

        КонецЦикла;


    ДетальныеЗаписи = ГруппировкаПоКандидат.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));
    ДетальныеЗаписи.Имя = "Детальные";
    ДетальныеЗаписи.Использование = Истина;

    //добавить автополе в группировку детальные
    АвтоПоле = ДетальныеЗаписи.Выбор.Элементы.Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));
    АвтоПоле.Использование = Истина;





    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    Макет = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, КомпНастроек.Настройки);

    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(Макет);
    ПроцессорКомпоновки.Сбросить();

    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ТабДок = Новый ТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ТабДок);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);

    Возврат ТабДок;


КонецФункции