Отправляю POST запрос с помощью функции
Функция ВыполнитьPOSTЗапрос(ИмяСервера, Порт, Команда, СсылкаНаРесурс)
    HTTP = Новый HTTPСоединение(ИмяСервера,Порт,,,,60);

    ФайлЗапроса = ПолучитьИмяВременногоФайла();
    ТекстовыйФайл = Новый ТекстовыйДокумент;
    ТекстовыйФайл.УстановитьТекст(СокрЛП(Команда));
    ТекстовыйФайл.Записать(ФайлЗапроса, КодировкаТекста.UTF8);
    ФайлРезультата = ПолучитьИмяВременногоФайла();
    ЗаголовокHTTP = Новый Соответствие();
    
    //ЗаголовокHTTP.Вставить("Accept-Language", "ru");
    //ЗаголовокHTTP.Вставить("Accept-Charset", "utf-8");
    //ЗаголовокHTTP.Вставить("Content-Language", "ru");
    //ЗаголовокHTTP.Вставить("Content-Charset", "utf-8");
    //ЗаголовокHTTP.Вставить("Content-Type", "application/x-www-form-urlencoded");
    //ЗаголовокHTTP.Вставить("Content-Type", "application/xml");
    ЗаголовокHTTP.Вставить("Content-Type", "application/json; charset=utf-8");

    HTTP.ОтправитьДляОбработки(ФайлЗапроса, СсылкаНаРесурс, ФайлРезультата, ЗаголовокHTTP);
    Ответ = Новый ТекстовыйДокумент();
    Ответ.Прочитать(ФайлРезультата, КодировкаТекста.UTF8);
    ТекстОтвета = Ответ.ПолучитьТекст();
    УдалитьФайлы(ФайлЗапроса);
    УдалитьФайлы(ФайлРезультата);
    
    Возврат ТекстОтвета;
КонецФункции

В на стороне приемника в начале текста возникает паразитный символ ?  
Ну и прилетает :
<result><code>0</code><message>error ORA-31011: сбой разбора XML</message></result>

Это тебе карма такая за использование файликов

это бом, а не паразитный символ

(1) Знаю
Я тоже против вариант но без файликов вообще возвращает Ошибку 500

Функция ВыполнитьPOSTЗапрос(ИмяСервера, Порт, СтрокаОтправки, СсылкаНаРесурс) Экспорт
    
    
    HTTP = Новый HTTPСоединение(ИмяСервера,Порт,,,,60);
        
    ЗаголовокЗапросаHTTP = Новый Соответствие();
    ЗаголовокЗапросаHTTP.Вставить("Content-Length",СтрДлина(СтрокаОтправки));
    //ЗаголовокЗапросаHTTP.Вставить("Content-Type", "application/x-www-form-urlencoded");
    //ЗаголовокЗапросаHTTP.Вставить("Content-Type", "application/json; charset=utf-8");
    ЗаголовокЗапросаHTTP.Вставить("Content-Type", "text/plain;charset=UTF-8");
    
    
    
    //HTTPЗапрос = Новый HTTPЗапрос(СсылкаНаРесурс,ЗаголовокЗапросаHTTP);
    HTTPЗапрос = Новый HTTPЗапрос;
    HTTPЗапрос.АдресРесурса = СсылкаНаРесурс;
    HTTPЗапрос.Заголовки = ЗаголовокЗапросаHTTP;
    
    HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаОтправки);
    
    Возврат HTTP.ОтправитьДляОбработки(HTTPЗапрос).ПолучитьТелоКакСтроку();
    
    
КонецФункции

Запомни на будущее простое правило: Content-Length никогда вообще не устанавливай в коде.

ЗаголовокЗапросаHTTP.Вставить("Content-Length",СтрДлина(СтрокаОтправки));
Не надо этого делать, платформа сама вставляет этот заголовок. Я тебе могу даже сказать где ты ошибся)
Если символов 1000 то эта штука СтрДлина(СтрокаОтправки) вернёт 1 000, и из-за неразрывного пробела все сломается)
Ещё раз повторю, этот заголовок ставится сам м его не надо устанавливать

Вот вариант :

1. без использования временных файлов
2. без Content-Length
3. Content-Type как Advancer Rest Client (где все ОК)

Все равно : <result><code>0</code><message>error ORA-31011: сбой разбора XML</message></result>

Функция ВыполнитьPOSTЗапрос(ИмяСервера, Порт, СтрокаОтправки, СсылкаНаРесурс) Экспорт
    
    
    HTTP = Новый HTTPСоединение(ИмяСервера,Порт,,,,60);
        
    ЗаголовокЗапросаHTTP = Новый Соответствие();
    ЗаголовокЗапросаHTTP.Вставить("Content-Length",СтрДлина(СтрокаОтправки));
    //ЗаголовокЗапросаHTTP.Вставить("Content-Type", "application/x-www-form-urlencoded");
    //ЗаголовокЗапросаHTTP.Вставить("Content-Type", "application/json; charset=utf-8");
    ЗаголовокЗапросаHTTP.Вставить("Content-Type", "text/plain;charset=UTF-8");
    
    
    
    //HTTPЗапрос = Новый HTTPЗапрос(СсылкаНаРесурс,ЗаголовокЗапросаHTTP);
    HTTPЗапрос = Новый HTTPЗапрос;
    HTTPЗапрос.АдресРесурса = СсылкаНаРесурс;
    HTTPЗапрос.Заголовки = ЗаголовокЗапросаHTTP;
    
    HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаОтправки);
    
    Возврат HTTP.ОтправитьДляОбработки(HTTPЗапрос).ПолучитьТелоКакСтроку();
        
КонецФункции

ЧТО ОН ТВАРЬ ЕЩЕ ХОЧЕТ ?

Подозреваю что куда то еще нужно впердолить  HTTP/1.1

говоришь "без", а в коде есть

(8) НЕ нет. Не то скопипастил.
Вот самый лайтовый вариант

Функция ВыполнитьPOSTЗапрос(ИмяСервера, Порт, СтрокаОтправки, СсылкаНаРесурс) Экспорт
        
    HTTP = Новый HTTPСоединение(ИмяСервера,Порт,,,,60);
        
    ЗаголовокЗапросаHTTP = Новый Соответствие();
    ЗаголовокЗапросаHTTP.Вставить("Content-Type"  , "application/xml");
        
    HTTPЗапрос = Новый HTTPЗапрос(СсылкаНаРесурс,ЗаголовокЗапросаHTTP);
    HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаОтправки);
    
    Возврат HTTP.ОтправитьДляОбработки(HTTPЗапрос).ПолучитьТелоКакСтроку();
        
КонецФункции

Покажи скрин ARC где все работает, включая URI

А также отладчик с точкой останова до отправки ПОСТ-запроса с видными значениями всех параметров метода

HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаОтправки,,ИспользованиеByteOrderMark.НеИспользовать);

(10)
Request https://yadi.sk/i/-ruvW5Nf_rY8ew
responce https://yadi.sk/i/jpMCPqx_WYgJgQ

(13) Ну так может у тебя действительно текст ХМЛ гуано в 1С

(12) ЕСТЬ !!!!
<result><code>1</code><message>OK; Load NOMENKLATURA complete.  Loaded 1 items.</message></result>

Спасибо огромное

А я же говорил )))

(16) Там похоже вебовец что то еще со своей стороны подшаминаивал.
Но по сути проблема была в Content-Length

Окончательный вариант функции если кому нужен будет :

Функция ВыполнитьPOSTЗапрос(ИмяСервера, Порт, СтрокаОтправки, СсылкаНаРесурс) Экспорт
        
    HTTP = Новый HTTPСоединение(ИмяСервера,Порт,,,,60);
        
    ЗаголовокЗапросаHTTP = Новый Соответствие();
    ЗаголовокЗапросаHTTP.Вставить("Content-Type"  , "application/xml");
        
    HTTPЗапрос = Новый HTTPЗапрос(СсылкаНаРесурс,ЗаголовокЗапросаHTTP);
    HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаОтправки,,ИспользованиеByteOrderMark.НеИспользовать);
    
    Возврат HTTP.ОтправитьДляОбработки(HTTPЗапрос).ПолучитьТелоКакСтроку();
        
КонецФункции

(17) Так без третьего параметра "ИспользованиеByteOrderMark.НеИспользовать" тоже работает?

(12) BOM это классика, в целом есть куча тонкостей в http но они все решаемые обычно

(19) нет

И таки да :
Всем большое спасибо в помощи по новой для меня теме

(17) тебе говорят бом, а ты почему то контент-ленгф