Добрый день,стоит задача -подключится к базе 1 через созданный в ней http сервис,получить остатки и передать их в базу 2..
Сервис создал,опубликовал...а вот что дальше ?если кто делал подобное-приведите пример или ткните кудой рыть?

(0) сервис работает?

да,сервис работает..

где запрос писать на остатки?как его передать?

(3) начни от сюда: Обращение к веб-сервису 1С

(2) Ну пиши в модуле сервиса код, который выгребет из БД необходимые данные, превратит их в структурированную строку (JSON, например), и отдаст в базу-потребителя.

(5) а я думал, остатки должен сервис вернуть.

(6) Ну а как он их будет возвращать? Строкой.

(7) как надо так и вернет, строкой можно GUID передать или другой идентификационный реквизит.

(8) Все правильно, я так в (5) и написал.

(9) Да-да, сори, я чет подзатупил.

(4) там идет обращение через браузер,а мне нужно из одной базы
обратится к сервису другой...приведите пример кода плз,

(5) запрос на нужные остатки  запросто,а вот как их предавать и обрабатывать-полный тупик

(11) http://catalog.mista.ru/public/327963/

http://programmist1s.ru/web-servisyi-v-1s/

https://www.yandex.ru/yandsearch?rpt=rad&text=1C%20Получение%20остатков%20из%20соседней%20базй%201с%208.3%20через%20Http%20сервис&lr=213

(11) Нет разницы, через браузер или из базы. В базе-потребителе надо делать http-запрос через объект HTTPСоединение.Получить()

https://its.1c.ru/db/metod8dev#content:5574:hdoc

да..уж..(

(18) Что не так-то?

да нет,все так...но конкретного примера кода именно с http сервисом так и не нашел..

(20) "HTTPСоединение.Получить()", выполненное в одной базе - это и есть запрос к http-сервису в другой базе.

(21) спасибо,попытаюсь..надеюсь получится..реализован данный механизм уже на ком соединениии и прекрасно работает,но руководство сказало переделать на http

(22) Правильно сказало.

Результат можно передавть через хранилище значения в XML. Так можно использовать таблицы значений и другие типы, которые в JSON не сериализуются плюс степень сжатия.

(23) А зачем хранилище значения в XML еще конвертить? Можно просто передать его как двоичные данные.

зачем вообще хранилищами обмениваться?

(25) +100500

(26) да,не стоит этого делать

(24) (25)

У меня было много данных в ТЗ и встроенные в конфигурацию процедуры взаимодействия с HTTP сервисами, в том числе не 1С, в формате JSON.

Видимо чтобы между сервисами 1С передавать ТЗ через JSON без конвертации в структуры. В JSON ТЗ только так получилось впихнуть.

Функция ОсновнойGET(Запрос)
    Ответ = Новый HTTPСервисОтвет(200);
    Ответ.УстановитьТелоИзСтроки(ВернутьОстатки());
    Возврат Ответ;
КонецФункции

Функция ВернутьОстатки()
    Запрос = Новый Запрос;
    Запрос.Текст =
    " ";
    Выборка = Запрос.Выполнить().Выбрать();
    ОтветМассив = Новый Массив;
    Пока Выборка.Следующий() Цикл
        ОтветМассив.Добавить(Новый Структура("tovar,ostatok",Выборка.Ссылка.Товар,""+Выборка.Ссылка.Остаток));
    КонецЦикла;
    
    Ответ = Новый ЗаписьJSON;
    Ответ.УстановитьСтроку();
    ЗаписатьJSON(Ответ,ОтветМассив); // сериализует ОтветМассив в формат JSON
    Возврат Ответ.Закрыть();
КонецФункции

вот пытаюсь делать каки то наметки..как обработать в базе получателе как Ответ?

(29) Вот именно.
Когда таких колонок over 9000 и структура в базе источнике и приёмнике одинаковая,

    ОтветМассив.Добавить(Новый Структура("

начинает, мягко говоря, надоедать.

Хочется просто использовать Загрузить/Выгрузить. Ну и плюс сжатие как я говорил.

(31) Про

    Выборка.Ссылка.Товар, Выборка.Ссылка.Остаток

скромно умолчу))

(32) да фиг с ней Выборка.Ссылка.Товар,тыщу раз еще запрос перепишу..как в базе приемнике обработать получить и обработать Отввет?

(33) Ответ

(33) HTTPСоединение.Получить() вернет тебе объект HTTPОтвет, а в его теле будет лежать твой JSON.

HTTPОтвет.ПолучитьТелоКакСтроку()

HTTP соединение еще создать нужно?каков синтаксис? если не сложно подскажите..плз

&НаКлиенте
Процедура ВыполнитьЗапрос(Команда)
    ВыполнитьHTTPЗапрос("http://example.com";);
КонецПроцедуры

&НаКлиенте
Процедура ВыполнитьHTTPЗапрос(ПолныйАдресРесурса)
    СтруктураURI = СтруктураURI(ПолныйАдресРесурса);
    HTTPСоединение = Новый HTTPСоединение(СтруктураURI.Хост, СтруктураURI.Порт);
    
    HTTPЗапрос = Новый HTTPЗапрос(СтруктураURI.ПутьНаСервере);
    Попытка
        Результат =  HTTPСоединение.Получить(HTTPЗапрос);
    Исключение
         // исключение здесь говорит о том, что запрос не дошел до HTTP-Сервера
         Сообщить("Произошла сетевая ошибка!");
         ВызватьИсключение;
     КонецПопытки;
    
     // Анализируем фатальные ошибки
     // В большинстве случаев нужно остановить работу и показать пользователю сообщение об ошибке,
     // включив в него HTTP-статус
    
     // Ошибки 4XX говорят о неправильном запросе - в широком смысле
     // Может быть неправильный адрес, ошибка аутентификации, плохой формат запроса
     // Подробнее смотри http://www.w3.org/Protocols/rfc2616/rfc2616-sec10.html#sec10.4
     Если Результат.КодСостояния >= 400 и Результат.КодСостояния < 500  Тогда
            Сообщить("Код статуса больше 4XX, ошибка запроса.  Код статуса: " + Результат.КодСостояния);
     КонецЕсли;
    
     // Ошибки 5XX говорят о проблемах на сервере (возможно, прокси-сервер)
     // Это может быть программная ошибка, нехватка памяти, ошибка конфигурации и т.д.
     // Подробнее смотри http://www.w3.org/Protocols/rfc2616/rfc2616-sec10.html#sec10.5
     Если Результат.КодСостояния >= 500 и Результат.КодСостояния < 600  Тогда
            Сообщить("Код статуса больше 5XX, ошибка сервера. Код статуса: " + Результат.КодСостояния);
     КонецЕсли;
    
     // Обрабатываем перенаправление
     Если Результат.КодСостояния >= 300 и Результат.КодСостояния < 400  Тогда
            Сообщить("Код статуса больше 3XX, Перенаправление. Код статуса: " + Результат.КодСостояния);
         Если Результат.КодСостояния = 302 Тогда
              Сообщить("Код статуса 302, Постоянное перенаправление.");
              АдресРесурса = Результат.Заголовки.Получить("Location");
              Если АдресРесурса <> Неопределено Тогда
                  Сообщить("Выполняю запрос по новому адресу " + АдресРесурса);
                  ВыполнитьHTTPЗапрос(АдресРесурса);
              Иначе
                  Сообщить("Сервер не сообщил адрес ресурса!");
              КонецЕсли;
         КонецЕсли;
     КонецЕсли;
     // Статусы 1XX и 2XX считаем хорошими
     Если Результат.КодСостояния < 300 Тогда
           Сообщить("Скорее всего все хорошо");    
           Сообщить("Код статуса: " + Результат.КодСостояния);    
     КонецЕсли;
КонецПроцедуры

  &НаКлиенте
Функция СтруктураURI(Знач СтрокаURI) Экспорт
    
    СтрокаURI = СокрЛП(СтрокаURI);
    
    // схема
    Схема = "";
    Позиция = Найти(СтрокаURI, "://");
    Если Позиция > 0 Тогда
        Схема = НРег(Лев(СтрокаURI, Позиция - 1));
        СтрокаURI = Сред(СтрокаURI, Позиция + 3);
    КонецЕсли;

    // строка соединения и путь на сервере
    СтрокаСоединения = СтрокаURI;
    ПутьНаСервере = "";
    Позиция = Найти(СтрокаСоединения, "/");
    Если Позиция > 0 Тогда
        ПутьНаСервере = Сред(СтрокаСоединения, Позиция + 1);
        СтрокаСоединения = Лев(СтрокаСоединения, Позиция - 1);
    КонецЕсли;
        
    // информация пользователя и имя сервера
    СтрокаАвторизации = "";
    ИмяСервера = СтрокаСоединения;
    Позиция = Найти(СтрокаСоединения, "@");
    Если Позиция > 0 Тогда
        СтрокаАвторизации = Лев(СтрокаСоединения, Позиция - 1);
        ИмяСервера = Сред(СтрокаСоединения, Позиция + 1);
    КонецЕсли;
    
    // логин и пароль
    Логин = СтрокаАвторизации;
    Пароль = "";
    Позиция = Найти(СтрокаАвторизации, ":");
    Если Позиция > 0 Тогда
        Логин = Лев(СтрокаАвторизации, Позиция - 1);
        Пароль = Сред(СтрокаАвторизации, Позиция + 1);
    КонецЕсли;
    
    // хост и порт
    Хост = ИмяСервера;
    Порт = "";
    Позиция = Найти(ИмяСервера, ":");
    Если Позиция > 0 Тогда
        Хост = Лев(ИмяСервера, Позиция - 1);
        Порт = Сред(ИмяСервера, Позиция + 1);
    КонецЕсли;
    
    Результат = Новый Структура;
    Результат.Вставить("Схема", Схема);
    Результат.Вставить("Логин", Логин);
    Результат.Вставить("Пароль", Пароль);
    Результат.Вставить("ИмяСервера", ИмяСервера);
    Результат.Вставить("Хост", Хост);
    Результат.Вставить("Порт", ?(Порт <> "", Число(Порт), Неопределено));
    Результат.Вставить("ПутьНаСервере", ПутьНаСервере);
    
    Возврат Результат;
    
КонецФункции

(38) спасибо..кажись пошел процесс..

(36) точно..ничего сложного)

(40) ну когда разберешся))

спасибо всем)

На здоровье )