Добрый день. Может ли кто-нибудь поделиться кодом для обхода xml документа. Чтобы обойти все узлы и атрибуты, так скажем прочитать XML. Заранее спасибо. Буду очень благодарен.

Книга знаний: Чтение и запись текстовых файлов XML средствами 1С:Предприятие 7.7

Спасибо, я это видел. Там конкретное позиционирование на конкретные узлы и атрибуты. А есть какая то универсальная обработка для чтения любого XML?

(2) DOM или SAX ?

(2)  есть. Минут через 40 буду дома и скину
Процедура простая рекурсивная строк 20—30

//**************************************************************************************
//
Процедура прТестовоеЧтение()
    
    Если ПустаяСтрока(ВыбФайл)=1
    Тогда
        Сообщить("тестовое чтение файла обмена: не задано имя файла..?","i");
        Возврат;
    КонецЕсли;    
        
    оТест =  СоздатьОбъект("Microsoft.XMLDOM");
    оТест.Load(ВыбФайл);
    Корень = оТест.DocumentElement;
    ОчиститьОкноСообщений();
    прПечатьУзлов(оТест, Корень, 0);
    
КонецПроцедуры //прТестовоеЧтение()

//**************************************************************************************
//
Процедура прПечатьУзлов(xmlDoc, Узел, Уровень=0)
    Состояние(Уровень);
    
    ЧислоДетей = Узел.childNodes.length;
    Для Инд=1 По ЧислоДетей    Цикл
        
        ТекУзел= Узел.childNodes.item(Инд-1);
        Если ТекУзел.nodeType<>1 Тогда Продолжить; КонецЕсли;
        
        Стр = Формат("","С"+Уровень*8);
        
        СтрАтрибуты="";
        
        Для Инд2=1 По Узел.attributes.length Цикл
            Атрибут=Узел.attributes.item(Инд2-1);
            СтрАтрибуты=СтрАтрибуты+?(СтрАтрибуты="","",";")+Атрибут.nodename+"="+Атрибут.value;
        КонецЦикла;
        
        Текст="";
        Если (ТекУзел.childNodes.length=1) and (ТекУзел.childNodes.item(0).nodetype=3) Тогда
            Текст=ТекУзел.childNodes.item(0).text;
        КонецЕсли;
        
        Стр=Стр+ТекУзел.tagName+?(СтрАтрибуты="","","("+СтрАтрибуты+")" ) + ":" +Текст;
        Сообщить(Стр);
        прПечатьУзлов(xmlDoc, ТекУзел, Уровень+1);
    КонецЦикла;
    
    Состояние("");
КонецПроцедуры //прПечатьУзлов()

(6) Уверен что это взлетит при размере XML файлика под гиг?

(7) хз.. вряд ли кто станет такой хренью читать файл под гиг.
но если файлик есть - давай, попробую

(8) Боюсь, окно сообщений лопнет от такого файлика))

Спасибо, думаю это то что надо

(9) не лопнет, но тормозить начнет

Мой файл не читает, ошибку выдает на первой же строке

        Если (ТекУзел.childNodes.length=1) and (ТекУзел.childNodes.item(0).nodetype=3) Тогда
            Текст=ТекУзел.childNodes.item(0).text;
        КонецЕсли;

Вот этом месте кода

Добавил этот блок в Попытку-Исключение, заработало
Можно пояснить, что означает этот блок, я так понимаю, он читает значение атрибута?

некоторые атрибуты не выводит

<СвОЭДОтпр НаимОрг="ООО "Компания "Тензор"" ИдЭДО="2BE" ИННЮЛ="7605016030"/> вот на этом рушится

(15) потому что кавычки внутри кавычек - это ненормально.

(13) нет, не атрибута.
он читает текст типа <СуммНал>420.00</СуммНал> - текст внутри тега

(14) выводит все нормально.
у меня эта процедура используется для тестового просмотра во всяких загрузках, читает выводит все нормально.
вот как раз сейчас Гиперглобус поправлял

Order-Header:
        OrderNumber:22217678
        OrderDate:2020-07-21
        ExpectedDeliveryDate:2020-07-24
        ExpectedDeliveryTime:09:00
        Currency:RUB
        DocumentFunctionCode:O
Order-Parties:
        Buyer:
                ILN:4680387000006
        Seller:
                ILN:4607172169991
                CodeByBuyer:26705
        DeliveryPoint:
                ILN:4680387000006
                Name:Логистика
                StreetAndNumber:г.Пушкино,Красноармейское ш. 107/1
                CityName:Пушкинский район
                PostalCode:141211
                Country:RU
                PhoneNumber:495 223-75-00
                LocationNumber:5600
        Invoicee:
                ILN:4690202000005
Order-Lines:
        Line:
                Line-Item:
                        LineNumber:1

(16) т.е. если есть кавычки то функция не работает?

(19) https://overcoder.net/q/7688/какие-символы-мне-нужно-экранировать-в-документах-xml

(12) при length=0 ошибка при обращении к .item(0)

(21) поправил. Заработало. Только все равно не все узлы и атрибуты выводит.

https://yadi.sk/d/2v0wk2dE-bc_gA
Попробуйте данным кодом прочитать этот файл

(23) угу, атрибуты не читает в комплексных типах,
это уже вечером только покопаюсь

ИдСв:
                                СвЮЛУч:
                        Адрес:
                                АдрРФ:

атрибуты в СвЮЛУч и АдрРФ не прочитал

(23) https://www.dropbox.com/s/odxgekf7fb1p0wb/Обход%20XMLDomDoc.ert?dl=0

(27) Спасибо

https://ru.stackoverflow.com/questions/448181/Проблема-с-xmlreader

(28) поправленное, вроде разбирает
.
Процедура прПечатьУзлов(xmlDoc, Узел, Уровень=0)
    Состояние(Уровень);
    
    ЧислоДетей = Узел.childNodes.length;
    Для Инд=1 По ЧислоДетей Цикл
        
        ТекУзел = Узел.childNodes.item(Инд-1);
        Если ТекУзел.nodeType<>1 Тогда Продолжить; КонецЕсли;
        
        Отступ = Формат("","С"+Уровень*8);
        СтрАтрибуты="";
        
        Для Инд2=1 По ТекУзел.attributes.length Цикл
            Атрибут=ТекУзел.attributes.item(Инд2-1);
            СтрАтрибуты=СтрАтрибуты+?(СтрАтрибуты="","",";")+Атрибут.nodename+"="+Атрибут.value;
        КонецЦикла;
        
        Текст="";
        Если ТекУзел.childNodes.length=1 Тогда
            Если ТекУзел.childNodes.item(0).nodetype=3 Тогда
                Текст=ТекУзел.childNodes.item(0).text;
            КонецЕсли;    
        КонецЕсли;
        
        Стр = Отступ+ТекУзел.tagName+?(СтрАтрибуты="","","("+СтрАтрибуты+")" ) + ":" +Текст;
        Сообщить(Стр);
        
        прПечатьУзлов(xmlDoc, ТекУзел, Уровень+1);
    КонецЦикла;
    
    Состояние("");
КонецПроцедуры //прПечатьУзлов()

//**************************************************************************************
//
Процедура прТестовоеЧтение()
    
    Если ПустаяСтрока(ВыбФайл)=1 Тогда
        Сообщить("тестовое чтение файла обмена: не задано имя файла..?","i");
        Возврат;
    КонецЕсли;    
        
    оТест =  СоздатьОбъект("Microsoft.XMLDOM");
    оТест.Load(ВыбФайл);
    Корень = оТест.DocumentElement;
    ОчиститьОкноСообщений();
    прПечатьУзлов(оТест, Корень, 0);
    
КонецПроцедуры //прТестовоеЧтение()

апшипачка была здесь:
.
       Для Инд2=1 По ТекУзел.attributes.length Цикл  //ТекУзел, было Узел
            Атрибут=ТекУзел.attributes.item(Инд2-1); //ТекУзел, было Узел