Почему-то не работает даже простой отчет при попытках программно сформировать через СКД. Где я мог ошибиться или что ещё забыл?

    СхемаКомпоновки = Новый СхемаКомпоновкиДанных;
    
    Источник = СхемаКомпоновки.ИсточникиДанных.Добавить();
    Источник.Имя = "ЛокальнаяБаза";
    Источник.СтрокаСоединения = "";
    Источник.ТипИсточникаДанных = "Local";
    
    НаборДанных = СхемаКомпоновки.НаборыДанных.Добавить(Тип("НаборДанныхЗапросСхемыКомпоновкиДанных"));
    НаборДанных.ИсточникДанных = "ЛокальнаяБаза";
    НаборДанных.АвтоЗаполнениеДоступныхПолей = Истина;
    НаборДанных.Имя = "ДанныеЗапрос";
    НаборДанных.Запрос = "ВЫБРАТЬ
                         |    ПодразделенияОрганизаций.Ссылка КАК Подразделение
                         |ИЗ
                         |    Справочник.ПодразделенияОрганизаций КАК ПодразделенияОрганизаций";
    
    ПолеПодразделение = НаборДанных.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));
    ПолеПодразделение.Заголовок = "Подразделение";
    ПолеПодразделение.ПутьКДанным = "Подразделение";
    ПолеПодразделение.Поле = "Подразделение";
    
    Настройки = СхемаКомпоновки.НастройкиПоУмолчанию;
    
    ГруппировкаПодразделение = Настройки.Структура.Добавить(Тип("ГруппировкаКомпоновкиДанных"));
    ПолеГруппировки = ГруппировкаПодразделение.ПоляГруппировки.Элементы.Добавить(Тип("ПолеГруппировкиКомпоновкиДанных"));
    ПолеГруппировки.Использование = Истина;
    ПолеГруппировки.Поле = Новый ПолеКомпоновкиДанных("Подразделение");
    ПолеГруппировки.ТипГруппировки = ТипГруппировкиКомпоновкиДанных.Элементы;
        
    ВыбранноеПоле = Настройки.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
    ВыбранноеПоле.Заголовок = "Подразделение";
    ВыбранноеПоле.Использование = Истина;
    ВыбранноеПоле.Поле = Новый ПолеКомпоновкиДанных("Подразделение");
    
    КомпоновщикНастроек = Новый КомпоновщикНастроекКомпоновкиДанных;
    КомпоновщикНастроек.Инициализировать(Новый ИсточникДоступныхНастроекКомпоновкиДанных(СхемаКомпоновки));
    КомпоновщикНастроек.ЗагрузитьНастройки(Настройки);
        
    КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
    Макет = КомпоновщикМакета.Выполнить(СхемаКомпоновки, КомпоновщикНастроек.ПолучитьНастройки());

    ПроцессорКомпоновки = Новый ПроцессорКомпоновкиДанных;
    ПроцессорКомпоновки.Инициализировать(Макет);
    
    ТабДок = Новый ТабличныйДокумент;
    ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
    ПроцессорВывода.УстановитьДокумент(ТабДок);
    ПроцессорВывода.Вывести(ПроцессорКомпоновки);


Табличный документ в результате получается пустой.

настрой руками в гуи, в ПриКомпоновкеРезультата смотришь - что получилось и что у тебя написано

(1) Спасиб за совет. А смотреть только переменную "СхемаКомпоновкиДанных" можно или ещё какие-нибудь есть?

(2) для настроек по умолчанию хватит

(3) Это да, просто как всегда не понятно какие переменные по умолчанию доступны в модуле отчета.

(4) https://1clenta.ru/pattern/54

Даже визуально сравнивая настройки в ПриКомпоновкеРезультата, всё равно не могу найти ошибку.
Существует ли программный генератор кода по схеме, так чтобы на входе схема, а на выходе табличный документ?

http://catalog.mista.ru/public/173317/

ГруппировкаПодразделение.Использование = Истина

(8) Не помогло, к сожалению.
(7) А за это спасибо. Действительно помогает!

КомпоновщикНастроек.ПолучитьНастройки()
Посмотри, структура отчета заполнена?

автополе в группировке есть (в выборе у группировки)?..

Вам нужно в ГруппировкаПодразделение
Добавить в Выбор добавить поле.

(12) Да, действительно разобрался, что надо было добавить "авто поле" по группировке "Подразделение":
ГруппировкаПодразделение.Выбор.Элементы.Добавить(Тип("АвтоВыбранноеПолеКомпоновкиДанных"));

Всем спасибо! Миста прям порадовала, теперь даже можно получить ответ )