Доброе утро, подскажите пожалуйста как такое может быть, в 1 базе в консоли формирую запрос из 2ух таблиц выводится сумма с 1ой и сумма со второй, сделал внешнюю обработку, подключился к базе передал этот запрос, установил все параметры запроса в базе к которой подключился,  далее делаю запрос выполнить выгрузить, 1ая сумма выходит вторая все колонки = 0, встречал кто нибудь такое?

Параметры разные пади

Или права пользователя ИБ

(2) пользователь под полными правами, я делаю запрос в самописный документ акт выполненых работ и регистр расчета управ начисления, вот из актов все тянется а с регистра нет, хотя честно сказать, я часто делаю ком соединения и с такой вот ошибкой столкнулся в первые.

(0)[становил все параметры запроса в базе к которой подключился]
ты главное код не показывай

(3) "под полными правами" // ни о чем

При работе через com- как правило вся проблема в параметрах. Точно в них переданы значения из базы к которой происходит подключение?

(6)     Запрос.УстановитьПараметр("Подразделение", База.Справочники.Подразделения.НайтиПоКоду("000000062"));
    Запрос.УстановитьПараметр("Период", КонецМесяца(ПереданныйОбъект.Дата));
    Запрос.УстановитьПараметр("Организация", База.Справочники.Организации.НайтиПоКоду("000000024"));

Запрос
    Запрос = База.newObject("Запрос");
    Запрос.Текст = "ВЫБРАТЬ РАЗРЕШЕННЫЕ
    |    АктВыполненныхРаботДокументыОснования.Основание.Организация КАК Организация,
    |    АктВыполненныхРаботДокументыОснования.Основание.Подразделение КАК Подразделение,
    |    АктВыполненныхРаботИсполнители.ФизЛицо,
    |    СУММА(ВЫБОР
    |            КОГДА (НЕ АктВыполненныхРаботДокументыОснования.Основание ССЫЛКА Документ.ЗаказПокупателя)
    |                    И (НЕ АктВыполненныхРаботДокументыОснования.Основание ССЫЛКА Документ.ВнутреннийЗаказ)
    |                ТОГДА АктВыполненныхРаботДокументыОснования.Сумма
    |            ИНАЧЕ 0
    |        КОНЕЦ) КАК СуммаВыработки,
    |    СУММА(ВЫБОР
    |            КОГДА АктВыполненныхРаботДокументыОснования.Основание ССЫЛКА Документ.ЗаказПокупателя
    |                    ИЛИ АктВыполненныхРаботДокументыОснования.Основание ССЫЛКА Документ.ВнутреннийЗаказ
    |                ТОГДА АктВыполненныхРаботДокументыОснования.Сумма
    |            ИНАЧЕ 0
    |        КОНЕЦ) КАК СуммаДоплатыВычеты,
    |    СУММА(АктВыполненныхРаботДокументыОснования.Сумма) КАК СуммаВсего
    |ПОМЕСТИТЬ Выработка
    |ИЗ
    |    Документ._АктВыполненныхРабот.ДокументыОснования КАК АктВыполненныхРаботДокументыОснования
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений._СостоянияОбъектов КАК СостоянияОбъектов
    |        ПО АктВыполненныхРаботДокументыОснования.Ссылка = СостоянияОбъектов.Объект
    |            И (СостоянияОбъектов.СостояниеОбъекта = ЗНАЧЕНИЕ(Перечисление.СостоянияОбъектов.Принят))
    |        ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ._АктВыполненныхРабот.Исполнители КАК АктВыполненныхРаботИсполнители
    |        ПО (АктВыполненныхРаботИсполнители.Ссылка = АктВыполненныхРаботДокументыОснования.Ссылка)
    |ГДЕ
    |    АктВыполненныхРаботДокументыОснования.Ссылка.Дата МЕЖДУ НАЧАЛОПЕРИОДА(&Период, МЕСЯЦ) И КОНЕЦПЕРИОДА(&Период, МЕСЯЦ)
    |    И АктВыполненныхРаботДокументыОснования.Ссылка.Подразделение = &Подразделение
    |    И АктВыполненныхРаботДокументыОснования.Ссылка.Проведен
    |
    |СГРУППИРОВАТЬ ПО
    |    АктВыполненныхРаботДокументыОснования.Основание.Подразделение,
    |    АктВыполненныхРаботДокументыОснования.Основание.Организация,
    |    АктВыполненныхРаботИсполнители.ФизЛицо
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    Выработка.ФизЛицо,
    |    СУММА(Выработка.СуммаВсего) КАК БазаРаспределенияПоФизЛицу
    |ПОМЕСТИТЬ БазаРаспределения
    |ИЗ
    |    Выработка КАК Выработка
    |
    |СГРУППИРОВАТЬ ПО
    |    Выработка.ФизЛицо
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    Выработка.Организация,
    |    Выработка.ФизЛицо,
    |    Выработка.Подразделение,
    |    Выработка.СуммаВсего / БазаРаспределения.БазаРаспределенияПоФизЛицу * 100 КАК ДоляЗатрат
    |ПОМЕСТИТЬ ДоляРаспределения
    |ИЗ
    |    Выработка КАК Выработка
    |        ЛЕВОЕ СОЕДИНЕНИЕ БазаРаспределения КАК БазаРаспределения
    |        ПО Выработка.ФизЛицо = БазаРаспределения.ФизЛицо
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ РАЗРЕШЕННЫЕ
    |    НачисленияУдержания.ФизЛицо,
    |    НачисленияУдержания.ВидУчета,
    |    СУММА(НачисленияУдержания.Начислено) КАК Начислено,
    |    СУММА(НачисленияУдержания.Удержано) КАК Удержано
    |ПОМЕСТИТЬ ПрочиеНачисленияУдержания
    |ИЗ
    |    (ВЫБРАТЬ
    |        УправленческиеНачисленияФактическийПериодДействия.ФизЛицо КАК ФизЛицо,
    |        ""УУ"" КАК ВидУчета,
    |        СУММА(УправленческиеНачисленияФактическийПериодДействия.Результат) КАК Начислено,
    |        0 КАК Удержано
    |    ИЗ
    |        РегистрРасчета.УправленческиеНачисления.ФактическийПериодДействия(
    |                ПериодРегистрации = НАЧАЛОПЕРИОДА(&Период, ДЕНЬ)
    |                    И Подразделение = &Подразделение
    |                    И (НЕ ВидРасчета.ЗачетОтработанногоВремени)
    |                    И Результат <> 0) КАК УправленческиеНачисленияФактическийПериодДействия
    |    
    |    СГРУППИРОВАТЬ ПО
    |        УправленческиеНачисленияФактическийПериодДействия.ФизЛицо
    |    
    |    ОБЪЕДИНИТЬ ВСЕ
    |    
    |    ВЫБРАТЬ
    |        УправленческиеУдержания.ФизЛицо,
    |        ""УУ"",
    |        0,
    |        СУММА(-УправленческиеУдержания.Результат)
    |    ИЗ
    |        РегистрРасчета.УправленческиеУдержания КАК УправленческиеУдержания
    |    ГДЕ
    |        УправленческиеУдержания.ПериодРегистрации = НАЧАЛОПЕРИОДА(&Период, ДЕНЬ)
    |        И УправленческиеУдержания.Подразделение = &Подразделение
    |        И УправленческиеУдержания.Результат <> 0
    |        И (НЕ УправленческиеУдержания.ВидРасчета.Наименование ПОДОБНО ""Выплачено БУ"")
    |    
    |    СГРУППИРОВАТЬ ПО
    |        УправленческиеУдержания.ФизЛицо
    |    
    |    ОБЪЕДИНИТЬ ВСЕ
    |    
    |    ВЫБРАТЬ
    |        УправленческиеУдержания.ФизЛицо,
    |        ""БУ"",
    |        0,
    |        СУММА(-УправленческиеУдержания.Результат)
    |    ИЗ
    |        РегистрРасчета.УправленческиеУдержания КАК УправленческиеУдержания
    |    ГДЕ
    |        УправленческиеУдержания.ПериодРегистрации = НАЧАЛОПЕРИОДА(&Период, ДЕНЬ)
    |        И УправленческиеУдержания.Подразделение = &Подразделение
    |        И УправленческиеУдержания.Результат <> 0
    |        И УправленческиеУдержания.ВидРасчета.Наименование ПОДОБНО ""Выплачено БУ""
    |    
    |    СГРУППИРОВАТЬ ПО
    |        УправленческиеУдержания.ФизЛицо) КАК НачисленияУдержания
    |
    |СГРУППИРОВАТЬ ПО
    |    НачисленияУдержания.ФизЛицо,
    |    НачисленияУдержания.ВидУчета
    |;
    |
    |////////////////////////////////////////////////////////////////////////////////
    |ВЫБРАТЬ
    |    Выработка.Организация КАК Организация,
    |    Выработка.Подразделение КАК Подразделение,
    |    Выработка.СуммаВсего КАК СуммаВсего,
    |    ПрочиеНачисленияУдержанияУУ.Начислено * ДоляРаспределения.ДоляЗатрат / 100 КАК ПрочиеНачисления
    |ИЗ
    |    Выработка КАК Выработка
    |        ЛЕВОЕ СОЕДИНЕНИЕ ДоляРаспределения КАК ДоляРаспределения
    |        ПО Выработка.ФизЛицо = ДоляРаспределения.ФизЛицо
    |            И Выработка.Подразделение = ДоляРаспределения.Подразделение
    |            И Выработка.Организация = ДоляРаспределения.Организация
    |        ЛЕВОЕ СОЕДИНЕНИЕ ПрочиеНачисленияУдержания КАК ПрочиеНачисленияУдержанияУУ
    |        ПО Выработка.ФизЛицо = ПрочиеНачисленияУдержанияУУ.ФизЛицо
    |            И (ПрочиеНачисленияУдержанияУУ.ВидУчета = ""УУ"")
    |        ЛЕВОЕ СОЕДИНЕНИЕ ПрочиеНачисленияУдержания КАК ПрочиеНачисленияУдержанияБУ
    |        ПО Выработка.ФизЛицо = ПрочиеНачисленияУдержанияБУ.ФизЛицо
    |            И (ПрочиеНачисленияУдержанияБУ.ВидУчета = ""БУ"")
    |ГДЕ
    |    Выработка.Организация = &Организация";

(6) Если бы были не правильные параметры, мне результат запроса выдал нельзя сравнивать не соответствующие типы

НАЧАЛОПЕРИОДА(&Период, ДЕНЬ)
"Период" = КонецМесяца(ПереданныйОбъект.Дата)
Тебе точно на последний день месяца надо?

(10) сейчас проверю рег расчета, возможно ты прав.

Зачем проверять - просто текст запроса и установку этого параметра сравни с тем, где у тебя работает как ожидается

(10) спасибо БРО!

в консоли поставил дату конец месяца и консоль выдала 0, запись в рег расчета идет 07.2018 и теперь понял что это начало месяца