Добрый день.
Суть проблемы такая: не получается установить отбор у динамического списка, вот код:

Процедура УстановитьОтборВСписке(Список,ИмяПоля,ПравоеЗначение,ВидСравнения) Экспорт    
    УдалитьОтборВСписке(СПисок,ИмяПоля);
    НовОтб=Список.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    НовОтб.Использование=Истина;
    НовОтб.ЛевоеЗначение=Новый ПолеКомпоновкиДанных(ИмяПоля);
    НовОтб.ВидСравнения=ВидСравнения;
    НовОтб.РежимОтображения=РежимОтображенияЭлементаНастройкиКомпоновкиДанных.БыстрыйДоступ;
    НовОтб.ПравоеЗначение=ПравоеЗначение;
КонецПроцедуры

Причем раньше этот код работал на ура, но после обновления платформы видимо что то поменялось.

Вот кстати накопал на форуме такую же проблему, но там так никто и не ответил толком

Перестал работать отбор

(3) тогда давай ответ на вопрос в (1) из этой ветки

(4)Причем когда открываю отбор этого списка (в режиме 1с предприятие), то там всё есть и после того как в окне отбора нажимаю "ОК", то отбор происходит таки.

(4) у меня отбор по полю типа "булево", должны отображаться строки без галочки, а отображаются все.

пробовал после этого кода делать ОбновитьОтображениеДанных(), но результат тот же

на клиенте или на серевере код?

получается что не хватает вот этого самого нажатия кнопки "ОК", но только программно.

(8) Код выполняется на сервере

Нужно не Список.Отбор, а (из типовой кусок)
    Если РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный Тогда
        ОтборДинамическогоСписка = ДинамическийСписок.КомпоновщикНастроек.ФиксированныеНастройки.Отбор;
    Иначе
        ОтборДинамическогоСписка = ДинамическийСписок.КомпоновщикНастроек.Настройки.Отбор;
    КонецЕсли;

ну и вообще
ОбщегоНазначенияКлиентСервер.УстановитьЭлементОтбораДинамическогоСписка

(12) У нас УТ 11.0 старая, там это в другом модуле (кстати код взят именно оттуда)


Процедура УстановитьЭлементОтбораДинамическогоСписка(ДинамическийСписок, ИмяПоля,
    ПравоеЗначение = Неопределено,
    ВидСравнения = Неопределено,
    Представление = Неопределено,
    Использование = Неопределено,
    РежимОтображения = Неопределено,
    ИдентификаторПользовательскойНастройки = Неопределено) Экспорт
    
    Если РежимОтображения = Неопределено Тогда
        РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный;
    КонецЕсли;
    
    Если РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный Тогда
        ОтборДинамическогоСписка = ДинамическийСписок.КомпоновщикНастроек.ФиксированныеНастройки.Отбор;
    Иначе
        ОтборДинамическогоСписка = ДинамическийСписок.КомпоновщикНастроек.Настройки.Отбор;
    КонецЕсли;
    
    УстановитьЭлементОтбора(
        ОтборДинамическогоСписка,
        ИмяПоля,
        ПравоеЗначение,
        ВидСравнения,
        Представление,
        Использование,
        РежимОтображения,
        ИдентификаторПользовательскойНастройки);
    
КонецПроцедуры

Процедура УстановитьЭлементОтбора(ОбластьПоискаДобавления,
                                Знач ИмяПоля,
                                Знач ПравоеЗначение = Неопределено,
                                Знач ВидСравнения = Неопределено,
                                Знач Представление = Неопределено,
                                Знач Использование = Неопределено,
                                Знач РежимОтображения = Неопределено,
                                Знач ИдентификаторПользовательскойНастройки = Неопределено) Экспорт
    
    ЧислоИзмененных = ИзменитьЭлементыОтбора(ОбластьПоискаДобавления, ИмяПоля, Представление,
                            ПравоеЗначение, ВидСравнения, Использование, РежимОтображения, ИдентификаторПользовательскойНастройки);
    
    Если ЧислоИзмененных = 0 Тогда
        Если ВидСравнения = Неопределено Тогда
            Если ТипЗнч(ПравоеЗначение) = Тип("Массив")
                Или ТипЗнч(ПравоеЗначение) = Тип("ФиксированныйМассив")
                Или ТипЗнч(ПравоеЗначение) = Тип("СписокЗначений") Тогда
                ВидСравнения = ВидСравненияКомпоновкиДанных.ВСписке;
            Иначе
                ВидСравнения = ВидСравненияКомпоновкиДанных.Равно;
            КонецЕсли;
        КонецЕсли;
        Если РежимОтображения = Неопределено Тогда
            РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный;
        КонецЕсли;
        ДобавитьЭлементКомпоновки(ОбластьПоискаДобавления, ИмяПоля, ВидСравнения,
                                ПравоеЗначение, Представление, Использование, РежимОтображения, ИдентификаторПользовательскойНастройки);
    КонецЕсли;
    
КонецПроцедуры

Функция ДобавитьЭлементКомпоновки(ОбластьДобавления,
                                    Знач ИмяПоля,
                                    Знач ВидСравнения,
                                    Знач ПравоеЗначение = Неопределено,
                                    Знач Представление  = Неопределено,
                                    Знач Использование  = Неопределено,
                                    знач РежимОтображения = Неопределено,
                                    знач ИдентификаторПользовательскойНастройки = Неопределено) Экспорт
    
    Элемент = ОбластьДобавления.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
    Элемент.ЛевоеЗначение = Новый ПолеКомпоновкиДанных(ИмяПоля);
    Элемент.ВидСравнения = ВидСравнения;
    
    Если РежимОтображения = Неопределено Тогда
        Элемент.РежимОтображения = РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный;
    Иначе
        Элемент.РежимОтображения = РежимОтображения;
    КонецЕсли;
    
    Если ПравоеЗначение <> Неопределено Тогда
        Если ТипЗнч(ПравоеЗначение) = Тип("Массив") Тогда
            Если ПравоеЗначение.Количество() = 1 Тогда
                Элемент.ПравоеЗначение         = ПравоеЗначение[0];
            ИначеЕсли ПравоеЗначение.Количество() > 1 Тогда
                ЗначениеСписок = Новый СписокЗначений;
                ЗначениеСписок.ЗагрузитьЗначения(ПравоеЗначение);
                Элемент.ПравоеЗначение         = ЗначениеСписок;
            Иначе
                Элемент.ПравоеЗначение         = ПравоеЗначение;
            КонецЕсли;
        Иначе
            Элемент.ПравоеЗначение         = ПравоеЗначение;
        КонецЕсли;
    КонецЕсли;
    
    Если Представление <> Неопределено Тогда
        Элемент.Представление = Представление;
    КонецЕсли;
    
    Если Использование <> Неопределено Тогда
        Элемент.Использование = Использование;
    КонецЕсли;
    
    // Важно: установка идентификатора должна выполняться
    // в конце настройки элемента, иначе он будет скопирован
    // в пользовательские настройки частично заполненным.
    Если ИдентификаторПользовательскойНастройки <> Неопределено Тогда
        Элемент.ИдентификаторПользовательскойНастройки = ИдентификаторПользовательскойНастройки;
    ИначеЕсли Элемент.РежимОтображения <> РежимОтображенияЭлементаНастройкиКомпоновкиДанных.Недоступный Тогда
        Элемент.ИдентификаторПользовательскойНастройки = ИмяПоля;
    КонецЕсли;
    
    Возврат Элемент;
    
КонецФункции




(12) щас гляну в БП типовой, она свежая

(14) вот спасибо, даже в БП похоже лезть не придется

(13) до версии 8.3.5 все было по другому

вы наверно режим совместимости изменили?

(18) режим совместимости не менял, просто обновили платформу, так как БП требовала свежую.

(0) В общем модуле современных конфигураций ОбщегоНазначенияКлиентСервер как написана эта процедура?