Всем привет.

Подскажите как в типовых на СКД сделать такую штуку. Есть простой запрос к реквизитам объектов справочника "Контрагенты". И есть доп. свойства, что из регистра сведений ДополнительныеСведения. Нужно вывести эти свойства вместе с остальными реквизитами, чтобы свойства были в шапке таблицы, а значения этих свойств в строках с остальными реквизитами.

Начал писать запрос и что-то залип :)

ВЫБРАТЬ
    Контрагенты.Ссылка,
    Контрагенты.Код,
    Контрагенты.ИНН
    ДополнительныеСведения.Свойство КАК ДопСвойство,
    ДополнительныеСведения.Значение КАК ЗначениеДопСвойства
ИЗ
    Справочник.Контрагенты КАК Контрагенты
    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ДополнительныеСведения КАК
ДополнительныеСведения
ПО Контрагенты.Ссылка = ДополнительныеСведения.Объект

Это типа очень просто или очень сложно?)

В запросе СКД есть специальная закладка Характеристики.

ВЫБРАТЬ
    Контрагенты.Ссылка КАК Контрагент,
    ВидыСвойствОбъектов.ВидСвойства,
    ЗначенияСвойствОбъектов.Свойство
ИЗ Справочник.Контрагенты КАК Контрагенты
    ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ РАЗЛИЧНЫЕ
        ЗначенияСвойствОбъектов.Свойство.Наименование КАК ВидСвойства
    ИЗ
    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов) КАК ВидыСвойствОбъектов
        ПО (1 = 1)
    ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ РАЗЛИЧНЫЕ
        ЗначенияСвойствОбъектов.Объект КАК Контрагент,
        ЗначенияСвойствОбъектов.Свойство.Наименование КАК ВидСвойства,
        ЗначенияСвойствОбъектов.Значение КАК Свойство
    ИЗ
    РегистрСведений.ЗначенияСвойствОбъектов КАК ЗначенияСвойствОбъектов) КАК ЗначенияСвойствОбъектов
    ПО (ЗначенияСвойствОбъектов.Контрагент = Контрагенты.Ссылка)
    И (ВидыСвойствОбъектов.ВидСвойства = ЗначенияСвойствОбъектов.ВидСвойства)
ГДЕ
    НЕ Контрагенты.ЭтоГруппа

в настройках группировку колонок по ВидСвойства
в ресурсах Свойство с выражением ресурса = Свойство

(0) Вроде работало с БП 3, добавить к тексту запроса СКД:
{ХАРАКТЕРИСТИКИ
    ТИП(Справочник.Контрагенты)
    ВИДЫХАРАКТЕРИСТИК (ВЫБРАТЬ
            ДополнительныеРеквизитыИСведения.Ссылка,
            ДополнительныеРеквизитыИСведения.Наименование,
            ДополнительныеРеквизитыИСведения.ТипЗначения
        ИЗ
            ПланВидовХарактеристик.ДополнительныеРеквизитыИСведения КАК ДополнительныеРеквизитыИСведения
        ГДЕ
            ДополнительныеРеквизитыИСведения.НаборСвойств = ЗНАЧЕНИЕ(Справочник.НаборыДополнительныхРеквизитовИСведений.Справочник_Контрагенты)
            И ДополнительныеРеквизитыИСведения.Доступен
            И НЕ ДополнительныеРеквизитыИСведения.ЭтоДополнительноеСведение
            И НЕ ДополнительныеРеквизитыИСведения.ПометкаУдаления)
    ПОЛЕКЛЮЧА Ссылка
    ПОЛЕИМЕНИ Наименование
    ПОЛЕТИПАЗНАЧЕНИЯ ТипЗначения
    ЗНАЧЕНИЯХАРАКТЕРИСТИК (ВЫБРАТЬ
            КонтрагентыДополнительныеРеквизиты.Ссылка,
            КонтрагентыДополнительныеРеквизиты.Свойство,
            КонтрагентыДополнительныеРеквизиты.Значение
        ИЗ
            Справочник.Контрагенты.ДополнительныеРеквизиты КАК КонтрагентыДополнительныеРеквизиты)
    ПОЛЕОБЪЕКТА Ссылка
    ПОЛЕВИДА Свойство
    ПОЛЕЗНАЧЕНИЯ Значение }
{ХАРАКТЕРИСТИКИ
    ТИП(Справочник.Контрагенты)
    ВИДЫХАРАКТЕРИСТИК (ВЫБРАТЬ
            ДополнительныеРеквизитыИСведения.Ссылка,
            ДополнительныеРеквизитыИСведения.Наименование,
            ДополнительныеРеквизитыИСведения.ТипЗначения
        ИЗ
            ПланВидовХарактеристик.ДополнительныеРеквизитыИСведения КАК ДополнительныеРеквизитыИСведения
        ГДЕ
            ДополнительныеРеквизитыИСведения.НаборСвойств = ЗНАЧЕНИЕ(Справочник.НаборыДополнительныхРеквизитовИСведений.Справочник_Контрагенты)
            И ДополнительныеРеквизитыИСведения.Доступен
            И ДополнительныеРеквизитыИСведения.ЭтоДополнительноеСведение
            И НЕ ДополнительныеРеквизитыИСведения.ПометкаУдаления)
    ПОЛЕКЛЮЧА Ссылка
    ПОЛЕИМЕНИ Наименование
    ПОЛЕТИПАЗНАЧЕНИЯ ТипЗначения
    ЗНАЧЕНИЯХАРАКТЕРИСТИК РегистрСведений.ДополнительныеСведения
    ПОЛЕОБЪЕКТА Объект
    ПОЛЕВИДА Свойство
    ПОЛЕЗНАЧЕНИЯ Значение }

Может что-то недооптимизировано, но на средних объемах сойдет.

В общем все дело в волшебных характеристиках, направление понятно. Всем спасибо!

(7) Не взлетело?

(8) не, все норм. Еще раз спасибо.

(5) Добрый день.
Подскажите, где в Бухгалтерии 3.0 вы подсмотрели этот код? В каком отчете он содержится?