Привет всем
в версии 1С 8.3 при попытке сохранить файл вылетела ошибка Файл не обнаружен заходишь в подробно там пишет: Ошибка при вызове конструктора (ДвоичныеДанные)
вот код:

&НаКлиенте
Процедура ИмяФайлаНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
    диалог = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
    диалог.МножественныйВыбор = Ложь;
    диалог.Заголовок = "Выберите прикрепляемый файл";
    Если диалог.Выбрать() Тогда
        файл = Новый Файл(диалог.ПолноеИмяФайла);
        Запись.ИмяФайла = файл.Имя;
        ЗагрузитьФайл(ПоместитьВоВременноеХранилище(Новый ДвоичныеДанные(файл.Имя)));
        Элементы.ОткрытьФайл.Видимость = Истина;
        Если Не РольДоступнаПолныеПрава() Тогда
            Попытка
                ЭтаФорма.ВладелецФормы.Родитель.Элементы.Список.Обновить();
            Исключение
                
            КонецПопытки;
            ЭтаФорма.Закрыть();
        КонецЕсли;
    КонецЕсли;
КонецПроцедуры

тот же код свободно и без ошибок отрабатывает в 1С 8.2, не подскажите где копать? вроде все правильно
С уважением Дамир

Ну а так-то не то свойство объекта "Файл" берешь. Полное имя надо

Файл.ПолноеИмя?

(6) ну если такое поле есть, то да, если нет - то тот же диалог.ПолноеИмяФайла

а в 8.2 так же отработает?

База поди в другом месте лежит? Файлик лежит рядом с одной базой - она его по одному имени находит, а другая база лежит в другом месте и этот файл не находит

Файл.ПолноеИмя правильный вариант, спасибо всем

(9) Все на клиенте

(0) Вот примерно что у тебя должно быть

&НаКлиенте
Процедура СохранитьДеревоВФайл(Команда)
    
    ДиалогСохраненияФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Сохранение);
    ДиалогСохраненияФайла.Фильтр                      = "Файлы Дерева (*.tab) |*.tab";
    ДиалогСохраненияФайла.Заголовок                   = "Укажите имя файла для сохранения!";
    ДиалогСохраненияФайла.ПредварительныйПросмотр     = Ложь;
    ДиалогСохраненияФайла.МножественныйВыбор          = Ложь;
    ДиалогСохраненияФайла.Расширение                  = "tab";
    Если ДиалогСохраненияФайла.Выбрать() Тогда
        ФайлДанные = ИспользоватьВременныйФайл();
        ФайлДанные.Записать(ДиалогСохраненияФайла.ПолноеИмяФайла);
    КонецЕсли;    
    
КонецПроцедуры

&НаСервере
Функция ИспользоватьВременныйФайл()
    
    тДерево = РеквизитФормыВЗначение("ДеревоОстатков");
    
    Попытка
        ИмяВремФайл = ПолучитьИмяВременногоФайла();
        ВремФайл = Новый Файл(ИмяВремФайл);
        ЗначениеВФайл(ИмяВремФайл, тДерево);
        Если ВремФайл.Существует() Тогда
            ФайлДанные = Новый ДвоичныеДанные(ИмяВремФайл);
            Хранилище = Новый ХранилищеЗначения(ФайлДанные);
        КонецЕсли;
        УдалитьФайлы(КаталогВременныхФайлов(), ИмяВремФайл);
    Исключение
        ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ОписаниеОшибки()); //сообщение пользователю        
    КонецПопытки;
    
    Возврат Хранилище.Получить();
    
КонецФункции

(0) Вот тебе открытие

&НаКлиенте
Процедура ЗагрузитьДеревоИзФайла(Команда)
    
    ОписаниеОповещения = Новый ОписаниеОповещения("ОбработатьВыборФайла", ЭтаФорма);
    
    ДиалогОткрытияФайла = Новый ДиалогВыбораФайла(РежимДиалогаВыбораФайла.Открытие);
    ДиалогОткрытияФайла.Фильтр                      = "Файлы Дерева (*.tab) |*.tab";
    ДиалогОткрытияФайла.Заголовок                   = "Укажите имя файла для открытия!";
    ДиалогОткрытияФайла.ПредварительныйПросмотр     = Ложь;
    ДиалогОткрытияФайла.МножественныйВыбор          = Ложь;
    ДиалогОткрытияФайла.Расширение                  = "tab";
    
    НачатьПомещениеФайлов(ОписаниеОповещения, , ДиалогОткрытияФайла, Истина, УникальныйИдентификатор);
    
КонецПроцедуры

&НаКлиенте
Процедура ОбработатьВыборФайла(ПомещенныеФайлы, ДополнительныеПараметры) Экспорт

    Если ПомещенныеФайлы = Неопределено Тогда
        Возврат;
    КонецЕсли;

    Для каждого ПереданныйФайл Из ПомещенныеФайлы Цикл
        ВосстановитьДеревоНаФорме(ПереданныйФайл.Хранение);
    КонецЦикла;
    
КонецПроцедуры // ()

&НаСервере
Процедура ВосстановитьДеревоНаФорме(КлючФайлаДерево)
    
    Попытка
        ИмяВремФайл = ПолучитьИмяВременногоФайла();
        ФайлДанные = ПолучитьИзВременногоХранилища(КлючФайлаДерево);    
        ФайлДанные.Записать(ИмяВремФайл);

        тДерево = ЗначениеИзФайла(ИмяВремФайл);
    
        УдалитьФайлы(ИмяВремФайл);
        ЗначениеВРеквизитФормы(тДерево, "ДеревоОстатков");
    Исключение
        ОбщегоНазначенияКлиентСервер.СообщитьПользователю(ОписаниеОшибки()); //сообщение пользователю
    КонецПопытки;

КонецПроцедуры