Подскажите новичку в 1С8. Где ошибка?
Запрос = Новый Запрос;
        Запрос.Текст=
        "ВЫБРАТЬ
        |    РеализацияТоваровУслуг.Ссылка КАК РеализацияТоваровУслуг,
        |    РеализацияТоваровУслуг.СуммаДокумента КАК СуммаДокумента1,
        |    ПриходныйКассовыйОрдер.СуммаДокумента КАК СуммаДокумента3,
        |    ПриходныйКассовыйОрдер.Ссылка КАК ПриходныйКассовыйОрдер
        |ИЗ
        |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        |        ПОЛНОЕ СОЕДИНЕНИЕ Документ.ПриходныйКассовыйОрдер КАК ПриходныйКассовыйОрдер
        |        ПО РеализацияТоваровУслуг.Ссылка = ПриходныйКассовыйОрдер.ДокументОснование.Ссылка


Не выходит полное соединение
//  ИмяИзТаблицы1   ИмяИзТаблицы2  
//  Реализация1           Приходник1          
//  Реализация2           Приходник2          
//  Реализация3           NULL            
//  Реализация4           NULL            NULL
//  NULL            Приходник3           25
//  NULL            Приходник4           30
А выходит
//  ИмяИзТаблицы1   ИмяИзТаблицы2  
//  Реализация1           Приходник1          
//  Реализация2           Приходник2    
с NULL выходят.

Вернее с NULL не выходит

Это весь текст запроса?

Судя по отсутствию закрывающей кавычки - нет. Так вот проблема в отрезанном хвосте

Запрос = Новый Запрос;
        Запрос.Текст=
        "ВЫБРАТЬ
        |    РеализацияТоваровУслуг.Ссылка КАК РеализацияТоваровУслуг,
        |    РеализацияТоваровУслуг.СуммаДокумента КАК СуммаДокумента1,
        |    ПриходныйКассовыйОрдер.СуммаДокумента КАК СуммаДокумента3,
        |    ПриходныйКассовыйОрдер.Ссылка КАК ПриходныйКассовыйОрдер
        |ИЗ
        |    Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
        |        ПОЛНОЕ СОЕДИНЕНИЕ Документ.ПриходныйКассовыйОрдер КАК ПриходныйКассовыйОрдер
        |        ПО РеализацияТоваровУслуг.Ссылка = ПриходныйКассовыйОрдер.ДокументОснование.Ссылка
        |ГДЕ";
        Если ЗначениеЗаполнено(Склад) Тогда
            Запрос.Текст = Запрос.Текст + "
        |    РеализацияТоваровУслуг.Ссылка.Склад В ИЕРАРХИИ(&Склад) И";
        КонецЕсли;    
        Если ЗначениеЗаполнено(Касса) Тогда
            Запрос.Текст = Запрос.Текст + "
        |    ПриходныйКассовыйОрдер.Ссылка.Касса В ИЕРАРХИИ(&Касса) И";
        КонецЕсли;    
        Если ТолькоПроведенные = Истина Тогда
            Запрос.Текст = Запрос.Текст + "
        |    РеализацияТоваровУслуг.Ссылка.Проведен И
        |    ПриходныйКассовыйОрдер.Ссылка.Проведен И";
        КонецЕсли;    
        Запрос.Текст =Запрос. Текст + "
        |    РеализацияТоваровУслуг.Ссылка.Дата МЕЖДУ &Дата1 И &Дата2
        |   И Не РеализацияТоваровУслуг.Ссылка.ПометкаУдаления
        |    И ПриходныйКассовыйОрдер.Ссылка.Дата МЕЖДУ &Дата1 И &Дата2
        |   И Не ПриходныйКассовыйОрдер.Ссылка.ПометкаУдаления
        |";

Пробывал с
        //|ИТОГИ ПО
        //|    ОБЩИЕ,
        //|    РеализацияТоваровУслуг";
        //    |";
Пробывал с Группировками

Ну конечно.

При наложении условий в "ГДЕ" проверки проводятся после соединения. И так как NULL не попадает в условие, то эти строки фильтруются.

Либо во все условия включаешь "ИЛИ NULL", либо фильтруешь всё до (или во время) слияния.

(5) А примере можете показать?

(5) Спасибо буду пробывать

(6) Через вложенный запрос, например:


ВЫБРАТЬ
    РеализацияТоваровУслуг.Ссылка КАК РеализацияТоваровУслуг,
    РеализацияТоваровУслуг.СуммаДокумента КАК СуммаДокумента1,
    ПриходныйКассовыйОрдер.Ссылка КАК ПриходныйКассовыйОрдер
ИЗ
    (ВЫБРАТЬ
        РеализацияТоваровУслуг.Ссылка КАК Ссылка,
        РеализацияТоваровУслуг.Дата КАК Дата,
        РеализацияТоваровУслуг.Склад КАК Склад,
        РеализацияТоваровУслуг.СуммаДокумента КАК СуммаДокумента
    ИЗ
        Документ.РеализацияТоваровУслуг КАК РеализацияТоваровУслуг
    ГДЕ
        РеализацияТоваровУслуг.Ссылка.Склад В ИЕРАРХИИ(&Склад)
        И РеализацияТоваровУслуг.Ссылка.Проведен
        И РеализацияТоваровУслуг.Ссылка.Дата МЕЖДУ &Дата1 И &Дата2
        И НЕ РеализацияТоваровУслуг.Ссылка.ПометкаУдаления) КАК РеализацияТоваровУслуг
        ПОЛНОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
            ПриходныйКассовыйОрдер.Ссылка КАК Ссылка,
            ПриходныйКассовыйОрдер.Дата КАК Дата,
            ПриходныйКассовыйОрдер.СуммаДокумента КАК СуммаДокумента,
            ПриходныйКассовыйОрдер.ДокументОснование КАК ДокументОснование
        ИЗ
            Документ.ПриходныйКассовыйОрдер КАК ПриходныйКассовыйОрдер
        ГДЕ
            ПриходныйКассовыйОрдер.Ссылка.Проведен
            И ПриходныйКассовыйОрдер.Ссылка.Дата МЕЖДУ &Дата1 И &Дата2
            И НЕ ПриходныйКассовыйОрдер.Ссылка.ПометкаУдаления) КАК ПриходныйКассовыйОрдер
        ПО РеализацияТоваровУслуг.Ссылка = ПриходныйКассовыйОрдер.ДокументОснование


Вложенные запросы фильтруются по условиям, результат сливается. Для наглядности можно вложенные запросы вынести во временные таблицы

ПробЫвать не пиши лучше

(9) ok)

(10) Главное понять ;)

Спасибо всем. Получилось