Добрый день. Подскажите, пожалуйста. Есть запрос, который выводит следующую информацию:

№ стр.     Физ.лицо    Получ.    Пл.агент    Период        Номер    Док.осн.Нач.    Док.осн.Конец    Начисления    НДФЛ        Комиссия    Удержания
1    ФИО                    Май.2019                        61 128,31    7 583,00        
2     ФИО        ФИО1    банк        Май.2019    01    24.08.2011    29.04.2029                    13,39        8 926,00
3     ФИО        ФИО2    банк        Май.2019    02    21.12.2011    15.02.2024                    13,39        8 926,00

Как правильно изменить запрос, чтобы "Начисления" и "НДФЛ" из строки 1 отображались в строках 2 и 3 (строка 1 не нужна)?

Текст запроса:

ВЫБРАТЬ
    ИсполнительныйЛист.Ссылка КАК Исполнительныйлист,
    ИсполнительныйЛист.ФизическоеЛицо КАК ФизическоеЛицо
ПОМЕСТИТЬ ИсполнительныеЛисты
ИЗ
    Документ.ИсполнительныйЛист КАК ИсполнительныйЛист
ГДЕ
    &ПериодНачало МЕЖДУ ИсполнительныйЛист.ДатаДействия И ИсполнительныйЛист.ДатаОкончания

СГРУППИРОВАТЬ ПО
    ИсполнительныйЛист.Ссылка,
    ИсполнительныйЛист.ФизическоеЛицо
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    НачисленияУдержанияПоСотрудникам.ФизическоеЛицо КАК ФизическоеЛицо,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.Получатель КАК Получатель,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.ПлатежныйАгент КАК ПлатежныйАгент,
    ВЫБОР
        КОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист
            ТОГДА НачисленияУдержанияПоСотрудникам.Период
    КОНЕЦ КАК Период,
    ВЫБОР
        КОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист
            ТОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование.Номер
    КОНЕЦ КАК ДокументОснованиеНомер,
    ВЫБОР
        КОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист
            ТОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование.ДатаДействия
    КОНЕЦ КАК ДокументОснованиеДатаДействия,
    ВЫБОР
        КОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист
            ТОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование.ДатаОкончания
    КОНЕЦ КАК ДокументОснованиеДатаОкончания,
    СУММА(ВЫБОР
            КОГДА НачисленияУдержанияПоСотрудникам.НачислениеУдержание <> ЗНАЧЕНИЕ(Перечисление.ВидыОсобыхНачисленийИУдержаний.НДФЛ)
                    И НачисленияУдержанияПоСотрудникам.НачислениеУдержание.Наименование <> "Комиссия банка по и/п"
                    И НачисленияУдержанияПоСотрудникам.НачислениеУдержание.Наименование <> "Удержание по исполнительному документу"
                ТОГДА НачисленияУдержанияПоСотрудникам.Сумма
        КОНЕЦ) КАК Начисления,
    СУММА(ВЫБОР
            КОГДА НачисленияУдержанияПоСотрудникам.НачислениеУдержание = ЗНАЧЕНИЕ(Перечисление.ВидыОсобыхНачисленийИУдержаний.НДФЛ)
                ТОГДА НачисленияУдержанияПоСотрудникам.Сумма
        КОНЕЦ) КАК НДФЛ,
    СУММА(ВЫБОР
            КОГДА НачисленияУдержанияПоСотрудникам.НачислениеУдержание.Наименование = "Комиссия банка по и/п"
                ТОГДА НачисленияУдержанияПоСотрудникам.Сумма
        КОНЕЦ) КАК Комиссия,
    СУММА(ВЫБОР
            КОГДА НачисленияУдержанияПоСотрудникам.НачислениеУдержание.Наименование = "Удержание по исполнительному документу"
                ТОГДА НачисленияУдержанияПоСотрудникам.Сумма
        КОНЕЦ) КАК Удержания
ИЗ
    ИсполнительныеЛисты КАК ИсполнительныеЛисты
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.НачисленияУдержанияПоСотрудникам КАК НачисленияУдержанияПоСотрудникам
        ПО ИсполнительныеЛисты.ФизическоеЛицо = НачисленияУдержанияПоСотрудникам.ФизическоеЛицо
ГДЕ
    НачисленияУдержанияПоСотрудникам.Период = &ПериодНачало
    И НачисленияУдержанияПоСотрудникам.Сумма <> 0

СГРУППИРОВАТЬ ПО
    НачисленияУдержанияПоСотрудникам.ФизическоеЛицо,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.Получатель,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.ПлатежныйАгент,
    ВЫБОР
        КОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист
            ТОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование.Номер
    КОНЕЦ,
    ВЫБОР
        КОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист
            ТОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование.ДатаДействия
    КОНЕЦ,
    ВЫБОР
        КОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист
            ТОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование.ДатаОкончания
    КОНЕЦ,
    ВЫБОР
        КОГДА НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист
            ТОГДА НачисленияУдержанияПоСотрудникам.Период
    КОНЕЦ

сделай две ВТ: "ПерваяСтрока" и "ОстальныеСтроки", соедини по периоду, выведи

(1) ой спасибище за идею! Не додумался.
А как вывести в "шапку" отчета организацию? Период выводится, а организация - нет. Группировки есть, поля в отчете выводятся.
Настройки отчета СКД:
- Организация, МесяцУчета(Период)
--ФИО,Номер и т.д.
---МесяцУчета

(2) кодом можно Заголовок подрихтовать

(3) понял)
А общие итоги как правильно сформировать? Т.е. в конце отчета строчку "Итоги" с суммарными начислениями/удержаниями можно вставить?

(4) Ресурсы закладка в схеме СКД

(5) стоит всё в "Сумма". Я имею в виду:

№/ФИО/Начисление/удержание
1/ФИО1/25/5
1/ФИО3/15/2
1/ФИО1/10/1
Итого:50/8

(6) строка итогов есть в отчете сейчас?

(7) Нет

(7) Вот исправленный запрос:

ВЫБРАТЬ
    ИсполнительныйЛист.Ссылка КАК Исполнительныйлист,
    ИсполнительныйЛист.ФизическоеЛицо КАК ФизическоеЛицо,
    ИсполнительныйЛист.Организация КАК Организация
ПОМЕСТИТЬ ИсполнительныеЛисты
ИЗ
    Документ.ИсполнительныйЛист КАК ИсполнительныйЛист
ГДЕ
    &ПериодНачало МЕЖДУ ИсполнительныйЛист.ДатаДействия И ИсполнительныйЛист.ДатаОкончания

СГРУППИРОВАТЬ ПО
    ИсполнительныйЛист.Ссылка,
    ИсполнительныйЛист.ФизическоеЛицо,
    ИсполнительныйЛист.Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    НачисленияУдержанияПоСотрудникам.ФизическоеЛицо КАК ФизическоеЛицо,
    СУММА(ВЫБОР
            КОГДА НачисленияУдержанияПоСотрудникам.НачислениеУдержание.Наименование <> "Удержание по исполнительному документу"
                    И НачисленияУдержанияПоСотрудникам.НачислениеУдержание.Наименование <> "Комиссия банка по и/п"
                ТОГДА НачисленияУдержанияПоСотрудникам.Сумма
        КОНЕЦ) КАК Начисления,
    СУММА(ВЫБОР
            КОГДА НачисленияУдержанияПоСотрудникам.НачислениеУдержание = ЗНАЧЕНИЕ(Перечисление.ВидыОсобыхНачисленийИУдержаний.НДФЛ)
                ТОГДА НачисленияУдержанияПоСотрудникам.Сумма
        КОНЕЦ) КАК НДФЛ,
    ИсполнительныеЛисты.Организация КАК Организация
ПОМЕСТИТЬ НачисленияСотрудника
ИЗ
    ИсполнительныеЛисты КАК ИсполнительныеЛисты
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.НачисленияУдержанияПоСотрудникам КАК НачисленияУдержанияПоСотрудникам
        ПО ИсполнительныеЛисты.ФизическоеЛицо = НачисленияУдержанияПоСотрудникам.ФизическоеЛицо
ГДЕ
    НачисленияУдержанияПоСотрудникам.Период = &ПериодНачало
    И НачисленияУдержанияПоСотрудникам.Сумма <> 0

СГРУППИРОВАТЬ ПО
    НачисленияУдержанияПоСотрудникам.ФизическоеЛицо,
    ИсполнительныеЛисты.Исполнительныйлист,
    ИсполнительныеЛисты.Организация
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    НачисленияУдержанияПоСотрудникам.ФизическоеЛицо КАК ФизическоеЛицо,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.Получатель КАК Получатель,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.ПлатежныйАгент КАК ПлатежныйАгент,
    НачисленияУдержанияПоСотрудникам.Период КАК Период,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.Номер КАК ДокументОснованиеНомер,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.ДатаДействия КАК ДокументОснованиеДатаДействия,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.ДатаОкончания КАК ДокументОснованиеДатаОкончания,
    СУММА(ВЫБОР
            КОГДА НачисленияУдержанияПоСотрудникам.НачислениеУдержание.Наименование = "Удержание по исполнительному документу"
                ТОГДА НачисленияУдержанияПоСотрудникам.Сумма
        КОНЕЦ) КАК Удержания,
    СУММА(ВЫБОР
            КОГДА НачисленияУдержанияПоСотрудникам.НачислениеУдержание.Наименование = "Комиссия банка по и/п"
                ТОГДА НачисленияУдержанияПоСотрудникам.Сумма
        КОНЕЦ) КАК Комиссия
ПОМЕСТИТЬ УдержанияСотрудника
ИЗ
    ИсполнительныеЛисты КАК ИсполнительныеЛисты
        ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.НачисленияУдержанияПоСотрудникам КАК НачисленияУдержанияПоСотрудникам
        ПО ИсполнительныеЛисты.ФизическоеЛицо = НачисленияУдержанияПоСотрудникам.ФизическоеЛицо
            И ИсполнительныеЛисты.Исполнительныйлист = НачисленияУдержанияПоСотрудникам.ДокументОснование
ГДЕ
    НачисленияУдержанияПоСотрудникам.Период = &ПериодНачало
    И НачисленияУдержанияПоСотрудникам.Сумма <> 0
    И НачисленияУдержанияПоСотрудникам.ДокументОснование ССЫЛКА Документ.ИсполнительныйЛист

СГРУППИРОВАТЬ ПО
    НачисленияУдержанияПоСотрудникам.ФизическоеЛицо,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.Получатель,
    НачисленияУдержанияПоСотрудникам.Период,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.Номер,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.ПлатежныйАгент,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.ДатаДействия,
    НачисленияУдержанияПоСотрудникам.ДокументОснование.ДатаОкончания
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    НачисленияСотрудника.Организация КАК Организация,
    УдержанияСотрудника.ФизическоеЛицо КАК ФизическоеЛицо,
    УдержанияСотрудника.Получатель КАК Получатель,
    УдержанияСотрудника.ПлатежныйАгент КАК ПлатежныйАгент,
    УдержанияСотрудника.Период КАК МесяцУчета,
    УдержанияСотрудника.ДокументОснованиеНомер КАК Номер,
    УдержанияСотрудника.ДокументОснованиеДатаДействия КАК ДатаДействия,
    УдержанияСотрудника.ДокументОснованиеДатаОкончания КАК ДатаОкончания,
    УдержанияСотрудника.Удержания КАК Удержания,
    УдержанияСотрудника.Комиссия КАК Комиссия,
    НачисленияСотрудника.Начисления - НачисленияСотрудника.НДФЛ КАК Начисления,
    НачисленияСотрудника.НДФЛ КАК НДФЛ
ИЗ
    УдержанияСотрудника КАК УдержанияСотрудника
        ЛЕВОЕ СОЕДИНЕНИЕ НачисленияСотрудника КАК НачисленияСотрудника
        ПО (НачисленияСотрудника.ФизическоеЛицо = УдержанияСотрудника.ФизическоеЛицо)

СГРУППИРОВАТЬ ПО
    УдержанияСотрудника.ФизическоеЛицо,
    УдержанияСотрудника.Получатель,
    УдержанияСотрудника.ПлатежныйАгент,
    УдержанияСотрудника.Период,
    УдержанияСотрудника.ДокументОснованиеНомер,
    УдержанияСотрудника.ДокументОснованиеДатаДействия,
    УдержанияСотрудника.ДокументОснованиеДатаОкончания,
    НачисленияСотрудника.НДФЛ,
    НачисленияСотрудника.Организация,
    УдержанияСотрудника.Удержания,
    УдержанияСотрудника.Комиссия,
    НачисленияСотрудника.Начисления - НачисленияСотрудника.НДФЛ

Все 3 ресурса (начисления, удержания, комиссия) установлены в "Сумма"