Доброго времени, помогите модернизировать, чтобы проверял наличие штрихкода и если присвоен, то пропускал.
И желательно с логированием в сообщениях:
ТабличноеПолеШК  - ТаблицаЗначений со списком номенклатуры

    Для каждого Строка из ТабличноеПолеШК Цикл
        
        новШк = РегистрыСведений.Штрихкоды.СоздатьМенеджерЗаписи();
        
        Объект = Строка.Номенклатура;
        новШк.Владелец         = Объект.Ссылка;
        новШк.ЕдиницаИзмерения = Объект.ЕдиницаХраненияОстатков;
        новШк.ТипШтрихкода     = ПланыВидовХарактеристик.ТипыШтрихкодов.EAN13;
        новШк.Качество         = Справочники.Качество.Новый;
        новШк.Штрихкод         = РаботаСТорговымОборудованием.СформироватьШтрихКод();
        
        новШк.Записать();
        
    КонецЦикла;

Перед записью можно прочитать и, если считанная запись не пустая - записывать.

(1)     Для каждого Строка из ТабличноеПолеШК Цикл
        
        новШк = РегистрыСведений.Штрихкоды.СоздатьМенеджерЗаписи();
        
        Объект = Строка.Номенклатура;
        
        новШк.Владелец         = Объект.Ссылка;
        новШк.ЕдиницаИзмерения = Объект.ЕдиницаХраненияОстатков;
        новШк.ТипШтрихкода     = ПланыВидовХарактеристик.ТипыШтрихкодов.EAN13;
        новШк.Качество         = Справочники.Качество.Новый;
        новШк.Штрихкод         = РаботаСТорговымОборудованием.СформироватьШтрихКод();
        
        новШк.Прочитать();
        
        Если новШк.Выбран() Тогда
            Сообщить("Для номенклатуры " + Объект.Наименование + " уже присвоен штрихкод!");
            Продолжить;
        КонецЕсли;    
        новШк.Записать();
        
        Сообщить("Для номенклатуры " + Объект.Наименование + " присвоен штрихкод: " + новШк.Штрихкод);
        
    КонецЦикла;









{ВнешняяОбработка.СозданиеШКдляНоменклатуры.Форма.Форма.Форма(22)}: Ошибка при вызове метода контекста (Записать)
        новШк.Записать();
по причине:
Запись не верна! Значение поля "Владелец" не может быть пустым!: Штрихкоды: , , , , , , , 0 (Регистр сведений: Штрихкоды)

Ну наверное, добавить
Если НЕ ЗначениеЗаполнено(Объект) Тогда
Продолжить;
КонецЕсли;

(3) Не совсем, дело в том что запись в менеджере очищается после метода Прочитать()

Все дело в том, что штрихкод все время уникален и читать бессмысленно, по логике вещей нужно делать так. Но почему-то по ссылке не хочет считывать..

    Для каждого Строка из ТабличноеПолеШК Цикл
        
        новШк = РегистрыСведений.Штрихкоды.СоздатьМенеджерЗаписи();
        
        Объект = Строка.Номенклатура;
        
        Если НЕ ЗначениеЗаполнено(Объект) Тогда
            Продолжить;
        КонецЕсли;
        
        новШк.Владелец = Объект.Наименование;
        новШк.Прочитать();
        
        Если новШк.Выбран() Тогда
            Сообщить("Для номенклатуры " + Объект.Наименование + " уже присвоен штрихкод!");
            Продолжить;
        КонецЕсли;    
        
        новШк.Владелец         = Объект.Ссылка;
        новШк.ЕдиницаИзмерения = Объект.ЕдиницаХраненияОстатков;
        новШк.ТипШтрихкода     = ПланыВидовХарактеристик.ТипыШтрихкодов.EAN13;
        новШк.Качество         = Справочники.Качество.Новый;        
        новШк.Штрихкод         = РаботаСТорговымОборудованием.СформироватьШтрихКод();
        
        новШк.Записать();
        
        Сообщить("Для номенклатуры " + Объект.Наименование + " присвоен штрихкод: " + новШк.Штрихкод);
        
    КонецЦикла;

Пардон

новШк.Владелец = Объект.Ссылка;

Вот..

Не считывает запись по ссылке, хотя их несколько. Ведь ссылка уникальна, в чем дело?

Т.к. может быть присвоено сразу несколько штрих-кодов решил читать набор записей.
В общем вот что в итоге получилось:

    Для каждого Строка из ТабличноеПолеШК Цикл
        
        Ссылка = Строка.Номенклатура; // Ссылка на номенклатуру
        
        НаборЗаписей = РегистрыСведений.Штрихкоды.СоздатьНаборЗаписей();
        НаборЗаписей.Отбор.Владелец.Установить(Ссылка);
        НаборЗаписей.Прочитать();
        
        Если ЗначениеЗаполнено(НаборЗаписей) Тогда
            Сообщить("Для номенклатуры " + Ссылка.Наименование + " штрихкод уже назначен!");
            Продолжить;
        КонецЕсли;    
        
        новШк = РегистрыСведений.Штрихкоды.СоздатьМенеджерЗаписи();
        новШк.Владелец         = Ссылка;
        новШк.ТипШтрихкода     = ПланыВидовХарактеристик.ТипыШтрихкодов.EAN13;
        новШк.ЕдиницаИзмерения = Ссылка.ЕдиницаХраненияОстатков;
        новШк.Качество         = Справочники.Качество.Новый;        
        новШк.Штрихкод         = РаботаСТорговымОборудованием.СформироватьШтрихКод();
        
        новШк.Записать();
        
        Сообщить("Для номенклатуры " + Ссылка.Наименование + " назначен штрихкод: " + новШк.Штрихкод);
        
    КонецЦикла;

Что скажете?

Если НаборЗаписей.Количество() = 0 Тогда добавляем
Иначе сообщаем и продолжаем

обычно еще отбирать по типу ШК надо и иногда по единице измерения

(8)     Для каждого Строка из ТабличноеПолеШК Цикл // ТабличноеПолеШК - реквизит
        
        Ссылка = Строка.Номенклатура; // ссылка на номенклатуру
        
        // Обработка ошибочной ситуации.
        Если Ссылка.Пустая() Тогда
            Продолжить;
        КонецЕсли;
        
        // Проверим, назначен ли штрих-код.
        НаборЗаписей = РегистрыСведений.Штрихкоды.СоздатьНаборЗаписей();
        НаборЗаписей.Отбор.Владелец.Установить(Ссылка);
        НаборЗаписей.Прочитать();
        Если НаборЗаписей.Количество() = 0 Тогда
            
            // Если не назначен, добавим новый штрих-код.
            НовШк = РегистрыСведений.Штрихкоды.СоздатьМенеджерЗаписи();
            НовШк.Владелец         = Ссылка;
            НовШк.ТипШтрихкода     = ПланыВидовХарактеристик.ТипыШтрихкодов.EAN13;
            НовШк.ЕдиницаИзмерения = Ссылка.ЕдиницаХраненияОстатков;
            НовШк.Качество         = Справочники.Качество.Новый;        
            НовШк.Штрихкод         = РаботаСТорговымОборудованием.СформироватьШтрихКод();
            
            НовШк.Записать();
            
            Сообщить("Для номенклатуры " + Ссылка.Наименование + " назначен штрихкод: " + НовШк.Штрихкод);    
            
        Иначе
            // Уже назначен штрих-код, сообщаем.
            Сообщить("Для номенклатуры " + Ссылка.Наименование + " штрихкод уже назначен!");
            Продолжить;
            
        КонецЕсли;    
        
    КонецЦикла;

(9) Лично для себя делаю помощника, мне проверки наличия достаточно)

(11) а мне все равно ))

(12) Ну в итоге то код нормальный получился?
Не слишком корявый?